add test purposes for aml (416f6950) · Commits · EMTEL - Emergency Communications / NG112 Conformance Test Suites

test_purposes/aml/aml_commons.tplan2

0 → 100644

+116 −0

Original line number	Diff line number	Diff line
		Package aml_commons {
		Domain {
		pics:
		- PICS_SMS_SUPPORT
		- PICS_HTTPS_SUPPORT
		;
		entities:
		- USER
		- IUT // The end-user device
		- SMS_ENDPOINT
		- HTTPS_ENDPOINT
		;
		events:
		- configured
		- sends
		- initiates
		- determines
		- has_no_record_of
		- is_triggered_to_perform
		;
		event templates:
		- "Emergency Call is triggered" {
		the IUT entity initiates an emergency sms
		}
		;
		}
		Data {
		type IMSI;

		type Config
		with
		"SMS_ENDPOINT" of type Number
		;


		type AML_SMS
		with
		"A\"ML" of type Number,
		"lt" of type DecimalDegrees,
		"lg" of type DecimalDegrees,
		"rd" of type Number,
		"top" of type UTCString,
		"lc" of type LevelOfConfidence,
		"pm" of type PositioningMethod,
		"si" of type IMSI,
		"ei" of type Number,
		"mcc" of type Number,
		"mnc" of type Number,
		"ml" of type Number
		;

		type HTTP_MESSAGE
		with
		"Body" of type AML_BODY,
		"ContentType" of type String,
		"Method" of type String
		;

		type AML_BODY
		with
		"location_latitude" of type DecimalDegrees,
		"location_longitude" of type DecimalDegrees,
		"location_accuracy" of type Number,
		"location_time" of type Number,
		"location_source" of type String,
		"location_confidence" of type Number,
		"device_imsi" of type Number,
		"device_imei" of type Number,
		"cell_network_mcc" of type Number,
		"cell_network_mnc" of type Number,
		optional "v" of type Number,
		optional "emergency_number" of type String,
		optional "source" of type String,
		optional "os_version" of type String,
		optional "time" of type Number,
		optional "gt_location_latitude" of type DecimalDegrees,
		optional "gt_location_longitude" of type DecimalDegrees,
		optional "location_altitude" of type Number,
		optional "location_vertical_accuracy" of type Number,
		optional "location_bearing" of type Number,
		optional "location_speed" of type Number,
		optional "device_number" of type String,
		optional "device_model" of type String,
		optional "device_iccid" of type Number,
		optional "cell_home_mcc" of type Number,
		optional "cell_home_mnc" of type Number
		;

		type LevelOfConfidence;
		type DecimalDegrees;
		type Number;
		type String;
		type PositioningMethod;
		type UTCString; // YYYYMMDDhhmmss
		type AML_SMS_FORMAT;
		type Radius; // Numeric or 'N'

		Number AML_VERSION; // 1

		PositioningMethod POSITIONING_SUCCESS; // W = WIFI, G = GNSS, C = CELL
		PositioningMethod POSITIONING_FAILURE; // N
		Number LEVEL_OF_CONFIDENCE; // The Level of Confidence is a percentage probability that the mobile handset is within the area being communicated


		// ######
		// PIXITS
		DecimalDegrees PX_LATITUDE; // The WGS84 latitude of the center of the location area given in decimal degrees using 5 decimal places giving resolution to 1.1 meters
		DecimalDegrees PX_LONGITUDE; // The WGS84 longitude of the center of the location area given in decimal degrees using 5 decimal places giving resolution to 1.1 meters


		Number PX_IMSI; // The SIM card identifier of the handset
		Number PX_IMEI; // The identifier of the handset that
		Number PX_MCC; // Mobile Country Code
		Number PX_MNC; // Mobile Network Code
		}
		}
		No newline at end of file

test_purposes/aml/aml_tps.tplan2

0 → 100644

+407 −0

