/*
Copyright (c) ETSI 2019.

This software is subject to copyrights owned by ETSI. Non-exclusive permission
is hereby granted, free of charge, to copy, reproduce and amend this file
under the following conditions: It is provided "as is", without warranty of any
kind, expressed or implied.

ETSI shall never be liable for any claim, damages, or other liability arising
from its use or inability of use.This permission does not apply to any documentation
associated with this file for which ETSI keeps all rights reserved. The present
copyright notice shall be included in all copies of whole or part of this
file and shall not imply any sub-license right.
*/


Package TP_S9 {
    
    import all from Sip_Common;
    import all from Diameter_Common;
    
    Test Purpose {
        TP Id TP_S9_PCRF_AAR_01
        //TP_EPC_8001_07 from TS 103 029 V5.1.1
        Test objective  "Verify that IUT receives AA-Request from visited P-CSCS and it sends AA-Request towards home PCRF."
        
        Reference 
            "TS 129 215 (V15.3.0) [11], clause 4.5.3.6"
        
        Config Id CF_VxLTE_RMI
        
        PICS Selection NONE
        
        Initial conditions with {
            the UE_A entity isAttachedTo the EPC_B and
            the UE_A entity isRegisteredTo the IMS_A
        }
        
        Expected behaviour
            ensure that {
                when {
                    the IMS_P_CSCF_B entity sends a AAR
                    to the EPC_PCRF_B entity
                }
                then {
                    the EPC_PCRF_B entity sends the AAR 
                    to the EPC_PCRF_A entity
                }
            }  
    }  // End of TP_S9_PCRF_AAR_01
     
    Test Purpose {
        TP Id TP_S9_PCRF_AAA_01
        //TP_EPC_8001_08 from TS 103 029 V5.1.1
        Test objective  "Verify when IUT receives AA-Request from visited PCRF then it sends a AA-Answer."
        
        Reference 
            "TS 129 215 (V15.3.0) [11], clause 4.5.3.6"
        
        Config Id CF_VxLTE_RMI
        
        PICS Selection NONE
        
        Initial conditions with {
        	the UE_A entity isNotAttachedTo the EPC_B and
            the UE_A entity isNotRegisteredTo the IMS_A
        }
        
        Expected behaviour
            ensure that {
                when {
                    the EPC_PCRF_B entity sends a AAR
                    to the EPC_PCRF_A entity
                }
                then {
                    the EPC_PCRF_A entity sends a AAA containing
                        Result_Code_AVP
                            indicating value DIAMETER_SUCCESS
                        Acceptable_Service_Info_AVP containing
                            "one or more" Media_Component_Description_AVP containing
                                Media_Component_Number_AVP
                                    indicating value 0,
                                Media_Sub_Component_AVP containing
                                    Flow_Description_AVP
                                        indicating value 
                                        "permit_in_ip from (UE_A-IP_address and  UE_A_port_number) to (P-CSCF-IP_address and P-CSCF_port_number) or
                                         permit_in_udp from (UE_A-IP_address and UE_A_port_number) to (P-CSCF-IP_address and P-CSCF_port_number) or
                                         permit_in_tcp from (UE_A-IP_address and UE_A_port_number) to (P-CSCF-IP_address and P-CSCF_port_number)",
                                    Flow_Description_AVP
                                        indicating value 
                                        "permit_out_ip from (P-CSCF-IP_address P-CSCF_port_number) to UE_A-IP_address or
                                         permit_out_udp from (P-CSCF-IP_address P-CSCF_port_number) to UE_A-IP_address or
                                         permit_out_tcp from (P-CSCF-IP_address P-CSCF_port_number) to UE_A-IP_address",
                                    Flow_Usage_AVP
                                        indicating value AF_SIGNALING,
                                    Flow_Status_AVP
                                        indicating value ENABLED,
                                    AF_Signalling_Protocol_AVP
                                        indicating value SIP
                                ;
                            ;
                        ;,
                        IP_CAN_AVP
                        RAT_Type_AVP
                    ;
                    to the EPC_PCRF_B entity
                }
            }  
    }  // End of TP_S9_PCRF_AAA_01
     
    Test Purpose {
        TP Id TP_S9_PCRF_AAA_02
        //TP_EPC_8002_02 from TS 103 029 V5.1.1
        Test objective  "Verify when IUT receives AA-Request from visited PCRF then it sends a AA-Answer."
        
        Reference 
            "TS 129 215 (V15.3.0) [11], clause 4.5.3.6"
        
        Config Id CF_VxLTE_RMI
        
        PICS Selection NONE
        
        Initial conditions with {
        	the UE_A entity isNotAttachedTo the EPC_B and
            the UE_A entity isNotRegisteredTo the IMS_A
        }
        
        Expected behaviour
            ensure that {
                when {
                    the EPC_PCRF_B entity sends a AAR
                    to the EPC_PCRF_A entity
                }
                then {
                    the EPC_PCRF_A entity sends a AAA containing
                        Result_Code_AVP
                            indicating value DIAMETER_SUCCESS
                        Acceptable_Service_Info_AVP containing
                            "one or more" Media_Component_Description_AVP
                        ;
                    ;
                    to the EPC_PCRF_B entity
                }
            }  
    }  // End of TP_S9_PCRF_AAA_02
     
    Test Purpose {
        TP Id TP_S9_PCRF_CCR_01
        //TP_EPC_8001_04 from TS 103 029 V5.1.1
        Test objective  "Verify that IUT receives CC-Request from P-GW and it sends CC-Request towards home PCRF."
        
        Reference 
            "TS 129 215 (V15.3.0) [11], clauses 4.5.1.1 and 4.5.3.1"
        
        Config Id CF_VxLTE_RMI
        
        PICS Selection NONE
        
        Initial conditions with {
        	the UE_A entity isNotAttachedTo the EPC_B and
            the UE_A entity isNotRegisteredTo the IMS_A
        }
        
        Expected behaviour
            ensure that {
                when {
                    the EPC_PGW_B entity sends an CCR
                    to the EPC_PCRF_B entity
                }
                then {
                    the EPC_PCRF_B entity sends an CCR containing
                        CC_Request_Type_AVP
                            indicating value INITIAL_REQUEST
                        Subscription_Id_AVP containing
                            Subscription_Id_Type_AVP
                                indicating value END_USER_IMSI
                            ;,
                        IP_CAN_Type_AVP
                        RAT_Type_AVP
                        Called_Station_Id_AVP
                        PDN_Connection_Id_AVP
                        Framed_IP_Address_AVP
                        "or" Framed_IP6_IP_Address_AVP
                        Bearer_Usage_AVP
                            indicating value IMS_SIGNALLING
                        QoS_Information_AVP
                            APN_Aggregate_Max_Requested_Bandwidth_UL_AVP
                            APN_Aggregate_Max_Requested_Bandwidth_DL_AVP
                            Bearer_Identifier_AVP
                        Default_EPS_Bearer_QoS_AVP containing
                            QoS_Class_Identifier_AVP
                                indicating value '5'
                            Allocation_Retention_Priority_AVP containing
                                Priority_Level_AVP
                                Pre_emption_Capablity_AVP
                                Pre_emption_Vulnerability_AVP
                            ;
                        ;,
                        Subsession_Enforcement_Info_AVP containing
                            Subsession_Id_AVP
                            Subsession_Operation_AVP
                                indicating value ESTABLISHMENT
                        ;
                    ;
                    to the EPC_PCRF_A entity
                }
            }  
    }  // End of TP_S9_PCRF_CCR_01
     
    Test Purpose {
        TP Id TP_S9_PCRF_CCA_01
        //TP_EPC_8001_05 from TS 103 029 V5.1.1
        Test objective  "Verify when IUT receives CC-Request from visited PCRF then it sends a CC-Answer."
        
        Reference 
            "TS 129 215 (V15.3.0) [11], clauses 4.5.1.1 and 4.5.3.1"
        
        Config Id CF_VxLTE_RMI
        
        PICS Selection NONE
        
        Initial conditions with {
        	the UE_A entity isNotAttachedTo the EPC_B and
            the UE_A entity isNotRegisteredTo the IMS_A
        }
        
        Expected behaviour
            ensure that {
                when {
                    the EPC_PCRF_B entity sends a CCR
                    to the EPC_PCRF_A entity
                }
                then {
                    the EPC_PCRF_A entity sends a CCA containing
                        Result_Code_AVP
                            indicating value DIAMETER_SUCCESS
                        Subsession_Decision_Info_AVP containing
                            Subsession_Id_AVP
                            QoS_Information_AVP containing
                                APN_Aggregate_Max_Requested_Bandwidth_UL_AVP
                                APN_Aggregate_Max_Requested_Bandwidth_DL_AVP
                                Bearer_Identifier_AVP;,
                            Default_EPS_Bearer_QoS_AVP containing
                                QoS_Class_Identifier_AVP
                                    indicating value '5'
                                Allocation_Retention_Priority_AVP containing
                                    Priority_Level_AVP
                                    Pre_emption_Capablity_AVP
                                    Pre_emption_Vulnerability_AVP
                                ;
                            ;
                        ;
                    ;
                    to the EPC_PCRF_B entity
                }
            }  
    }  // End of TP_S9_PCRF_CCA_01
    
    Test Purpose {
        TP Id TP_S9_PCRF_STR_01
        //TP_EPC_8002_04 from TS 103 029 V5.1.1
        Test objective  "Verify that IUT receives ST-Request from visited P-CSCS and it sends ST-Request towards home PCRF."
        
        Reference 
            "TS 129 215 (V15.3.0) [11], clause 4.5.3.6"
        
        Config Id CF_VxLTE_RMI
        
        PICS Selection NONE
        
        Initial conditions with {
            the UE_A entity isAttachedTo the EPC_B and
            the UE_A entity isRegisteredTo the IMS_A
        }
        
        Expected behaviour
            ensure that {
                when {
                    the IMS_P_CSCF_B entity sends a STR
                    to the EPC_PCRF_B entity
                }
                then {
                    the EPC_PCRF_B entity sends the STR 
                    to the EPC_PCRF_A entity
                }
            }  
    }  // End of TP_S9_PCRF_STR_01
     
    Test Purpose {
        TP Id TP_S9_PCRF_STA_01
        //TP_EPC_8002_05 from TS 103 029 V5.1.1
        Test objective  "Verify when IUT receives ST-Request from visited PCRF then it sends a ST-Answer."
        
        Reference 
            "TS 129 215 (V15.3.0) [11], clause 4.5.3.6"
        
        Config Id CF_VxLTE_RMI
        
        PICS Selection NONE
        
        Initial conditions with {
        	the UE_A entity isNotAttachedTo the EPC_B and
            the UE_A entity isNotRegisteredTo the IMS_A
        }
        
        Expected behaviour
            ensure that {
                when {
                    the EPC_PCRF_B entity sends a STR
                    to the EPC_PCRF_A entity
                }
                then {
                    the EPC_PCRF_A entity sends a STA containing
                        Result_Code_AVP
                            indicating value DIAMETER_SUCCESS
                    ;
                    to the EPC_PCRF_B entity
                }
            }  
    }  // End of TP_S9_PCRF_STA_01
    
} // End of Package TP_S9