LibItsMapemSpatem_Templates.ttcn

/**
 *    @author   ETSI / STF484
 *    @version  $URL$
 *              $Id$
 *    @desc     Module containing base template definitions for MAPEM SPATEM
 *
 */
module LibItsMapemSpatem_Templates {

    // LibCommon
    import from LibCommon_BasicTypesAndValues all;
    import from LibCommon_DataStrings all;
    
    // LibIts
    import from ITS_Container language "ASN.1:1997" all;
    import from MAPEM_PDU_Descriptions language "ASN.1:1997" all;
    import from SPATEM_PDU_Descriptions language "ASN.1:1997" all;
    import from DSRC language "ASN.1:1997" all;
    
    // LibItsCommon
    import from LibItsCommon_Functions all;
    import from LibItsCommon_TypesAndValues all;
    
    // LibItsMapemSpatem
    import from LibItsMapemSpatem_TestSystem all;
    import from LibItsMapemSpatem_TypesAndValues all;
    import from LibItsMapemSpatem_Pixits all;

    group primitivesTemplates {
        
        /**
         * @desc    Send template for MAPEM Message (MapemSpatemPort Primitive)
         * @param   p_mapemMsg    The MAPEM Message to be sent
         */
        template (value) MapemReq m_mapemReq(
                                             in template (value) MAPEM p_mapemMsg
        ) := {
            msgOut := p_mapemMsg
        }
        
        /**
         * @desc    Receive template for MAPEM Message (MapemSpatemPort Primitive)
         * @param   p_mapemMsg    The expected MAPEM Message
         */
        template (present) MapemInd mw_mapemInd(
                                                template (present) MAPEM p_mapemMsg
        ) := {
            msgIn               := p_mapemMsg,
            gnNextHeader        := *,
            gnHeaderType        := *,
            gnHeaderSubtype     := *,
            gnLifetime          := *,
            gnTrafficClass      := *,
            btpDestinationPort  := *,
            btpInfo             := *,
            ssp                 := *,
            its_aid             := * 
        }
        
        /**
         * @desc    Receive template for MAPEM Message (MapemSpatemPort Primitive)
         * @param   p_mapemMsg          The expected MAPEM Message
         * @param   p_gnNextHeader      GN next header value
         * @param   p_gnHeaderType      GN header type value
         * @param   p_gnHeaderSubtype   GN header subtype value
         * @param   p_gnLifetime        GN packet lifetime value (ms)
         * @param   p_gnTrafficClass    GN traffic class value
         */
        template (present) MapemInd mw_mapemIndWithGnParameters(
                                                                template (present) MAPEM p_mapemMsg,
                                                                in template UInt8 p_gnNextHeader := *,
                                                                in template UInt8 p_gnHeaderType := *,
                                                                in template UInt8 p_gnHeaderSubtype := *,
                                                                in template UInt32 p_gnLifetime := *,
                                                                in template UInt8 p_gnTrafficClass := *
        ) modifies mw_mapemInd := { 
            gnNextHeader    := p_gnNextHeader,
            gnHeaderType    := p_gnHeaderType,
            gnHeaderSubtype := p_gnHeaderSubtype,
            gnLifetime      := p_gnLifetime,
            gnTrafficClass  := p_gnTrafficClass
        }
        
        /**
         * @desc    Receive template for MAPEM Message (MapemSpatemPort Primitive)
         * @param   p_mapemMsg              Expected MAPEM Message
         * @param   p_btpDestinationPort    BTP destination port value
         * @param   p_btpInfo               BTP destination port info value (if BTP-B) or BTP source port value (if BTP-A)
         */
        template MapemInd mw_mapemIndWithBtpParameters(
                                                       template (present) MAPEM p_mapemMsg,
                                                       in template UInt16 p_btpDestinationPort := *,
                                                       in template UInt16 p_btpInfo := *
        ) modifies mw_mapemInd := { 
            btpDestinationPort  := p_btpDestinationPort,
            btpInfo             := p_btpInfo     
        };
        
        /**
         * @desc    Receive template for MAPEM Message (MapemSpatemPort Primitive)
         * @param   p_mapemMsg  The expected MAPEM Message
         * @param   p_ssp       SSP value
         * @param   p_its_aid   ITS-AID value
         */
        template (present) MapemInd mw_mapemIndWithSecurityParameters(
                                                                      template (present) MAPEM p_mapemMsg,
                                                                      template Bit256 p_ssp := *,
                                                                      template UInt32 p_its_aid := *
        ) modifies mw_mapemInd := { 
            ssp     := p_ssp,
            its_aid := p_its_aid
        }
        
        /**
         * @desc    Send template for SPATEM Message (MapemSpatemPort Primitive)
         * @param   p_spatemMsg    The SPATEM Message to be sent
         */
        template (value) SpatemReq m_spatemReq(
                                               in template (value) SPATEM p_spatemMsg
        ) := {
            msgOut := p_spatemMsg
        }
        
        /**
         * @desc    Receive template for SPATEM Message (MapemSpatemPort Primitive)
         * @param   p_spatemMsg    The expected SPATEM Message
         */
        template (present) SpatemInd mw_spatemInd(
                                                  template (present) SPATEM p_spatemMsg
        ) := {
            msgIn               := p_spatemMsg,
            gnNextHeader        := *,
            gnHeaderType        := *,
            gnHeaderSubtype     := *,
            gnLifetime          := *,
            gnTrafficClass      := *,
            btpDestinationPort  := *,
            btpInfo             := *,
            ssp                 := *,
            its_aid             := * 
        };

        /**
         * @desc    Receive template for SPATEM Message (MapemSpatemPort Primitive)
         * @param   p_spatemMsg         The expected SPATEM Message
         * @param   p_gnNextHeader      GN next header value
         * @param   p_gnHeaderType      GN header type value
         * @param   p_gnHeaderSubtype   GN header subtype value
         * @param   p_gnLifetime        GN packet lifetime value (ms)
         * @param   p_gnTrafficClass    GN traffic class value
         */
        template (present) SpatemInd mw_spatemIndWithGnParameters(
                                                                  template (present) SPATEM p_spatemMsg,
                                                                  in template UInt8 p_gnNextHeader := *,
                                                                  in template UInt8 p_gnHeaderType := *,
                                                                  in template UInt8 p_gnHeaderSubtype := *,
                                                                  in template UInt32 p_gnLifetime := *,
                                                                  in template UInt8 p_gnTrafficClass := *
        ) modifies mw_spatemInd := { 
            gnNextHeader    := p_gnNextHeader,
            gnHeaderType    := p_gnHeaderType,
            gnHeaderSubtype := p_gnHeaderSubtype,
            gnLifetime      := p_gnLifetime,
            gnTrafficClass  := p_gnTrafficClass
        }
        
        /**
         * @desc    Receive template for SPATEM Message (MapemSpatemPort Primitive)
         * @param   p_spatemMsg             Expected MAPEM Message
         * @param   p_btpDestinationPort    BTP destination port value
         * @param   p_btpInfo               BTP destination port info value (if BTP-B) or BTP source port value (if BTP-A)
         */
        template SpatemInd mw_spatemIndWithBtpParameters(
                                                         template (present) SPATEM p_spatemMsg,
                                                         template UInt16 p_btpDestinationPort := *,
                                                         template UInt16 p_btpInfo := *
        ) modifies mw_spatemInd := { 
            btpDestinationPort  := p_btpDestinationPort,
            btpInfo             := p_btpInfo
        };

        /**
         * @desc    Receive template for SPATEM Message (MapemSpatemPort Primitive)
         * @param   p_spatemMsg  The expected SPATEM Message
         * @param   p_ssp        SSP value
         * @param   p_its_aid    ITS-AID value
         */
        template (present) SpatemInd mw_spatemIndWithSecurityParameters(
                                                                        template (present) SPATEM p_spatemMsg,
                                                                        template Bit256 p_ssp := *,
                                                                        template UInt32 p_its_aid := *
        ) modifies mw_spatemInd := { 
            ssp     := p_ssp,
            its_aid := p_its_aid
        }
        
    }

