ItsMapem_TpFunctions.ttcn 19.4 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480
/**
 *    @author   ETSI STF517
 *    @version  $URL$
 *              $Id$
 *    @desc     MAPEM TP functions
 *
 */

module ItsMapem_TpFunctions {
    
    // LibCommon
    import from LibCommon_BasicTypesAndValues all;
    import from LibCommon_Sync all;
    import from LibCommon_VerdictControl all;
    import from LibCommon_Time all;
    
    // LibItsCommon
    import from LibItsCommon_Functions all;
    import from LibItsCommon_TypesAndValues all;
    
    // LibIts
    import from ITS_Container language "ASN.1:1997" all;
    import from MAPEM_PDU_Descriptions language "ASN.1:1997" all;
    import from SPATEM_PDU_Descriptions language "ASN.1:1997" all;
    import from DSRC language "ASN.1:1997" all;
    
    // LibItsMapemSpatem
    import from LibItsMapemSpatem_TestSystem all;
    import from LibItsMapemSpatem_Functions all;
    import from LibItsMapemSpatem_Templates all;
    import from LibItsMapemSpatem_TypesAndValues all;
    import from LibItsMapemSpatem_Pics all;
    
    group mapeMessageDissemination { 
        
        group mapeMessageFormat { 
            
            /**
             * @desc    TP Function for TC_IS_RLT_MSGF_BV_01
             */
            function f_IS_RLT_MSGF_BV_01 () runs on ItsMapemSpatem {
                
                // Local variables
                
                // Test control
                if (not PICS_RSU or not PICS_MAPEM_GENERATION) {
                    log("*** " & testcasename() & ": PICS_RSU  and PICS_MAPEM_GENERATION required for executing the TC ***");
                    setverdict(inconc);
                    stop;
                }
                
                // Test component configuration
                f_cfUp();
                    
                // Preamble
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                // Test Body
                tc_ac.start;
                alt {
                    [] mapemSpatemPort.receive(
                        mw_mapemInd(
                            mw_mapemPdu
                    )) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Successfully received MAPEM PDU header. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Timeout while awaiting the reception of a message. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // End of function f_IS_RLT_MSGF_BV_01
            
        } // End of group mapeMessageFormat
        
        group mapeMessageEventGeneration { 
            
            /**
             * @desc    TP Function for TC_IS_RLT_EVGN_BV_01
             */
            function f_IS_RLT_EVGN_BV_01 () runs on ItsMapemSpatem {
                
                // Local variables
                
                // Test control
                if (not PICS_RSU or not PICS_MAPEM_GENERATION) {
                    log("*** " & testcasename() & ": PICS_RSU  and PICS_MAPEM_GENERATION required for executing the TC ***");
                    setverdict(inconc);
                    stop;
                }
                
                // Test component configuration
                f_cfUp();
                    
                // Preamble
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                // Test Body
                tc_ac.start;
                alt {
                    [] mapemSpatemPort.receive(
                        mw_mapemInd(
                            mw_mapemPdu(
                                mw_mapemWellFormatted
                    ))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Successfully received MAPEM. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] mapemSpatemPort.receive(
                        mw_mapemInd(
                            mw_mapemPdu(
                                mw_defaultMapem
                    ))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": FAIL: Received a MAPEM with incorrect information. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Timeout while awaiting the reception of a message. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // End of function f_IS_RLT_EVGN_BV_01
            
            /**
             * @desc    TP Function for TC_IS_RLT_EVGN_BV_02
             */
            function f_IS_RLT_EVGN_BV_02 () runs on ItsMapemSpatem {
                
                // Local variables
                var MapemInd v_mapem;
                
                // Test control
                if (not PICS_RSU or not PICS_MAPEM_GENERATION) {
                    log("*** " & testcasename() & ": PICS_RSU  and PICS_MAPEM_GENERATION required for executing the TC ***");
                    setverdict(inconc);
                    stop;
                }
                
                // Test component configuration
                f_cfUp();
                    
                // Preamble
                f_awaitMapeMessage(
                    mw_mapemInd(
                        mw_mapemPdu(
                            mw_defaultMapem
                    )),
                    v_mapem
                );
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                // Test Body
                f_utTriggerEvent(m_utTriggerEvent(mapemNewContent));
                tc_ac.start;
                alt {
                    [] mapemSpatemPort.receive(v_mapem) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": FAIL: The same MAPEM was received. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_error);
                    }
                    [] mapemSpatemPort.receive(
                        mw_mapemInd(
                            mw_mapemPdu(
                                mw_mapemWellFormatted
                    ))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Successfully received a new MAPEM. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] mapemSpatemPort.receive(
                        mw_mapemInd(
                            mw_mapemPdu(
                                mw_defaultMapem
                    ))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": FAIL: Received a MAPEM with incorrect information. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Timeout while awaiting the reception of a message. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // End of function f_IS_RLT_EVGN_BV_02
            
        } // End of group mapeMessageEventGeneration
        
        group mapeCommunication {
            
            /**
             * @desc    TP Function for TC_IS_RLT_COMM_BV_01
             */
            function f_IS_RLT_COMM_BV_01 () runs on ItsMapemSpatem {
                
                // Local variables
                
                // Test control
                if (not PICS_RSU or not PICS_MAPEM_GENERATION or not PICS_SPATEM_GENERATION) {
                    log("*** " & testcasename() & ": PICS_RSU  and PICS_MAPEM_GENERATION and PICS_SPATEM_GENERATION required for executing the TC ***");
                    setverdict(inconc);
                    stop;
                }
                
                // Test component configuration
                f_cfUp();
                    
                // Preamble
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                // Test Body
                tc_ac.start;
                alt {
                    [] mapemSpatemPort.receive(
                        mw_mapemInd(
                            mw_mapemPdu(
                                mw_mapemWellFormatted
                    ))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": INFO: Successfully received well-formed MAPEM. ***");
                        f_utTriggerEvent(m_utTriggerEvent(startTLMService));
                        tc_ac.start;
                        repeat;
                    }
                    [] mapemSpatemPort.receive(
                        mw_spatemInd(
                            mw_spatemPdu(
                                mw_spatemWellFormatted
                    ))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Successfully received well-formed MAPEM & SPATEM. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Timeout while awaiting the reception of a message. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_utTriggerEvent(m_utTriggerEvent(stopTLMService));
                f_poDefault();
                f_cfDown();
                
            } // End of function f_IS_RLT_COMM_BV_01
            
            /**
             * @desc    TP Function for TC_IS_RLT_COMM_BV_02_01
             */
            function f_IS_RLT_COMM_BV_02_01 () runs on ItsMapemSpatem {
                
                // Local variables
                const UInt8 c_gnNhBtpB := 2;
                
                // Test component configuration
                f_cfUp();
                
                // Preamble
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                
                // Test Body
                tc_ac.start;
                alt {
                    [] mapemSpatemPort.receive(
                        mw_mapemIndWithGnParameters(
                           mw_mapemPdu(
                               mw_mapemWellFormatted
                           ), 
                           c_gnNhBtpB
                    )) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Expected MAPEM message encapsultated in BTP-B packet received. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] mapemSpatemPort.receive(mw_mapemIndWithGnParameters(mw_mapemPdu(mw_mapemWellFormatted), omit)) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": INCONC: no GN NH information in MapemInd ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);  
                    }                    
                    [] mapemSpatemPort.receive(mw_mapemInd(mw_mapemPdu(mw_defaultMapem))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": FAIL: Expected MAPEM message received, but not encapsulated in BTP-B packet ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_error);  
                    }                    
                    []    tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Timeout while awaiting the reception of a message. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // End of function f_IS_RLT_COMM_BV_02_01
            
            /**
             * @desc    TP Function for TC_IS_RLT_COMM_BV_02_02
             */
            function f_IS_RLT_COMM_BV_02_02 () runs on ItsMapemSpatem {
                
                // Local variables
                const UInt16 c_gnNhBtpBPort := 2003;
                
                // Test component configuration
                f_cfUp();
                
                // Preamble
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                
                // Test Body
                tc_ac.start;
                alt {
                    [] mapemSpatemPort.receive(
                        mw_mapemIndWithBtpParameters(
                           mw_mapemPdu, 
                           c_gnNhBtpBPort,
                           0
                    )) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Expected MAPEM message encapsultated in BTP packet with port value 2003 received. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] mapemSpatemPort.receive(mw_mapemInd(mw_mapemPdu(mw_defaultMapem))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": FAIL: Expected MAPEM message received, but not addressed to the correct destination port. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_error);  
                    }                    
                    []    tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Timeout while awaiting the reception of a message. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // End of function f_IS_RLT_COMM_BV_02_02
            
            /**
             * @desc    TP Function for TC_IS_RLT_COMM_BV_03
             */
            function f_IS_RLT_COMM_BV_03 () runs on ItsMapemSpatem {
                
                // Local variables
                const UInt8 c_gnHtGbc := 4;
                
                // Test control
                if (not PICS_RSU or not PICS_MAPEM_GENERATION) {
                    log("*** " & testcasename() & ": PICS_RSU  and PICS_MAPEM_GENERATION required for executing the TC ***");
                    setverdict(inconc);
                    stop;
                }
                
                // Test component configuration
                f_cfUp();
                    
                // Preamble
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                // Test Body
                tc_ac.start;
                alt {
                    [] mapemSpatemPort.receive(
                        mw_mapemIndWithGnParameters(
                            mw_mapemPdu(
                                mw_mapemWellFormatted
                            ),
                            -, 
                            c_gnHtGbc
                    )) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Expected DENM message encapsulated in GBC packet received. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
                    }
                    [] mapemSpatemPort.receive(
                        mw_mapemIndWithGnParameters(
                            mw_mapemPdu(
                                mw_mapemWellFormatted
                            ),
                            -, 
                            omit
                    )) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": FAIL: no GN HT information in MapemInd. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_error);
                    }
                    [] mapemSpatemPort.receive(
                        mw_spatemInd(
                            mw_spatemPdu(
                                mw_spatemWellFormatted
                    ))) { 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": FAIL:  Expected MAPEM received, but not encapsulated in GBC packet. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_error);
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Timeout while awaiting the reception of a message. ***");
                        f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_utTriggerEvent(m_utTriggerEvent(stopTLMService));
                f_poDefault();
                f_cfDown();
                
            } // End of function f_IS_RLT_COMM_BV_03
            
        } // End of group mapeCommunication 
        
    } // End of group mapeMessageDissemination
    
    group mapeMessageProcessing {
        
        /**
         * @desc    TP Function for TC_IS_RLT_MSGF_BV_02
         */
        function f_IS_RLT_MSGF_BV_02 () runs on ItsMapemSpatem {
            
            // Local variables
            var MapemReq   v_mapemReq;
            var integer     i;
                
            if (PICS_RSU or not PICS_MAPEM_RECEPTION) {
                log("*** " & testcasename() & ": not PICS_RSU and PICS_MAPEM_RECEPTION required for executing the TC ***");
                setverdict(inconc);
                stop;
            }
                
            // Test component configuration
            f_cfUp();
                
            // Preamble
            f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                
            // Test Body
            v_mapemReq := valueof(m_mapemReq(m_mapemPdu(m_defaultMapem)));
            mapemSpatemPort.send(v_mapemReq) ;
                
            f_sleep(PX_TAC);
            for (i := 0; i < lengthof(vc_utMapemEvents) and not match (v_mapemReq.msgOut , vc_utMapemEvents[i].mapeMsg); i := i + 1) {
                // empty on purpose 
            }
            if (i < lengthof(vc_utMapemEvents) ) {
                log("*** " & testcasename() & ": PASS: MAPEM was transmitted to upper layer ***");
                f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
            } else {
                log("*** " & testcasename() & ": FAIL: MAPEM was not transmitted to upper layer ***");
                f_selfOrClientSyncAndVerdict(c_tbDone, e_error);
            }
                
            // Postamble
            f_poDefault();
            f_cfDown();
                
        } // End of function f_IS_RLT_MSGF_BV_02
        
    } // End of group mapeMessageProcessing
    
} // End of module ItsMapem_TpFunctions