Newer
Older
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
/**
* @author ETSI / STF517
* @version $URL$
* $Id$
* @desc Module containing functions for IVIM
*
*/
module LibItsIvim_Functions {
// LibCommon
import from LibCommon_Sync all;
import from LibCommon_VerdictControl all;
import from LibCommon_Time all;
// LibItsCommon
import from LibItsCommon_Templates all;
import from LibItsCommon_TypesAndValues all;
import from LibItsCommon_Functions all;
import from LibItsCommon_Pixits all;
// LibItsIvim
import from ITS_Container language "ASN.1:1997" all;
import from IVIM_PDU_Descriptions language "ASN.1:1997" all;
import from IVI language "ASN.1:1997" all;
import from EfcDsrcGeneric language "ASN.1:1997" all;
import from EfcDsrcApplication language "ASN.1:1997" all;
// LibItsIvim
import from LibItsIvim_TestSystem all;
import from LibItsIvim_TypesAndValues all;
import from LibItsIvim_Templates all;
import from LibItsIvim_Pixits all;
group itsFunction {
/**
* @desc Gets the Provifr of test system
* @return Test system's Provider value
* @see PX_PROVIDER
*/
function f_getProvider()
return Provider {
return PX_PROVIDER;
} // end f_getProvider
} // End of group itsFunction
group utFuntions {
/**
* @desc Requests to bring the IUT in an initial state
* @param p_init The initialisation to trigger.
*/
function f_utInitializeIut(template (value) UtInitialize p_init) runs on ItsIvim {
utPort.send(p_init);
tc_wait.start;
alt {
[] utPort.receive(UtInitializeResult:true) {
tc_wait.stop;
log("*** " & testcasename() & ": INFO: IUT initialized ***");
}
[] a_utDefault() {
//empty on purpose
}
[] tc_wait.timeout {
log("*** " & testcasename() & ": INFO: Could not receive expected UT message from IUT in time ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
[else] { // Shortcut defaults
// //f_sleep(0.050); // 50 ms
repeat;
}
}
}
/**
* @desc Triggers an event from the application layer
* @param p_event The event to trigger.
*/
function f_utTriggerEvent(
in template (value) UtIvimTrigger p_event
) runs on ItsIvim return IviIdentificationNumber {
var IviIdentificationNumber v_iviIdentificationNumber;
var UtIvimTriggerResult v_result;
utPort.send(p_event);
tc_wait.start;
alt {
[] utPort.receive(UtIvimTriggerResult:?) -> value v_result {
tc_wait.stop;
v_iviIdentificationNumber := v_result.iviIdentificationNumber;
if ( not v_result.result ) {
f_selfOrClientSyncAndVerdict("IVIM Trigger failed", e_error);
}
}
[] a_utDefault() {
//empty on purpose
}
[] tc_wait.timeout {
log("*** " & testcasename() & ": INFO: Could not receive expected UT message from IUT in time ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
[else] { // Shortcut defaults
// //f_sleep(0.050); // 50 ms
repeat;
}
}
return v_iviIdentificationNumber;
}
/**
* @desc Updates an event at the application layer
* @param p_event The event to update.
*/
function f_utUpdateEvent(
in template (value) UtIvimUpdate p_event
) runs on ItsIvim return IviIdentificationNumber {
var IviIdentificationNumber v_iviIdentificationNumber;
var UtIvimUpdateResult v_result;
utPort.send(p_event);
tc_wait.start;
alt {
[] utPort.receive(UtIvimUpdateResult:?) -> value v_result {
tc_wait.stop;
v_iviIdentificationNumber := v_result.iviIdentificationNumber;
}
[] a_utDefault() {
//empty on purpose
}
[] tc_wait.timeout {
log("*** " & testcasename() & ": INFO: Could not receive expected UT message from IUT in time ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
[else] { // Shortcut defaults
// //f_sleep(0.050); // 50 ms
repeat;
}
}
return v_iviIdentificationNumber;
}
/**
* @desc Terminates an event at the application layer
* @param p_event The event to terminate.
*/
function f_utTerminateEvent(template (value) UtIvimTermination p_event) runs on ItsIvim {
utPort.send(p_event);
tc_wait.start;
alt {
[] utPort.receive(UtIvimTerminationResult:?) {
tc_wait.stop;
}
[] tc_wait.timeout {
log("*** " & testcasename() & ": INFO: Could not receive expected UT message from IUT in time ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
[] a_utDefault() {
//empty on purpose
}
[else] { // Shortcut defaults
// //f_sleep(0.050); // 50 ms
repeat;
}
}
}
} // End of group utFunctions
group adapterControl {
/**
* @desc Triggers event in the test system adaptation.
* @param p_event The event to trigger
* @return FncRetCode
*/
function f_acTriggerGnssEvent(template (value) AcGnssPrimitive p_event) runs on ItsIvim return FncRetCode {
var FncRetCode v_ret := e_success;
acPort.send(p_event);
tc_ac.start;
alt {
[] acPort.receive(m_acGnssResponseSuccess) {
tc_ac.stop;
}
[] acPort.receive {
tc_ac.stop;
log("*** " & __SCOPE__ & ": ERROR: Received unexpected message ***");
f_selfOrClientSyncAndVerdict("error", e_error);
}
[] tc_ac.timeout {
log("*** " & __SCOPE__ & ": ERROR: Timeout while waiting for adapter control event result ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
}
return v_ret;
}
/**
* @desc Loads the given scenario
*
* @param p_scenario The scenario to load.
*/
function f_acLoadScenario(Scenario p_scenario) runs on ItsIvim {
if (PICS_GNSS_SCENARIO_SUPPORT==true) {
f_acTriggerGnssEvent(m_loadScenario(p_scenario));
}
} // end f_acLoadScenario
/**
* @desc Starts a loaded scenario
*/
function f_acStartScenario() runs on ItsIvim {
if (PICS_GNSS_SCENARIO_SUPPORT==true) {
f_acTriggerGnssEvent(m_startScenario);
vc_scenarioStarted := true;
}
} // end f_acStartScenario
/**
* @desc Stops a loaded scenario
*/
function f_acStopScenario() runs on ItsIvim {
if (PICS_GNSS_SCENARIO_SUPPORT==true and vc_scenarioStarted==true) {
f_acTriggerGnssEvent(m_stopScenario);
vc_scenarioStarted := false;
}
} // end f_acStopScenario
function f_acAwaitDistanceCovered(float p_distanceToCover) runs on ItsIvim return FncRetCode {
var FncRetCode v_ret := e_success;
if (PICS_GNSS_SCENARIO_SUPPORT==true and vc_scenarioStarted==true) {
f_acTriggerGnssEvent(m_distanceToCover(p_distanceToCover));
tc_ac.start;
alt {
[] acPort.receive(m_acGnssDistanceCovered) {
tc_ac.stop;
}
[] acPort.receive {
tc_ac.stop;
log("*** " & __SCOPE__ & ": ERROR: Received unexpected message ***");
f_selfOrClientSyncAndVerdict("error", e_error);
}
[] tc_ac.timeout {
log("*** " & __SCOPE__ & ": ERROR: Timeout while waiting for covered distance indication ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
}
}
return v_ret;
} // end f_acAwaitDistanceCovered
} // End of group adapterControl
group ivimConfigurationFunctions {
/**
* @desc Setups default configuration
*/
function f_cfUp() runs on ItsIvim system ItsIvimSystem {
map(self:acPort, system:acPort);
map(self:utPort, system:utPort);
map(self:ivimPort, system:ivimPort);
f_connect4SelfOrClientSync();
} // end f_cfUp
/**
* @desc Deletes default configuration
*/
function f_cfDown() runs on ItsIvim system ItsIvimSystem {
unmap(self:acPort, system:acPort);
unmap(self:utPort, system:utPort);
unmap(self:ivimPort, system:ivimPort);
f_disconnect4SelfOrClientSync();
} // end f_cfDown
} //end ivimConfigurationFunctions
group altsteps {
/**
* @desc The base default.
*/
altstep a_default() runs on ItsIvim {
[] ivimPort.receive(
mw_ivimInd(
mw_ivimPdu(
mw_ivimStructure
))) {
log("*** " & testcasename() & ": INFO: IVIM message received in default ***");
vc_ivimReceived := true;
repeat;
}
[] ivimPort.receive {
log("*** " & testcasename() & ": ERROR: Received an unexpected message ***");
f_selfOrClientSyncAndVerdict("error", e_error);
}
[] tc_wait.timeout {
log("*** " & testcasename() & ": INCONC: Timeout while awaiting reaction of the IUT prior to Upper Tester action ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
[] tc_ac.timeout {
log("*** " & testcasename() & ": INCONC: Timeout while awaiting the reception of a message ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
[] a_shutdown() {
f_poDefault();
f_cfDown();
log("*** " & testcasename() & ": INFO: TEST COMPONENT NOW STOPPING ITSELF! ***");
stop;
}
}
/**
* @desc The default for handling upper tester messages.
*/
altstep a_utDefault() runs on ItsIvim {
var UtIvimEventInd v_event;
[] utPort.receive(UtIvimEventInd:?) -> value v_event {
//store every upper tester indication received
vc_utEvents[lengthof(vc_utEvents)] := v_event;
repeat;
}
[] utPort.receive {
log("*** " & testcasename() & ": INFO: Received unhandled/unknown UT message from IUT ***");
repeat;
}
}
} // End of group altsteps
group preambles {
/**
* @desc The default preamble.
*/
function f_prDefault() runs on ItsIvim {
vc_default := activate(a_default());
activate(a_utDefault());
}
/**
* @desc Brings the IUT into an initial state.
* @return FncRetCode
*/
function f_prInitialState(Scenario p_scenario := e_staticPosition) runs on ItsIvim return FncRetCode {
var FncRetCode v_ret := e_success;
f_utInitializeIut(m_ivimStructureInitialize);
f_acLoadScenario(valueof(p_scenario));
f_acStartScenario();
f_prDefault();
return v_ret;
}
} // End of group preambles
group postambles {
/**
* @desc The default postamble.
*/
function f_poDefault() runs on ItsIvim {
var FncRetCode v_ret := e_success;
f_acStopScenario();
}
/**
* @desc Postamble including cancellation of an event.
* @param p_trigger Indicates if the cancellation have to be raised by the test system(e_ets)
* or at the application layer of the IUT(e_iut).
* @param p_actionId The action ID of the event to be cancelled
*/
function f_poCancelEvent(
in template (value) Trigger p_trigger,
in template (value) IviIdentificationNumber p_iviIdentificationNumber
) runs on ItsIvim {
var FncRetCode v_ret := e_success;
if (valueof(p_trigger) == e_ets) {
f_sendIviMessage(m_ivimStructureCancellation(p_iviIdentificationNumber));
f_sleep(PX_TNOAC);
}
else {
f_utTerminateEvent(m_utEventCancellation(p_iviIdentificationNumber));
}
f_poDefault();
}
} // End of group postambles
group sendFunctions {
/**
* @desc Sends a IVI message
* @param p_sendMsg The IVI message to send.
* @param p_overrideSeqNo Overrides the sequence number with the stored one.
*/
function f_sendIviMessage(
in template (value) IviStructure p_ivim
) runs on ItsIvim {
ivimPort.send(
m_ivimStructureReq(
m_ivimStructurePdu(
p_ivim
)
)
);
}
} // end sendFunctions
group receiveFunctions {
/**
* @desc Awaits a IVI message and returns it
* @param p_rcvMsg The expected message to be received.
* @param p_rcvdMsg The received message - OUT.
*/
function f_awaitIviMessage(in template (present) IvimInd p_rcvMsg, out IvimInd p_rcvdMsg) runs on ItsIvim {
tc_ac.start;
alt {
[] ivimPort.receive(p_rcvMsg) -> value p_rcvdMsg {
tc_ac.stop;
}
[] tc_ac.timeout {
log("*** " & testcasename() & ": INFO: Timeout while awaiting the reception of a message ***");
f_selfOrClientSyncAndVerdict("error", e_timeout);
}
}
}
} // end receiveFunctions
group miscellaneousFunctions {
/**
* @desc Increases the IviIdentification number and handles the special case where the
* IviIdentification number reaches the limit of 32768 and will be reset to 0.
* @param p_iviIdentificationNumber The IviIdentification number to increase.
* @return The increased IviIdentification number.
*/
function f_increaseIviIdentificationNumber(in IviIdentificationNumber p_iviIdentificationNumber) return IviIdentificationNumber {
// if maximum number of 32768 reached, reset it to 0
return ((p_iviIdentificationNumber + 1) mod 32768);
}
} // End of group miscellaneousFunctions
} // End of module LibItsIvim_Functions