    group utPrimitives {
            
        /**
         * @desc    Send template for Upper Tester event initialization
         * @member hashedId8 In case of secured mode set, hashedId8 indicate which certificate the IUT shall use
        */
        template (value) UtInitialize m_mapemSpatemInitialize := {
            hashedId8 := '0000000000000000'O
        }

        /**
        * @desc    Send template for Upper Tester Trigger event
        */
            template (value) UtMapemSpatemTrigger m_utTriggerEvent ( Event p_event ) := {
                event    := p_event
        }
    }

    group mapSpatPduTemplates {
        
        /**
         * @desc    Send template for MAPEM PDU
         * @param   p_map  The MAPEM Message
         */
        template (value) MAPEM m_mapemPdu(
                                          in template (value) MapData p_map
        ) := {
            header  := m_itsPduHeader( - , - ,ItsPduHeader_messageID_mapem_ ),
            map_    := p_map
        }
        
        /**
         * @desc    Receive template for MAPEM PDU
         * @param   p_map  The MAPEM Message
         */
        template (present) MAPEM mw_mapemPdu(
                                             template (present) MapData p_map := ?
        ) := {
            header  := mw_itsPduHeaderMapem,
            map_    := p_map
        }
        
        /**
         * @desc    Send template for SPATEM PDU
         * @param   p_spat  The SPATEM Message
         */
        template (value) SPATEM m_spatemPdu(
                                            in template (value) SPAT p_spat
        ) := {
            header  := m_itsPduHeader( - , - , ItsPduHeader_messageID_spatem_ ),
            spat    := p_spat
        }
        
        /**
         * @desc    Receive template for SPATEM PDU
         * @param   p_spat  The SPATEM Message
         */
        template (present) SPATEM mw_spatemPdu(
                                               template (present) SPAT p_spat := ?
        ) := {
            header  := mw_itsPduHeaderSpatem,
            spat    := p_spat
        }
        
    } // End of group mapSpatPduTemplates
    
