/*****************************************************************
 ** @author   STF 470
 ** @version  0.0.1
 ** @purpose  1:22.4, Verify behaviour of any port.check(getcall) with assignment in case of unsuccessful match in standalone statement
 ** @verdict  pass accept, ttcn3verdict:pass
 *****************************************************************/
module Sem_2204_the_check_operation_040 {

	signature S(integer p_par1);
	type port P procedure {
		inout S;
	}

    type component GeneralComp {
		port P p1, p2;
		var integer v_val;
	}

	altstep a() runs on GeneralComp {
		[] any port.getcall {
			if (not isbound(v_val)) { setverdict(pass, "As expected, the check operation didn't match"); }
			else { setverdict(fail, "The value should still be undefined at this point"); }
			stop;
		}
	}

	function f() runs on GeneralComp {
		activate(a());
        any port.check(getcall(S:{ p_par1 := (0..10)}) from self -> param(v_val := p_par1));
		setverdict(fail, "Incorrect match");
	}

	testcase TC_Sem_2204_the_check_operation_040() runs on GeneralComp system GeneralComp{
		var GeneralComp v_ptc := GeneralComp.create;
		connect(self:p1, v_ptc:p1);
		connect(self:p2, v_ptc:p2);
		p2.call(S:{ p_par1 := 1 }, nowait);
		v_ptc.start(f());
		v_ptc.done;
    }

    control {
        execute(TC_Sem_2204_the_check_operation_040(), 5.0);
    }
}