ItsAtsp_TestCases.ttcn

             *          }
             *     }
             *     
             * Final conditions:
             * ensure that {
             *     when {
             *          the IUT deregistered
             *          }
             *     then {
             *          the IUT no more is addressable by the ITS-S management entity
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BV/10
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BV_10() runs on ItsCalm system ItsCalmSystem {
                    // Local variables
                    var CIstatus v_CIstatus;
                    
                    // Test control
                    if (not(PICS_DYNREG)) {
                        log("*** TC_ATSP_SE_BV_10: ERROR: 'PICS_DYNREG' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    // Clause 'Initial conditions'
                    
                    // Get CI status
                    v_CIstatus := f_initialCIstatesOperational();
                    
                    // Test Body
                    // Clause 'when'
                    f_cnSendMICOMMAND_RequestCheckSuccessCI(m_miStateChangeCommandRequest(
                                                        f_get_CI_LinkID(), 
                                                        f_getNextCommandRef(), 
                                                        c_ciStateChngDeregister), true);
                    //Clause 'then'
                    //    the IUT deregistered !!??!! ToDo: This might not be possible. Check with ISO
                    f_cnAwaitEventNotificationCI(f_get_CI_LinkID(), mw_miEvent21218_5(
                                                                        mw_miCIStatusParam(c_ciStatusNot_existent)), true);
                    // and is no more addressable
                    f_cnTestGetCiStatusParameterValueNoReplyExpected(f_get_CI_LinkID());
                                        
                    log("*** TC_ATSP_SE_BV_10: INFO: test body done ***");
                    
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_10: INFO: Postamble: done ***");
                    
                } // End of testcase TC_ATSP_SE_BV_10

            /**
             * @desc    TP: IUT performs inactivation
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: PICS_INACT
             * Initial conditions: 
             *  with {
             *       the IUT being in the CI state "active" or "connected" or "suspended"
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT receives the COMMAND "CIstateChng" with the value "inactivate"
             *          }
             *     then {
             *          the IUT performs inactivation
             *          }
             *     }
             *     
             * Final conditions:
             * ensure that {
             *     when {
             *          the IUT performed inactivation
             *          }
             *     then {
             *          the IUT no more has VCIs
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BV/11
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BV_11() runs on ItsCalm system ItsCalmSystem {
                    // Local variables
                    var IParamList v_IparamList;
                    var CIstatus v_CIstatus;
                    
                    // Test control
                    if (not(PICS_INACT)) {
                        log("*** TC_ATSP_SE_BV_11: ERROR: 'PICS_INACT' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    // Clause 'Initial conditions'
                    
                    // Get CI status
                    v_CIstatus := f_cnGetCiStatusParameterValueCI( f_get_CI_LinkID());
                    if( (v_CIstatus == c_ciStatusUnknown) or (v_CIstatus == c_ciStatusNot_existent) or (v_CIstatus == c_ciStatusExistent) or (v_CIstatus == c_ciStatusInactive) or (v_CIstatus == c_ciStatusRegistered))
                    // wrong status 
                    {
                        // Request operator to switch on the SUT or to activate the IUT
                        action("Switch on SUT or activate IUT");
						f_cnAwaitRegistrationCI(f_get_CI_LinkID(), PX_CI_MED_TYPE, true);
                    	f_cnAwaitEventNotificationCI(f_get_CI_LinkID(), mw_miEvent21218_5(mw_miCIStatusParam(c_ciStatusActive)), true);
                        v_CIstatus := f_cnGetCiStatusParameterValueCI( f_get_CI_LinkID());
                    }
                    // check again CI status after activation of IUT
                    if( (v_CIstatus == c_ciStatusUnknown) or (v_CIstatus == c_ciStatusNot_existent) or (v_CIstatus == c_ciStatusExistent) or (v_CIstatus == c_ciStatusInactive) or (v_CIstatus == c_ciStatusRegistered))                    // wrong status 
                    {
                        log("*** TC_ATSP_BV_11: ERROR: Invalid CI status returned ***", v_CIstatus);
                        f_selfOrClientSyncAndVerdict("error", e_timeout);  // Might be just a time-out error
                        stop;
                    }
                    else
                    {
                        log("*** TC_ATSP_BV_11: Allowed CI status returned ***", v_CIstatus);
                    }
                    
                    // Test Body
                    // Clause 'when'
                    //        the IUT receives the COMMAND "CIstateChng" with the value "inactivate"
                    f_cnTriggerStateChangeAndWaitCI(f_get_CI_LinkID(), c_ciStateChngInactivate, c_ciStatusInactive, false);
                    
                    //Clause 'when'
                    //        the IUT performed inactivation
                    
                    
                    //Clause 'then'
                    v_IparamList := f_cnGetIParameterValueCI(f_get_CI_LinkID(), {c_ciIParamNoVirtualCI}, false );
                    if(lengthof(v_IparamList) == 1 and v_IparamList[0].paramNo == c_ciIParamNoVirtualCI and f_getVirualCIcount(v_IparamList[0]) == 0)
					{
						f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);
                        log("*** TC_ATSP_SE_BV_11: INFO: test body done ***");
					}
					else if(lengthof(v_IparamList) == 0)
					{
						f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);
                        log("*** TC_ATSP_SE_BV_11: INFO: test body done ***");
					}
					else
                    {
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_error);
                        log("*** TC_ATSP_SE_BV_11: ERROR: Inactivated CI still has VCIs ***");
                    }
        
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_11: INFO: Postamble: done ***");
                    
                } // End of testcase TC_ATSP_SE_BV_11

            /**
             * @desc    TP: IUT performs activation
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: PICS_ACT
             * Initial conditions: 
             *  with {
             *       the IUT being in the CI state "inactive"
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT receives the COMMAND "CIstateChng" with the value "activate"
             *          }
             *     then {
             *          the IUT performs activation, i.e. reaches the CI state "registered"
             *          }
             *     }
              * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BV/12
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BV_12() runs on ItsCalm system ItsCalmSystem {
                    // Local variables
                    var CIstatus v_CIstatus;
					var template MI_Command_request v_stateChangeRequest;
                    
                    // Test control
                    if (not(PICS_ACT)) {
                        log("*** TC_ATSP_SE_BV_12: ERROR: 'PICS_ACT' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    // Clause 'Initial conditions'
                    
                    // Get CI status
                    v_CIstatus := f_cnGetCiStatusParameterValueCI( f_get_CI_LinkID());
                    if( (v_CIstatus == c_ciStatusUnknown) or (v_CIstatus == c_ciStatusNot_existent) or (v_CIstatus == c_ciStatusExistent) or (v_CIstatus == c_ciStatusInactive) or (v_CIstatus == c_ciStatusRegistered))
                    // wrong status 
                    {
                        // Request operator to switch on the SUT or to activate the IUT
                        action("Switch on SUT or activate IUT");
						f_cnAwaitRegistrationCI(f_get_CI_LinkID(), PX_CI_MED_TYPE, true);
                    	f_cnAwaitEventNotificationCI(f_get_CI_LinkID(), mw_miEvent21218_5(mw_miCIStatusParam(c_ciStatusActive)), true);
                        v_CIstatus := f_cnGetCiStatusParameterValueCI( f_get_CI_LinkID());
                    }
                    // check again CI status after activation of IUT
                    if( (v_CIstatus == c_ciStatusUnknown) or (v_CIstatus == c_ciStatusNot_existent) or (v_CIstatus == c_ciStatusExistent) or (v_CIstatus == c_ciStatusInactive) or (v_CIstatus == c_ciStatusRegistered))                    // wrong status 
                    {
                        log("*** TC_ATSP_BV_12: ERROR: Invalid CI status returned ***", v_CIstatus);
                        f_selfOrClientSyncAndVerdict("error", e_timeout);  // Might be just a time-out error
                        stop;
                    }
                    else
                    {
                        log("*** TC_ATSP_BV_12: Allowed CI status returned ***", v_CIstatus);
                    }
                    // Inactivate CI (required initial state)
                    f_cnTriggerStateChangeAndWaitCI(f_get_CI_LinkID(), c_ciStateChngInactivate, c_ciStatusInactive, false);
					
					
                    // Test Body
                    // Clause 'when'
                    //the IUT receives the COMMAND "CIstateChng" with the value "activate"
                    //inactive->active state chenge is not possible inactive->registered->active is possible
					//f_cnSendMICOMMAND_RequestCheckSuccessCI(m_miStateChangeCommandRequest(f_get_CI_LinkID(), f_getNextCommandRef(), c_ciStatusRegistered), true);
					v_stateChangeRequest := m_miStateChangeCommandRequest(f_get_CI_LinkID(), f_getNextCommandRef(), c_ciStatusRegistered);
                    f_cnSendMICOMMAND_RequestCI(v_stateChangeRequest);
					
                    //Clause 'then'
                    //        the IUT performs activation, i.e. reaches the CI state "registered"
					f_cnAwaitRegistrationCI(f_get_CI_LinkID(), PX_CI_MED_TYPE, true);
					
					f_cnAwaitCommandConfirmSuccess(v_stateChangeRequest, false);
					f_cnAwaitEventNotificationCI(f_get_CI_LinkID(), mw_miEvent21218_5(mw_miCIStatusParam(c_ciStatusActive)), true);
					
					f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success); // ToDo: Is this needed here?
                    log("*** TC_ATSP_SE_BV_12: INFO: test body done ***");
        
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_12: INFO: Postamble: done ***");
                } // End of testcase TC_ATSP_SE_BV_12

            /**
             * @desc    TP: IUT performs suspension
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: PICS_SUSP
             * Initial conditions: 
             *  with {
             *       the IUT being in the CI state "connected"
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT receives the COMMAND "CIstateChng" with the value "suspend"
             *          }
             *     then {
             *          the IUT performs suspension
             *          }
             *     }
             *     
             * Final conditions:
             * ensure that {
             *     when {
             *          the IUT performed suspension
             *          }
             *     then {
             *          the IUT still accepts new transmission requests at the IN-SAP, without performing the transmission
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BV/13
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BV_13() runs on ItsCalm system ItsCalmSystem {
                    //TODO:         Ensure IUT is in "connected" state
                    //    
                    
                    
                    // Local variables
                    var CIstatus v_CIstatus;
                    var template AtspInd v_atspEventInd;
                    
                    // Test control
                    if (not(PICS_SUSP)) {
                        log("*** TC_ATSP_SE_BV_13: ERROR: 'PICS_ACT' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    // Clause 'Initial conditions'
                    
                    // IUT in interim CI state "active"
                    v_CIstatus := f_initialCIstateActive();
                    // Connect CI by sending a frame
                    f_atspSendIN_UNITDATA_Request(
                                    //source
                                    m_inLLServiceAddr( 
                                        PX_IN_SAP_ADDRESS,
                                        f_get_TesterCI_LinkID()),     
                                    //destination
                                    m_inLLServiceAddr(
                                        PX_IN_SAP_ADDRESS,
                                        f_get_TesterDestinationVCI_BC_LinkID()),
                                    m_inDataEmpty,
                                    m_inUserPriorityHighest);
                    
                    // Test Body
                    // Clause 'when'
                    //the IUT receives the COMMAND "CIstateChng" with the value "suspend"
                    f_cnTriggerStateChangeAndWaitCI(f_get_CI_LinkID(), c_ciStateChngSuspend, c_ciStatusSuspended, false);
                
                    //Clause 'then'
                    //        the IUT still accepts new transmission requests at the IN-SAP, without performing the transmission
                    f_utSendIN_UNITDATA_Request(
                                    //source
                                    m_inLLServiceAddr( 
                                        PX_IN_SAP_ADDRESS,
                                        f_get_CI_LinkID()),     
                                    //destination
                                    m_inLLServiceAddr(
                                        PX_IN_SAP_ADDRESS,
                                        f_get_DestinationVCI_BC_LinkID()),
                                    m_inDataEmpty,
                                    m_inUserPriorityHighest);                    

                    //Check whether the transmission request is performed unexpected
                    v_atspEventInd := ?;

                    alt {
                        [] atspPort.receive(v_atspEventInd) {
                            tc_wait.stop;
                            log("*** TC_ATSP_SE_BV_13: INFO: Unexpected IN-UNITDATA.indication received ***");
                            f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_error);
                        }
                        [] tc_wait.timeout {
                            log("*** TC_ATSP_SE_BV_13: INFO: Expected time out ***");
                            f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);
                        }
                    }
        
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_13: INFO: Postamble: done ***");
                    
                } // End of testcase TC_ATSP_SE_BV_13

            /**
             * @desc    TP: IUT performs suspension
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: PICS_RES
             * Initial conditions: 
             *  with {
             *       the IUT being in the CI state "suspended"
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT receives the COMMAND "CIstateChng" with the value "resume"
             *          }
             *     then {
             *          the IUT performs resuming
             *          }
             *     }
             *     
             * Final conditions:
             * ensure that {
             *     when {
             *          the IUT performed resuming
             *          }
             *     then {
             *          the IUT starts transmisison of pending packets
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BV/14
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BV_14() runs on ItsCalm system ItsCalmSystem {                    
                    // Local variables
                    var AtspInd v_result;
                    var template AtspInd v_atspEventInd;
                    var CIstatus v_CIstatus;
                    
                    // Test control
                    if (not(PICS_RES)) {
                        log("*** TC_ATSP_SE_BV_14: ERROR: 'PICS_ACT' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    // Clause 'Initial conditions'
                    
                    // Get IUT in CI state "active
                    v_CIstatus := f_initialCIstateActive();
                    // Get IUT in CI state "connected"
                    f_atspSendIN_UNITDATA_Request(
                                    //source
                                    m_inLLServiceAddr( 
                                        PX_IN_SAP_ADDRESS,
                                        f_get_TesterCI_LinkID()),     
                                    //destination
                                    m_inLLServiceAddr(
                                        PX_IN_SAP_ADDRESS,
                                        f_get_TesterDestinationVCI_BC_LinkID()),
                                    m_inDataEmpty,
                                    m_inUserPriorityHighest);
                    
                    // Force the IUT to enter the state suspended
                    f_cnTriggerStateChangeAndWaitCI(f_get_CI_LinkID(), c_ciStateChngSuspend, c_ciStatusSuspended, true);
                    // Request IUT to send several BC frames
                    f_utSendIN_UNITDATA_Request(
                                    //source
                                    m_inLLServiceAddr( 
                                        PX_IN_SAP_ADDRESS,
                                        f_get_CI_LinkID()),     
                                    //destination
                                    m_inLLServiceAddr(
                                        PX_IN_SAP_ADDRESS,
                                        f_get_DestinationVCI_BC_LinkID()),
                                    m_inDataEmpty,
                                    m_inUserPriorityAverage);
                    f_utSendIN_UNITDATA_Request(
                                    //source
                                    m_inLLServiceAddr( 
                                        PX_IN_SAP_ADDRESS,
                                        f_get_CI_LinkID()),     
                                    //destination
                                    m_inLLServiceAddr(
                                        PX_IN_SAP_ADDRESS,
                                        f_get_DestinationVCI_BC_LinkID()),
                                    m_inDataAA,
                                    m_inUserPriorityHighest);
                    f_utSendIN_UNITDATA_Request(
                                    //source
                                    m_inLLServiceAddr( 
                                        PX_IN_SAP_ADDRESS,
                                        f_get_CI_LinkID()),     
                                    //destination
                                    m_inLLServiceAddr(
                                        PX_IN_SAP_ADDRESS,
                                        f_get_DestinationVCI_BC_LinkID()),
                                    m_inDataBB,
                                    m_inUserPriorityLowest);
                    
                    // Check that IUT does not send the frames
                    v_atspEventInd := ?;

                    alt {
                        [] atspPort.receive(v_atspEventInd) {
                            tc_wait.stop;
                            log("*** TC_ATSP_SE_BV_14: INFO: Unexpected IN-UNITDATA.indication received ***");
                            f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_error);
                        }
                        [] tc_wait.timeout {
                            log("*** TC_ATSP_SE_BV_14: INFO: Expected time out ***");
                            f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);
                        }
                    } // End of 'alt' statement    
                    
                    // Test Body
                    // Clause 'when'
                    //        the IUT receives the COMMAND "CIstateChng" with the value "resume"
                    f_cnTriggerStateChangeAndWaitCI(f_get_CI_LinkID(), c_ciStateChngResume, c_ciStatusConnected, true);
                    //        the IUT performed resuming
                    
                    //Clause 'then'
                    //        the IUT starts transmisison of pending packets
                    v_atspEventInd := ?;
                    
                    // Clause 'then' receive via atspPort
                    for( var integer x:=1; x <4; x := x+1) {
                        tc_wait.start;
                        alt {
                            [] atspPort.receive(v_atspEventInd) {
                                tc_wait.stop;
                                log("*** TC_ATSP_SE_BV_14: INFO: Expected IN-UNITDATA.indication received ***");
                                f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);
                                log("*** TC_ATSP_SE_BV_14: INFO: test body done ***");
                            }
                            [] tc_wait.timeout {
                                log("*** TC_ATSP_SE_BV_14: INFO: Unexpected time out ***");
                                f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                            }
                        } // End of 'alt' statement    
                    }
                    
                    f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);
                    log("*** TC_ATSP_SE_BV_14: INFO: test body done ***");
                    
                    log("*** TC_ATSP_SE_BV_14: INFO: test body done ***");
        
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_14: INFO: Postamble: done ***");
                } // End of testcase TC_ATSP_SE_BV_14

            /**
             * @desc    TP: IUT of CIC-l2 and CIAC-2 performs connection manually
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: PICS_CIC_l2 AND PICS_CIAC2
             * Initial conditions: 
             *  with {
             *       the IUT being in the CI state "active",
             *       valid access information in I-Parameters "SIMpin", "ProviderInfo" is present,
             *       the IUT is exposed to the signals of a related base station,
             *       I-Parameter Connect is set to "manual"
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT receives the COMMAND "CONcmd"
             *          }
             *     then {
             *          the IUT performs connection
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BV/15
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BV_15() runs on ItsCalm system ItsCalmSystem {
                    // Local variables
                    var CIstatus v_CIstatus;

                    // Test control
                    if (not(PICS_CIC_l2 and PICS_CIAC2)) {
                        log("*** TC_ATSP_SE_BV_15: ERROR: 'PICS_CIC_l2 AND PICS_CIAC2' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Get CI status
                    v_CIstatus := f_initialCIstateActive();
                    // Set I-Parameter Connect to "manual"
                    // set access credentials in I-Parameters "SIMpin", "ProviderInfo"
                    // ToDo
                    //
                    
                    // Test Body
                    // Clause 'when'
                    // the IUT receives the COMMAND "CONcmd"
                    // Clause 'then'
                    // the IUT performs connection
                    f_cnSendMICOMMAND_RequestCheckSuccessCI(m_miCONcmdCommandRequest( 
                                                            f_get_CI_LinkID(), 
                                                            f_getNextCommandRef(),
                                                            c_ciConConnect), true);
                    
                    // Check whether CI status is now "connected"
                    f_cnAwaitEventNotificationCI(f_get_CI_LinkID(), mw_miEvent21218_5(mw_miCIStatusParam(c_ciStatusConnected)), true);
                    
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_15: INFO: Postamble: done ***");
                    
                } // End of testcase TC_ATSP_SE_BV_15

            /**
             * @desc    TP: IUT CIC-l2 performs connection automatically
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: PICS_CIC_l2
             * Initial conditions: 
             *  with {
             *       the IUT being in the CI state "active",
             *       valid access information in I-Parameters "SIMpin", "ProviderInfo" is present,
             *       the IUT is not exposed to the signals of a related base station,
             *       I-Parameter Connect is set to "automatic"
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT is exposed to the signal of a related base station
             *          }
             *     then {
             *          the IUT performs connection
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BV/16
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BV_16() runs on ItsCalm system ItsCalmSystem {
                    // Local variables
                    var CIstatus v_CIstatus;

                    // Test control
                    if (not(PICS_CIC_l2)) {
                        log("*** TC_ATSP_SE_BV_15: ERROR: 'PICS_CIC_l2' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Initial conditions
                    // CI status has to be "active"
                    v_CIstatus := f_initialCIstateActive();
                    // Set I-Parameter Connect to "automatic"
                    // set access credentials in I-Parameters "SIMpin", "ProviderInfo"
                    // ToDo
                    
                    // Test Body
                    // Clause 'when'
                    // the IUT is exposed to the signal of a related base station
                    action("Expose IUT to signal of base station");

                    // Clause 'then'
                    // the IUT performs connection
                    // Check whether CI status is now "connected"
                    f_cnAwaitEventNotificationCI(f_get_CI_LinkID(), mw_miEvent21218_5(mw_miCIStatusParam(c_ciStatusConnected)), true);
                    
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_16: INFO: Postamble: done ***");
                    
                } // End of testcase TC_ATSP_SE_BV_16

            /**
             * @desc    TP: IUT CIAC-2 or CIAC-3 performs disconnection 
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: PICS_DISCONN
             * Initial conditions: 
             *  with {
             *       the IUT being in the CI state "connected"
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT receives the COMMAND "CIstateChng" with the value "disconnect"
             *          }
             *     then {
             *          the IUT performs disconnection
             *          }
             *     }
             *     
             * Final conditions:
             * ensure that {
             *     when {
             *          the IUT performed disconnection
             *          }
             *     then {
             *          the IUT is in the CI state "active"
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BV/17
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BV_17() runs on ItsCalm system ItsCalmSystem {
                    // Local variables
//                    var integer v_messageCounter;
                    var CIstatus v_CIstatus;
                    
                    // Test control
                    if (not(PICS_DISCONN)) {
                        log("*** TC_ATSP_SE_BV_17: ERROR: 'PICS_DISCONN' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    // Clause 'Initial conditions'
                    // CI status has to be "active"
                    v_CIstatus := f_initialCIstateActive();
                    // 
                    // Connect CI by sending a frame
                    f_atspSendIN_UNITDATA_Request(
                                    //source
                                    m_inLLServiceAddr( 
                                        PX_IN_SAP_ADDRESS,
                                        f_get_TesterCI_LinkID()),     
                                    //destination
                                    m_inLLServiceAddr(
                                        PX_IN_SAP_ADDRESS,
                                        f_get_TesterDestinationVCI_BC_LinkID()),
                                    m_inDataEmpty,
                                    m_inUserPriorityHighest);
                    
                    
                    // Test Body
                    // Clause 'when'
                    //the IUT receives the COMMAND "CIstateChng" with the value "disconnect"
                    f_cnSendMICOMMAND_RequestCheckSuccessCI(m_miStateChangeCommandRequest(
                                                                f_get_CI_LinkID(), 
                                                                f_getNextCommandRef(), 
                                                                c_ciStateChngDisconnect), true);
                    
                    //Clause 'then'
                    //        the IUT is in the CI state "active"
                    f_cnAwaitEventNotificationCI(f_get_CI_LinkID(), mw_miEvent21218_5(mw_miCIStatusParam(c_ciStatusActive)), true);
                    f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);
                    log("*** TC_ATSP_SE_BV_17: INFO: test body done ***");
        
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_17: INFO: Postamble: done ***");
                } // End of testcase TC_ATSP_SE_BV_17

        } // End of group validBehavior
            
            
        group invalidBehavior {

            /**
             * @desc    TP: IUT rejects an invalid CI state transition request 
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: PICS_DYNREG OR PICS_INACT OR PICS_ACT OR PICS_SUSP OR PICS_RES OR PICS_CONN OR PICS_DISCONN
             * Initial conditions: 
             *  with {
             *       the IUT being in any CI state except the CI state "existent" or "not-existent"
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT receives the MI-COMMAND "CIstateChng" with an invalid value of CIstatus
             *          }
             *     then {
             *          the IUT acknowledges with error code "INVALID COMMAND/REQUEST VALUE"
             *          }
             *     }
             *     
             * Final conditions:
             * ensure that {
             *     when {
             *          the IUT acknowledged with error code "INVALID COMMAND/REQUEST VALUE"
             *          }
             *     then {
             *          the IUT is still in the initial CI state
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BI/01
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BI_01() runs on ItsCalm system ItsCalmSystem {
                    // Local variables
                    var integer v_messageCounter;
                    var template(value) MI_Command_request v_stateChangeCommand;
                    var CIstatus v_CIstatus;
                    var CIstatus v_CIstatus1;
                    
                    // Test control
                    if (not(PICS_DYNREG or PICS_INACT or PICS_ACT or PICS_SUSP or PICS_RES or PICS_CONN or PICS_DISCONN)) {
                        log("*** TC_ATSP_SE_BI_01: ERROR: 'PICS_DYNREG' or 'PICS_INACT' or 'PICS_ACT'",
                                " or 'PICS_SUSP' or 'PICS_RES' or 'PICS_CONN' or 'PICS_DISCONN' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    // Clause 'Initial conditions'
                    // the IUT being in any CI state except the CI state "existent" or "not-existent" 
                    // Check initial CI state
                    v_CIstatus := f_initialCIstatesOperational();
                    
                    // Test Body
                    // Clause 'when'
                    //the IUT receives the MI-COMMAND "CIstateChng" with an invalid value of CIstatus
                    v_stateChangeCommand := m_miStateChangeCommandRequest(
                                                    f_get_CI_LinkID(), 
                                                    f_getNextCommandRef(), 
                                                    c_ciStateChngInvalidValue);
                    f_cnSendMICOMMAND_RequestCI(v_stateChangeCommand);
					
                    //Clause 'then'
                    //        the IUT acknowledged with error code "INVALID COMMAND/REQUEST VALUE"
                    f_cnAwaitCommandConfirm(v_stateChangeCommand, c_ciErrStatusCmdReqVal, true);
                    
                                        
                    //Clause 'then'
                    //        the IUT is still in the initial CI state
                    v_CIstatus1 := f_cnGetCiStatusParameterValueCI(f_get_CI_LinkID());
                    if(v_CIstatus1 == v_CIstatus) {
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);
                    } else {
                        log("*** TC_ATSP_SE_BI_01: INFO: CI status changed unexpected", v_CIstatus1);
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_error); 
                    }
                    
                    log("*** TC_ATSP_SE_BI_01: INFO: test body done ***");
        
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BI_01: INFO: Postamble: done ***");
                    
                    
                } // End of testcase TC_ATSP_SE_BI_01
            
            /**
             * @desc    TP: IUT ignores a connect request with missing access information
             * @author  STF 455
             * @config  
             * 
             * <pre>
             * PICS selection: (PICS_CIAC2 OR PICS_CIAC3) AND PICS_CONN
             * Initial conditions: 
             *  with {
             *       the IUT being in the CI state "active",
             *       I-Parameter "Connect" is set to "manual",
             *       no access information in I-Parameters "SIMpin", "ProviderInfo" is present
             *       }
             * 
             * Expected behaviour:
             *  ensure that {
             *     when {
             *          the IUT receives the MI-COMMAND "CONcmd" with value "connect"
             *          }
             *     then {
             *          the IUT acknowledges with error code "INVALID COMMAND/REQUEST VALUE"
             *          }
             *     }
             *     
             * Final conditions:
             * ensure that {
             *     when {
             *          the IUT acknowledged with error code "INVALID COMMAND/REQUEST VALUE"
             *          }
             *     then {
             *          the IUT is still in the CI state "active"
             *          }
             *     }
             * </pre>
             * 
             * @version 2013-05-07.0
             * @since   2013-05-07.0
             * @status  empty test case
             * @reference     ETSI TS 102 760-2 v1.1.2_STF455_v06 SE/BI/02
             * @remark  to be created
             */
                testcase TC_ATSP_SE_BI_02() runs on ItsCalm system ItsCalmSystem {
                    // Local variables
                    var CIstatus v_CIstatus;
                    var template MI_Command_request v_stateChngCmdReq;

                    // Test control
                    if (not(PICS_CIC_l2 and PICS_CIAC2)) {
                        log("*** TC_ATSP_SE_BV_15: ERROR: 'PICS_CIC_l2 AND PICS_CIAC2' required for executing the TC ***");
                        stop;
                    }
                    
                    // Test component configuration
                    f_cf01Up();
                    
                    // Test adapter configuration
                    
                    //  CI status has to be "active"
                    v_CIstatus := f_initialCIstateActive();
                    // Set I-Parameter Connect to "manual"
                    // ToDo
                    //
                    
                    // Test Body
                    // Clause 'when'
                    // the IUT receives the COMMAND "CONcmd"
                    v_stateChngCmdReq := m_miStateChangeCommandRequest(
                                                    f_get_CI_LinkID(),
                                                    f_getNextCommandRef(), 
                                                    c_ciStateChngConnect);
                    f_cnSendMICOMMAND_RequestCI(v_stateChngCmdReq);
                    // Clause 'then'
                    // the IUT rejects connection
                    f_cnAwaitCommandConfirm(v_stateChngCmdReq, c_ciErrStatusCmdReqVal, false);
                    
                    // Check whether CI status is still "active"
                    f_cnAwaitEventNotificationCI(f_get_CI_LinkID(), mw_miEvent21218_5(mw_miCIStatusParam(c_ciStatusActive)), true);
                    
                    // Postamble
                    f_poDefault();
                    f_cf01Down();
                    log("*** TC_ATSP_SE_BV_15: INFO: Postamble: done ***");
                    
                    
                } // End of testcase TC_ATSP_SE_BI_02
            
        } // End of group invalidBehavior
            
    } // End of group stateEventTransitions


    
    // MIB I-Parameters
    group mibIparameters {
        
            
        group validBehavior {

            /**
             * @desc    TP: IUT correctly reads I-Parameters with Read/Write access or Read-only access