    group headerTemplates {
        
        /**
         * @desc    Default send template for ITS PDU header
         * @param   p_stationID         The source station ID (Default: test system station id)
         * @param   p_protocolVersion   The protocol version (Default: current MAPEM SPATEM protocol version)
         * @param   p_messageID         The message Id (Default: MAPEM SPATEM id)
         */
        template (value) ItsPduHeader m_itsPduHeader(
                                                     in template (value) StationID p_stationID := f_getTsStationId(),
                                                     in template (value) ItsPduHeader.protocolVersion p_protocolVersion := ItsPduHeader_protocolVersion_currentVersion_,
                                                     in template (value) ItsPduHeader.messageID p_messageID
        ) := {
            protocolVersion := p_protocolVersion,
            messageID       := p_messageID,
            stationID       := p_stationID
        }
        
        /**
         * @desc    Default receive template for ITS PDU header
         * @param   p_stationID         The expected station id (Default: any)
         * @param   p_protocolVersion   The expected protocol version (Default: current MAPEM SPATEM protocol version)
         * @param   p_messageID         The expected message id (Default: MAPEM SPATEM message id)
         */
        template ItsPduHeader mw_itsPduHeader(
                                              template (present) StationID p_stationID := ?,
                                              template (present) ItsPduHeader.protocolVersion p_protocolVersion := ItsPduHeader_protocolVersion_currentVersion_,
                                              template (present) ItsPduHeader.messageID p_messageID := ?
        ) := {
            protocolVersion := p_protocolVersion,
            messageID       := p_messageID,
            stationID       := p_stationID
        }
        
        /**
         * @desc    Default receive template for ITS PDU header
         * @param   p_stationID         The expected station id (Default: any)
         * @param   p_protocolVersion   The expected protocol version (Default: current MAPEM SPATEM protocol version)
         * @param   p_messageID         The expected message id (Default: MAPEM id)
         */
        template ItsPduHeader mw_itsPduHeaderMapem(
                                                   template (present) StationID p_stationID := ?,
                                                   template (present) ItsPduHeader.protocolVersion p_protocolVersion := ItsPduHeader_protocolVersion_currentVersion_,
                                                   template (present) ItsPduHeader.messageID p_messageID := ItsPduHeader_messageID_mapem_
        ) := {
            protocolVersion := p_protocolVersion,
            messageID       := p_messageID,
            stationID       := p_stationID
        }
        
        /**
         * @desc    Default receive template for ITS PDU header
         * @param   p_stationID         The expected station id (Default: any)
         * @param   p_protocolVersion   The expected protocol version (Default: current MAPEM SPATEM protocol version)
         * @param   p_messageID         The expected message id (Default: SPATEM id)
         */
        template ItsPduHeader mw_itsPduHeaderSpatem(
                                                    template (present) StationID p_stationID := ?,
                                                    template (present) ItsPduHeader.protocolVersion p_protocolVersion := ItsPduHeader_protocolVersion_currentVersion_,
                                                    template (present) ItsPduHeader.messageID p_messageID := ItsPduHeader_messageID_spatem_
        ) := {
            protocolVersion := p_protocolVersion,
            messageID := p_messageID,
            stationID := p_stationID
        }
        
        /**
         * @desc    Default receive template for the station id
         */
        template (present) StationID mw_anyStationId := ?;
        
    } // End of group headerTemplates