Original line number	Diff line number	Diff line
		Package AML {
		Group 'SMS Transmission' {
		import all from aml_commons;

		Test Purpose {
		TP Id TP_AML_SMS_BV_01

		Test objective
		"Verify that the IUT automatically sends AML via SMS when an emergency call is initiated"

		Reference
		"ETSI TS 103 625 V1.1.1, clause 5.2 paragraph 2"

		PICS Selection PICS_SMS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the SMS_ENDPOINT entity
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity initiates an emergency call
		}
		then {
		the IUT entity sends an AML_SMS to the SMS_ENDPOINT entity
		}
		}
		}

		Test Purpose {
		TP Id TP_AML_SMS_BV_02

		Test objective
		"Verify that the IUT automatically sends AML via SMS when an emergency SMS is sent"

		Reference
		"ETSI TS 103 625 V1.1.1, clause 5.2 paragraph 3"

		PICS Selection PICS_SMS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the SMS_ENDPOINT entity
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity initiates an emergency sms
		}
		then {
		the IUT entity sends an AML_SMS to the SMS_ENDPOINT entity
		}
		}
		}

		Test Purpose {
		TP Id TP_AML_SMS_BV_03

		Test objective
		"Verify the SMS format and values of the AML SMS message"

		Reference
		"ETSI TS 103 625 V1.1.1, Annex A, table A.1"

		PICS Selection PICS_SMS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the SMS_ENDPOINT entity
		and the IUT entity determines a Location
		containing
		latitude indicating value close_to PX_LATITUDE,
		longitude indicating value close_to PX_LONGITUDE
		;
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity is_triggered_to_perform an emergency call
		}
		then {
		the IUT entity sends an AML_SMS containing
		User_Data containing
		"AM\"L" indicating value AML_VERSION,
		"lt" indicating value close_to PX_LATITUDE,
		"lg" indicating value close_to PX_LONGITUDE,
		"rd" containing Number
		indicating value "the radius of the location area in meters";,
		"top" containing UTCString
		indicating value "when the location was determined";,
		"lc" containing Number
		indicating value "the level of confidence";,
		"pm" indicating value "('G' \| 'W' \| 'C')",
		"si" corresponding to PX_IMSI,
		"ei" corresponding to PX_IMEI,
		"mcc" corresponding to PX_MCC,
		"mnc" corresponding to PX_MNC,
		"ml" derived from the value of AML_SMS;
		;
		to the SMS_ENDPOINT entity
		}
		}
		}

		Test Purpose {
		TP Id TP_AML_SMS_BV_04

		Test objective
		"Verify that the IUT sends AML via SMS within the timeout T1"

		Reference
		"ETSI TS 103 625 V1.1.1, clause 5.1 paragraph 1-2"

		PICS Selection PICS_SMS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the SMS_ENDPOINT entity
		and the IUT entity is configured the timeout T1
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity initiates an emergency call
		}
		then {
		the IUT entity sends an AML_SMS "within" timeout T1
		to the SMS_ENDPOINT entity
		}
		}
		}

		Test Purpose {
		TP Id TP_AML_SMS_BV_05

		Test objective
		"Verify the SMS format and values of the AML message when no location can be determined"

		Reference
		"ETSI TS 103 625 V1.1.1, Annex A, table A.1"

		PICS Selection PICS_SMS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the SMS_ENDPOINT entity
		and the IUT entity not determines a Location
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity initiates an emergency call
		}
		then {
		the IUT entity sends an AML_SMS_MESSAGE containing
		User_Data containing
		"AM\"L" indicating value AML_VERSION,
		"lt" set to '+00.00000',
		"lg" set to '+000.00000',
		"rd" set to N,
		"top" containing UTCString
		indicating value "when location process was deemed to have failed";,
		"lc" set to 0,
		"pm" set to N,
		"si" set to PX_IMSI,
		"ei" set to PX_IMEI,
		"mcc" set to PX_MCC,
		"mnc" set to PX_MNC,
		"ml" derived from the value of AML_SMS_MESSAGE;
		;
		to the SMS_ENDPOINT entity
		}
		}
		}


		Test Purpose {
		TP Id TP_AML_SMS_BV_06

		Test objective
		"Verify that no record of the AML message is available to the user"

		Reference
		"ETSI TS 103 625 V1.1.1, clause 5.2 paragraph 2"

		PICS Selection PICS_SMS_SUPPORT

		Expected behaviour
		ensure that {
		when {
		the IUT entity initiates an emergency call
		}
		then {
		the IUT entity sends an AML_SMS to the SMS_ENDPOINT entity
		and the USER entity has_no_record_of the AML_SMS
		}
		}
		}
		}

		Group 'HTTPs Transmission' {
		import all from aml_commons;

		Test Purpose {
		TP Id TP_AML_HTTPS_BV_01

		Test objective
		"Verify that the IUT automatically sends AML via HTTPs when an emergency call is initiated"

		Reference
		"ETSI TS 103 625 V1.1.1, clause 5.2 paragraph 2"

		PICS Selection PICS_HTTPS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the HTTPS_ENDPOINT entity
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity initiates an emergency call
		}
		then {
		the IUT entity sends an HTTP_MESSAGE containing
		Method set to 'POST',
		ContentType set to 'application/x-www-form-urlencoded',
		Body corresponding to any AML_BODY
		;
		to the HTTPS_ENDPOINT entity
		}
		}
		}

		Test Purpose {
		TP Id TP_AML_HTTPS_BV_02

		Test objective
		"Verify that the IUT automatically sends AML via HTTPs when an emergency SMS is sent"

		Reference
		"ETSI TS 103 625 V1.1.1, clause 5.2 paragraph 3"

		PICS Selection PICS_HTTPS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the HTTPS_ENDPOINT entity
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity initiates an emergency sms
		}
		then {
		the IUT entity sends an HTTP_MESSAGE containing
		Method set to 'POST',
		ContentType set to 'application/x-www-form-urlencoded',
		Body corresponding to any AML_BODY
		;
		to the HTTPS_ENDPOINT entity
		}
		}
		}

		Test Purpose {
		TP Id TP_AML_HTTPS_BV_03

		Test objective
		"Verify the HTTP Format of the AML message"

		Reference
		"ETSI TS 103 625 V1.1.1, Annex A, table A.1"

		PICS Selection PICS_HTTPS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the HTTPS_ENDPOINT entity
		and the IUT entity determines a Location
		containing
		latitude indicating value close_to PX_LATITUDE,
		longitude indicating value close_to PX_LONGITUDE
		;
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity is_triggered_to_perform an emergency call
		}
		then {
		the IUT entity sends an HTTP_MESSAGE containing
		Method set to 'POST',
		ContentType set to 'application/x-www-form-urlencoded',
		Body containing
		"location_latitude" indicating value close_to PX_LATITUDE,
		"location_longitude" indicating value close_to PX_LONGITUDE,
		"location_time" containing Number
		indicating value "when the location was determined";,
		"location_accuracy" containing Number
		indicating value "the radius of the location area in meters";,
		"location_source" indicating value "('gps' \| 'Wi-Fi' \| 'cell')",
		"location_confidence" containing Number
		indicating value "the level of confidence";,
		"device_imsi" corresponding to PX_IMSI,
		"device_imei" corresponding to PX_IMEI,
		"cell_network_mcc" corresponding to PX_MCC,
		"cell_network_mnc" corresponding to PX_MNC
		;
		;
		to the HTTPS_ENDPOINT entity
		}
		}
		}

		Test Purpose {
		TP Id TP_AML_HTTPS_BV_04

		Test objective
		"Verify that the IUT sends AML via HTTPs within the timeout T1"

		Reference
		"ETSI TS 103 625 V1.1.1, clause 5.1 paragraph 1-2"

		PICS Selection PICS_HTTPS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the HTTPS_ENDPOINT entity
		and the IUT entity is configured the timeout T1
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity initiates an emergency call
		}
		then {
		the IUT entity sends an HTTP_MESSAGE "within" timeout T1 containing
		Method set to 'POST',
		ContentType set to 'application/x-www-form-urlencoded',
		Body corresponding to any AML_BODY
		;
		to the HTTPS_ENDPOINT entity
		}
		}
		}

		Test Purpose {
		TP Id TP_AML_HTTPS_BV_05

		Test objective
		"Verify the HTTP format and values of the AML message when no location can be determined"

		Reference
		"ETSI TS 103 625 V1.1.1, clause 6.3.6.2, paragraph 3",
		"ETSI TS 103 625 V1.1.1, Annex A, table B.1"

		PICS Selection PICS_HTTPS_SUPPORT

		Initial conditions
		with {
		the IUT entity is configured to the HTTPS_ENDPOINT entity
		and the IUT entity not determines a Location
		}

		Expected behaviour
		ensure that {
		when {
		the IUT entity is_triggered_to_perform an emergency call
		}
		then {
		the IUT entity sends an HTTP_MESSAGE containing
		Method set to 'POST',
		ContentType set to 'application/x-www-form-urlencoded',
		Body containing
		"location_latitude" set to 0,
		"location_longitude" set to 0,
		"location_time" containing Number
		indicating value "when location process was deemed to have failed";,
		"location_source" set to 'Unknown',
		"location_accuracy" set to 0,
		"location_confidence" set to 0,
		"device_imsi" corresponding to PX_IMSI,
		"device_imei" corresponding to PX_IMEI,
		"cell_network_mcc" corresponding to PX_MCC,
		"cell_network_mnc" corresponding to PX_MNC
		;
		;
		to the HTTPS_ENDPOINT entity
		}
		}
		}
		}
		}