Add UEinformationAPI tests

ttcn/AtsMec/AtsMec_UEinformation_TestCases.ttcn

+/**
+ *    @author   ETSI / STF569
+ *    @version  $URL:$
+ *              $ID:$
+ *    @desc     This module provides the MEC test cases.
+ *    @copyright   ETSI Copyright Notification
+ *                 No part may be reproduced except as authorized by written permission.
+ *                 The copyright and the foregoing restriction extend to reproduction in all media.
+ *                 All rights reserved.
+ *    @see      ETSI GS MEC 003, Draft ETSI GS MEC 013 V2.0.3 (2018-10)
+ */
+module AtsMec_UEinformation_TestCases {
+  
+  // Libcommon
+  import from LibCommon_Time all;
+  import from LibCommon_VerdictControl all;
+  import from LibCommon_Sync all;
+  
+  // LibHttp
+  import from LibItsHttp_TypesAndValues all;
+  import from LibItsHttp_Functions all;
+  import from LibItsHttp_Templates all;
+  import from LibItsHttp_JsonTemplates all;
+  import from LibItsHttp_TestSystem all;
+  
+  // LibMec_LocationAPI
+  import from LocationAPI_TypesAndValues all;
+  import from LocationAPI_Templates all;
+  import from LocationAPI_Pics all;
+  import from LocationAPI_Pixits all;
+  
+  // LibMec
+  import from LibMec_Functions all;
+  import from LibMec_Pics all;
+  import from LibMec_Pixits all;
+  
+  group me_app_role {
+    
+    /**
+     * @desc Check that the IUT responds with the information pertaining to one or more UEs in a particular location when queried by a MEC Application
+     * @see https://forge.etsi.org/gitlab/mec/MEC-tests/blob/master/Test%20Purposes/Plat/Mp1/UeInformation/PlatUeInformation.tplan2
+     */
+    testcase TC_MEC_PLAT_MP1_INF_BV_001() runs on HttpComponent system HttpTestAdapter {
+        // Local variables
+        var HeaderLines v_headers;
+        var HttpMessage v_response;
+        
+        // Test control
+        if (not(PICS_ME_APP_IUT) or not(PICS_LOCATION_API_SUPPORTED)) {
+            log("*** " & testcasename() & ": PICS_ME_APP_IUT and PICS_LOCATION_API_SUPPORTED required for executing the TC ***");
+            setverdict(inconc);
+            stop;
+        }
+        
+        // Test component configuration
+        f_cf_01_http_up();
+        
+        // Test adapter configuration
+        
+        // Preamble
+        f_init_default_headers_list(-, -, v_headers);
+        httpPort.send(
+                      m_http_request(
+                                     m_http_request_get(
+                                                        PICS_ME_APP_Q_USERS_LIST_URI & oct2char(unichar2oct(PX_ZONE_ID, "UTF-8")),
+                                                        v_headers
+                                                        )
+                                     )
+                      );
+        f_selfOrClientSyncAndVerdict(c_prDone, e_success);
+        
+        // Test Body
+        tc_ac.start;
+        alt {
+          [] httpPort.receive(
+                              mw_http_response(
+                                               mw_http_response_ok(
+                                                                   mw_http_message_body_json(
+                                                                                             mw_body_json_user_list(
+                                                                                                                    mw_user_list(-, ?)
+                                                                                                                    ))))) -> value v_response {
+            log("*** " & testcasename() & ": PASS: IUT successfully responds with a UserList ***");
+            f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
+          }
+          [] tc_ac.timeout {
+            log("*** " & testcasename() & ": INCONC: Expected message not received ***");
+            f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
+          }
+        } // End of 'alt' statement
+        
+        // Postamble
+        f_cf_01_http_down();
+    } // End of testcase TC_MEC_PLAT_MP1_INF_BV_001
+    
+  } // End of group me_app_role 
+  
+} // End of module AtsMec_UEinformation_TestCases