LibItsDenm_TypesAndValues.ttcn

/**
 *  @author     ETSI / STF449
 *  @version    $URL$
 *              $Id$
 *  @desc       Module containing type and value definitions for DENM
 *
 */
module LibItsDenm_TypesAndValues {

    //LibIts
    import from DENM_PDU_Descriptions language "ASN.1:1997" all;
    import from ITS_Container language "ASN.1:1997" all;

    group actionTypes {
        
        /**
         * @desc Indication of whether event cancellation has to be raised by the test system or iut
         */
        type enumerated Trigger {
            e_ets(0),
            e_iut(1)
        }
        
    } // end group actionTypes
    
    group denmConstants {
        
        const DataVersion c_dataVersionFirst := 0;
        const DataVersion c_dataVersionCancellation := 255;
        
        const ValidityDuration c_defaultValidity := 600; 
        
    } // end group denmConstants
    
    group denmTimeConstants {
        
        // in milliseconds
        const TimestampIts c_duration20000ms := 20000;
        const TimestampIts c_duration40000ms := 40000;
        
        const float c_eventFrequencyMultiplier := 0.1;
        
    } // end denmTimeConstants
    
    group utPrimitives {

        /**
         * @desc Upper Tester message to initialize DENM IUT 
         */
        type record UtInitialize {
        }
        type boolean UtInitializeResult;
        
        /**
         * @desc Upper Tester message to trigger an action on DENM IUT 
         */
        type record UtTrigger {
            TimestampIts detectionTime,
            ValidityDuration validityDuration optional,
            ValidityDuration repetitionDuration optional,
            SituationContainer situtation,
            LocationContainer location,
            AlacarteContainer alacarte optional,
            RelevanceDistance relevanceDistance,
            RelevanceTrafficDirection relevanceTrafficDirection,
            integer trafficClass,
            TransmissionInterval transmissionInterval optional,
            boolean keepAliveForwardingRequest optional
        }
        type ActionID UtTriggerResult;
        
        /**
         * @desc Upper Tester message to trigger an action on DENM IUT 
         */
        type record UtUpdate {
            ActionID actionId,
            TimestampIts detectionTime,
            ValidityDuration validityDuration,
            SituationContainer situtation,
            LocationContainer location
        }
        type ActionID UtUpdateResult;
        
        /**
         * @desc Upper Tester message to trigger an action on DENM IUT 
         */
        type record UtTermination {
            ActionID actionId
        }
        type boolean UtTerminationResult;
        
        /**
         * @desc Upper Tester message to check event/status on DENM IUT 
         */
        type record UtEventInd {
            DENM denMsg
        }
        
    } // end utPrimitives
}
with {
    encode "LibItsDenm_TypesAndValues"
}