/*****************************************************************
 ** @author   STF 470
 ** @version  0.0.1
 ** @purpose  1:22.4, Verify behaviour of any port.check(getreply) in case of unsuccessful match in standalone statement
 ** @verdict  pass accept, ttcn3verdict:pass
 *****************************************************************/
module Sem_2204_the_check_operation_063 {

	signature S(out integer p_par1) return integer;
	type port P procedure {
		inout S;
	}

    type component GeneralComp {
		port P p1, p2;
	}

	function f() runs on GeneralComp {
		p2.getcall;
		setverdict(pass, "Call received");
		p2.reply(S:{ p_par1 := 1} value 5);
	}

	altstep a() runs on GeneralComp {
		[] any port.getreply {
			setverdict(pass, "As expected, the check operation didn't match");
			stop;
		}
	}

	testcase TC_Sem_2204_the_check_operation_063() runs on GeneralComp system GeneralComp{
		var GeneralComp v_ptc := GeneralComp.create;
		activate(a());
		connect(self:p1, v_ptc:p1);
		connect(self:p2, v_ptc:p2);
		p2.call(S:{ p_par1 := - }, nowait);
		v_ptc.start(f());
        any port.check(getreply(S:? value ?) from self);
		setverdict(fail, "Incorrect match");
    }

    control {
        execute(TC_Sem_2204_the_check_operation_063(), 5.0);
    }
}