    group mapemSpatemTemplates {
        
        template (omit) IntersectionReferenceID m_intersectionReferenceID(
                                                                          in template (value) IntersectionID p_intersectionID := 0,
                                                                          in template (omit) RoadRegulatorID p_roadRegulatorID := omit
        ) := {
            region  := p_roadRegulatorID,   // a globally unique regional assignment value typical assigned to a regional DOT authority the value zero shall be used for testing needs
            id      := p_intersectionID     // a unique mapping to the intersection in question within the above region of use
        }
        
        template (omit) Connection m_connction(
                                               in template (value) ConnectingLane p_connectingLane, 
                                               in template (omit) IntersectionReferenceID p_remoteIntersection := omit,
                                               in template (omit) SignalGroupID p_signalGroup := omit,
                                               in template (omit) RestrictionClassID p_userClass := omit,
                                               in template (omit) LaneConnectionID p_connectionID := omit
        ) := {
            connectingLane      := p_connectingLane,        // The index of the connecting lane and also the maneuver from the current lane to it
            remoteIntersection  := p_remoteIntersection,    // This entry is only used when the indicated connecting lane belongs to another intersection layout.
            signalGroup         := p_signalGroup,           // The matching signal group send by the SPAT message for this lane/maneuver.
            userClass           := p_userClass,             // The Restriction Class of users this applies to
            connectionID        := p_connectionID           // An optional connection index used to relate this lane connection to any dynamic clearance data in the SPAT
        }
        
        group mapemTemplates {
            
            group mapemTemplatesSend {
                
                /**
                 * @desc    Send template for MAPEM Message
                 */
                template (value) MapData m_defaultMapem := {
                    timeStamp         := omit,
                    msgIssueRevision  := PX_MSG_ISSUE_REVISION,
                    layerType         := omit,
                    layerID           := omit,
                    intersections     := omit,
                    roadSegments      := omit,
                    dataParameters    := omit,
                    restrictionList   := omit,
                    regional          := omit
                }
                
                /**
                 * @desc    Receive template for MAPEM Message
                 */
                template (omit) MapData m_mapem(
                                                in template (value) MsgCount p_msgIssueRevision,
                                                in template (omit) IntersectionGeometryList p_intersectionGeometryList := omit,
                                                in template (omit) RoadSegmentList p_roadSegments := omit
                ) modifies m_defaultMapem := {
                    msgIssueRevision  := p_msgIssueRevision,
                    intersections     := p_intersectionGeometryList,
                    roadSegments      := p_roadSegments
                }
                
                template (omit) IntersectionGeometry m_intersectionGeometry(
                                                                            in template (value) IntersectionReferenceID p_intersectionReferenceID,
                                                                            in template (value) MsgCount p_revision,
                                                                            in template (value) Position3D p_position3D,
                                                                            in template (value) LaneList p_laneList,
                                                                            in template (omit) LaneWidth p_laneWidth := 2000
                ) := {
                    name                := omit,                        //For debug use only
                    id                  := p_intersectionReferenceID,   // A globally unique value set, consisting of a regionID and intersection ID assignment
                    revision            := p_revision,                  // Required default values about lane descriptions follow
                    refPoint            := p_position3D,                // The reference from which subsequent data points are offset until a new point is used. 
                    laneWidth           := p_laneWidth,                 // Reference width used by all subsequent lanes unless a new width is given speedLimits SpeedLimitList OPTIONAL, 
                    laneSet             := p_laneList,                  // Data about one or more lanes (all lane data is found here)
                    preemptPriorityData := omit,                        // data about one or more regional preempt or priority zones 
                    regional            := omit
                }
                
                template (value) Position3D m_position3D(
                                                         in template (value) Latitude p_latitude,
                                                         in template (value) Longitude p_longitude
                ) := {
                    lat        := p_latitude,   // in 1/10th micro degrees
                    long       := p_longitude,  // in 1/10th micro degrees
                    elevation  := omit,         // in 10 cm units
                    regional   := omit
                }
                
                template (omit) GenericLane m_laneList(
                                                       in template (value) LaneID p_laneID, 
                                                       in template (value) LaneAttributes p_laneAttributes, 
                                                       in template (value) NodeListXY p_nodeListXY,
                                                       in template (omit) ConnectsToList p_connectsToList := omit, 
                                                       in template (omit) ApproachID p_ingressApproach := omit,
                                                       in template (omit) ApproachID p_egressApproach := omit,
                                                       in template (omit) AllowedManeuvers p_allowedManeuvers := omit
                ) := {
                    laneID          :=  p_laneID,           // The unique ID number assigned to this lane object
                    name            := omit,                // often for debug use only but at times used to name ped crossings
                    ingressApproach := p_ingressApproach,   // inbound Approach IDs to which this lane belongs
                    egressApproach  := p_egressApproach,    // outbound Approach IDs to which this lane belongs
                    laneAttributes  := p_laneAttributes,    // All Attribute information about the basic selected lane type
                    maneuvers       := p_allowedManeuvers,  // the permitted maneuvers for this lane
                    nodeList        := p_nodeListXY,        // Lane spatial path information as well as various Attribute information along the node path  
                                                            // Attributes found here are more general and may come and go over the length of the lane.
                    connectsTo      := p_connectsToList,    // a list of other lanes and their signal group IDs each connecting lane and its signal group ID is given, therefore this element provides the information formerly in "signalGroups" in prior editions.
                    overlays        := omit,
                    regional        := omit
                }
                
                template (omit) RoadSegment m_roadSegment(
                                                          in template (value) RoadSegmentReferenceID p_id,
                                                          in template (value) MsgCount p_revision,
                                                          in template (value) Position3D p_position3D,
                                                          in template (value) RoadLaneSetList p_roadLaneSet,
                                                          in template (omit) SpeedLimitList p_speedLimits := omit,
                                                          in template (omit) LaneWidth p_laneWidth := 2000
                ) := {
                    name        := omit,
                    id          := p_id,            // a globally unique value for the segment
                    revision    := p_revision,      // Required default values about the descriptions to follow
                    refPoint    := p_position3D,    // the reference from which subsequent data points are offset until a new point is used.
                    laneWidth   := p_laneWidth,     // Reference width used by all subsequent lanes unless a new width is given  
                    speedLimits := p_speedLimits,   // Reference regulatory speed limits used by all subsequent lanes unless a new speed is given   
                    roadLaneSet := p_roadLaneSet,
                    regional    := omit
                }
                
                template (value) RegulatorySpeedLimit m_speedLimits(
                                                                    in template (value) SpeedLimitType p_speedLimitType, 
                                                                    in template (value) Velocity p_velocity
                ) := {
                    type_   := p_speedLimitType,    // The type of regulatory speed which follows
                    speed   := p_velocity           // The speed in units of 0.02 m/s
                }
                
            } // End of group mapemTemplatesSend 
            
            group mapemTemplatesRecv {
                
                /**
                 * @desc    Receive template for MAPEM Message
                 */
                template (present) MapData mw_defaultMapem := {
                    timeStamp         := *,
                    msgIssueRevision  := ?,
                    layerType         := *,
                    layerID           := *,
                    intersections     := *,
                    roadSegments      := *,
                    dataParameters    := *,
                    restrictionList   := *,
                    regional          := *
                }
                
                /**
                 * @desc    Receive template for MAPEM Message with no LayerType
                 */
                template (present) MapData mw_mapemWellFormatted modifies mw_defaultMapem := {
                    layerType         := omit,
                    layerID           := omit
                }
                
                /**
                 * @desc    Receive template for MAPEM Message with no LayerType
                 */
                template (present) MapData mw_mapemLayerType(
                                                             in template (present) LayerID p_layerID := ?
                ) modifies mw_mapemWellFormatted := {
                    layerType         := ?,
                    layerID           := p_layerID
                }
                
                template (present) IntersectionGeometry mw_intersectionGeometry(
                                                                                template (present) IntersectionReferenceID p_id := ?,
                                                                                template (present) MsgCount p_revision := ?,
                                                                                template (present) Position3D p_position3D := ?,
                                                                                template (present) LaneList p_laneList := ?
                ) := {
                    name                := *,                           //For debug use only
                    id                  := p_id,                        // A globally unique value set, consisting of a regionID and intersection ID assignment
                    revision            := p_revision,                  // Required default values about lane descriptions follow
                    refPoint            := p_position3D,                // The reference from which subsequent data points are offset until a new point is used. 
                    laneWidth           := *,                           // Reference width used by all subsequent lanes unless a new width is given speedLimits SpeedLimitList OPTIONAL, 
                    laneSet             := p_laneList,                  // Data about one or more lanes (all lane data is found here)
                    preemptPriorityData := *,                           // data about one or more regional preempt or priority zones 
                    regional            := *
                }
                
                template (present) RoadSegment mw_roadSegment(
                                                              template (present) RoadSegmentReferenceID p_id := ?,
                                                              template (present) MsgCount p_revision := ?,
                                                              template (present) Position3D p_position3D := ?, 
                                                              template (present) RoadLaneSetList p_roadLaneSet := ?
                ) := {
                    name        := *,
                    id          := p_id,            // a globally unique value for the segment
                    revision    := p_revision,      // Required default values about the descriptions to follow
                    refPoint    := p_position3D,    // the reference from which subsequent data points are offset until a new point is used.
                    laneWidth   := *,               // Reference width used by all subsequent lanes unless a new width is given  
                    speedLimits := *,               // Reference regulatory speed limits used by all subsequent lanes unless a new speed is given   
                    roadLaneSet := p_roadLaneSet,
                    regional    := *
                }
                
            } // End of group mapemTemplatesRecv 
            
        } // End of group mapemTemplates 
        
        group spatemTemplates {
            
            group spatemTemplatesSend {
                
            /**
             * @desc    Send default template for SPAT Message
             */
            template (value) SPAT m_defaultSpatem := {
                timeStamp      := omit,
                name           := omit, 
                intersections  := m_intersections,
                regional       := omit
            }
            
            /**
             * @desc    Send template for SPAT Message
             */
            template (omit) SPAT m_spatem(
                                          in template (value) IntersectionStateList p_intersections,
                                          in template (omit) DescriptiveName p_name := omit
            ) modifies m_defaultSpatem:= {
                timeStamp      := omit,
                name           := p_name, 
                intersections  := p_intersections,
                regional       := omit
            }
            
            template (value) IntersectionStateList m_intersections := { m_intersection };
            
            template (value) IntersectionState m_intersection := {
                    name                := omit,                                                // Human readable name for intersection to be used only in debug mode
                    id                  := m_intersectionReferenceID,                           // A globally unique value set, consisting of a  regionID and 
                                                                                                // intersection ID assignment provides a unique mapping to the intersection MAP in question which provides complete location and approach/move/lane data
                revision            := PX_INTERSECTIONSTATE_REVISION,
                    status              := IntersectionStatusObject_manualControlIsEnabled_,    // General status of the controller(s)
                    moy                 := omit,                                                // Minute of current UTC year used only with messages to be archived 
                    timeStamp           := omit,                                                // The mSec point in the current UTC minute that this message was constructed
                    enabledLanes        := { 1, 2 },                                            // A list of lanes where the RevocableLane bit has been set which are now active andtherefore part of the current intersection
                    states              := m_movements,                                         // Each Movement is given in turn and contains its signal phase state, mapping to the lanes it applies to, and point in time it will end, and it may contain both active and future states
                    maneuverAssistList  := omit,                                                // Assist data
                regional            := omit
            }
            
            template (value) MovementList m_movements := { m_movement };
            
            template (value) MovementState m_movement := {
                movementName           := omit,
                signalGroup            := PX_SIGNAL_GROUP_ID,    
                state_time_speed       := m_movementEventList,
                    maneuverAssistList     := { m_connectionManeuverAssist(1) },
                regional               := omit
            }
            
            template (value) MovementEventList m_movementEventList := { m_movementEvent };
            
                template (omit) MovementEvent m_movementEvent(
                                                              in template (value) MovementPhaseState p_eventState := stop_Then_Proceed,
                                                              in template (omit) TimeChangeDetails p_timing := omit,
                                                              in template (omit) MovementEvent.speeds p_speeds := omit
                ) := {
                    eventState      := stop_Then_Proceed,   // Consisting of: Phase state (the basic 11 states) and Directional, protected, or permissive state
                    timing          := p_timing,            // Timing Data in UTC time stamps for event includes start and min/max end times of phase confidence and estimated next occurrence
                    speeds          := p_speeds,            // Various speed advisories for use by general and specific types of vehicles supporting green-wave and other flow needs
                    regional        := omit 
                }
                
                template (omit) ConnectionManeuverAssist m_connectionManeuverAssist(
                                                                                    in template (value) LaneConnectionID p_connectionID,
                                                                                    in template (omit) ZoneLength p_queueLength := omit,
                                                                                    in template (omit) ZoneLength p_availableStorageLength := omit,
                                                                                    in template (omit) WaitOnStopline p_waitOnStop := omit,
                                                                                    in template (omit) PedestrianBicycleDetect p_pedBicycleDetect := omit
                ) := { 
                    connectionID            := p_connectionID,
                    queueLength             := p_queueLength,
                    availableStorageLength  := p_availableStorageLength,
                    waitOnStop              := p_waitOnStop,
                    pedBicycleDetect        := p_pedBicycleDetect,
                regional        := omit 
            }
            
                template (omit) TimeChangeDetails m_itmeChangeDetails(
                                                                      in template (value) TimeMark p_minEndTime,
                                                                      in template (omit) TimeMark p_startTime := omit,
                                                                      in template (omit) TimeMark p_maxEndTime := omit,
                                                                      in template (omit) TimeMark p_likelyTime := omit,
                                                                      in template (omit) TimeIntervalConfidence p_confidence := omit,
                                                                      in template (omit) TimeMark p_nextTime := omit
                ) := {
                    startTime  := p_startTime,  // When this phase 1st started
                    minEndTime := p_minEndTime, // Expected shortest end time
                    maxEndTime := p_maxEndTime, // Expected longest end time
                    likelyTime := p_likelyTime, // Best predicted value based on other data
                    confidence := p_confidence, // Applies to above time element only
                    nextTime   := p_nextTime    // A rough estimate of time when this phase may next occur again used to support various ECO driving power management needs.
                }
                
                template (omit) AdvisorySpeed m_advisorySpeed(
                                                              in template (value) AdvisorySpeedType p_type,
                                                              in template (omit) SpeedAdvice p_speed := omit,
                                                              in template (omit) SpeedConfidence p_confidence := omit,
                                                              in template (omit) ZoneLength p_distance := omit,
                                                              in template (omit) RestrictionClassID p_class := omit
                ) := {
                    type_       := p_type,          // The type of advisory which this is.
                    speed       := p_speed, 
                    confidence  := p_confidence,    // A confidence value for the above speed
                    distance    := p_distance,      // The distance indicates the region for which the advised speed  is recommended, it is specified upstream from the stop bar   along the connected egressing lane
                    class       := p_class,         // The vehicle types to which it applies when absent, the AdvisorySpeed applies to all motor vehicle types
                    regional    := omit
                }
                
            } // End of group spatemTemplatesSend
            
            group spatemTemplatesRecv {
                
            /**
             * @desc    Receive template for SPATEM Message
             */
            template (present) SPAT mw_defaultSpatem := {
                timeStamp      := *,
                name           := *, 
                intersections  := ?,
                regional       := *
            }
            
            template (present) SPAT mw_spatemWellFormatted 
            modifies mw_defaultSpatem := {
            }
            
            template (present) SPAT mw_spatem_with_region_id(
                                                             template (present) SPAT.regional p_regional := ?
            ) modifies mw_defaultSpatem := {
                regional       := p_regional // TODO Try to refined it
            }
            
        } // End of group spatemTemplates
            
        } // End of group spatemTemplatesRecv 
        
    } // End of group mapemSpatemTemplates

} // End of module LibItsMapemSpatem_Templates