clean away old VMS cruft

TODO:

=====

There are a few things that need to be worked out in the VMS version of

OpenSSL, still:

- Description files. ("Makefile's" :-))

- Script code to link an already compiled build tree.

- A VMSINSTALlable version (way in the future, unless someone else hacks).

- shareable images (DLL for you Windows folks).

There may be other things that I have missed and that may be desirable.

Please send mail to <openssl-users@openssl.org> or to me directly if you

have any ideas.

--

Richard Levitte <richard@levitte.org>

1999-05-24

* Have the building procedure contain a LINK-only possibility.

  Wished by Mark Daniel <mark.daniel@dsto.defence.gov.au>

  One way to enable that is also to go over to DESCRIP.MMS files.

$! install-vms.com -- Installs the files in a given directory tree

$!

$! Author: Richard Levitte <richard@levitte.org>

$! Time of creation: 23-MAY-1998 19:22

$!

$! P1	root of the directory tree

$!

$!

$! Announce/identify.

$!

$ proc = f$environment( "procedure")

$ write sys$output "@@@ "+ -

   f$parse( proc, , , "name")+ f$parse( proc, , , "type")

$!

$ on error then goto tidy

$ on control_c then goto tidy

$!

$ if p1 .eqs. ""

$ then

$   write sys$output "First argument missing."

$   write sys$output -

     "Should be the directory where you want things installed."

$   exit

$ endif

$

$ if (f$getsyi( "cpu") .lt. 128)

$ then

$   arch = "VAX"

$ else

$   arch = f$edit( f$getsyi( "arch_name"), "upcase")

$   if (arch .eqs. "") then arch = "UNK"

$ endif

$

$ root = f$parse( P1, "[]A.;0", , , "SYNTAX_ONLY, NO_CONCEAL")- "A.;0"

$ root_dev = f$parse( root, , , "device", "syntax_only")

$ root_dir = f$parse( root, , , "directory", "syntax_only") - -

   "[000000." - "][" - "[" - "]"

$ root = root_dev + "[" + root_dir

$

$ define /nolog wrk_sslroot 'root'.] /translation_attributes = concealed

$ define /nolog wrk_sslinclude wrk_sslroot:[include]

$

$ if f$parse( "wrk_sslroot:[000000]") .eqs. "" then -

   create /directory /log wrk_sslroot:[000000]

$ if f$parse( "wrk_sslinclude:") .eqs. "" then -

   create /directory /log wrk_sslinclude:

$ if f$parse( "wrk_sslroot:[vms]") .eqs. "" then -

   create /directory /log wrk_sslroot:[vms]

$!

$ copy /log /protection = world:re openssl_startup.com wrk_sslroot:[vms]

$ copy /log /protection = world:re openssl_undo.com wrk_sslroot:[vms]

$ copy /log /protection = world:re openssl_utils.com wrk_sslroot:[vms]

$!

$ tidy:

$!

$ call deass wrk_sslroot

$ call deass wrk_sslinclude

$!

$ exit

$!

$ deass: subroutine

$ if (f$trnlnm( p1, "LNM$PROCESS") .nes. "")

$ then

$   deassign /process 'p1'

$ endif

$ endsubroutine

$!

multinet:multinet_socket_library.exe/share

$!

$! Startup file for OpenSSL 1.x.

$!

$! 2011-03-05 SMS.

$!

$! This procedure must reside in the OpenSSL installation directory.

$! It will fail if it is copied to a different location.

$!

$! P1  qualifier(s) for DEFINE.  For example, "/SYSTEM" to get the

$!     logical names defined in the system logical name table.

$!

$! P2  "64", to use executables which were built with 64-bit pointers.

$!

$! Good (default) and bad status values.

$!

$ status =    %x00010001 ! RMS$_NORMAL, normal successful completion.

$ rms_e_fnf = %x00018292 ! RMS$_FNF, file not found.

$!

$! Prepare for problems.

$!

$ orig_dev_dir = f$environment( "DEFAULT")

$ on control_y then goto clean_up

$ on error then goto clean_up

$!

$! Determine hardware architecture.

$!

$ if (f$getsyi( "cpu") .lt. 128)

$ then

$   arch_name = "VAX"

$ else

$   arch_name = f$edit( f$getsyi( "arch_name"), "upcase")

$   if (arch_name .eqs. "") then arch_name = "UNK"

$ endif

$!

$ if (p2 .eqs. "64")

$ then

$   arch_name_exe = arch_name+ "_64"

$ else

$   arch_name_exe = arch_name

$ endif

$!

$! Derive the OpenSSL installation device:[directory] from the location

$! of this command procedure.

$!

$ proc = f$environment( "procedure")

$ proc_dev_dir = f$parse( "A.;", proc, , , "no_conceal") - "A.;"

$ proc_dev = f$parse( proc_dev_dir, , , "device", "syntax_only")

$ proc_dir = f$parse( proc_dev_dir, , , "directory", "syntax_only") - -

   ".][000000"- "[000000."- "]["- "["- "]"

$ proc_dev_dir = proc_dev+ "["+ proc_dir+ "]"

$ set default 'proc_dev_dir'

$ set default [-]

$ ossl_dev_dir = f$environment( "default")

$!

$! Check existence of expected directories (to see if this procedure has

$! been moved away from its proper place).

$!

$ if ((f$search( "certs.dir;1") .eqs. "") .or. -

   (f$search( "include.dir;1") .eqs. "") .or. -

   (f$search( "private.dir;1") .eqs. "") .or. -

   (f$search( "vms.dir;1") .eqs. ""))

$ then

$    write sys$output -

      "   Can't find expected common OpenSSL directories in:"

$    write sys$output "   ''ossl_dev_dir'"

$    status = rms_e_fnf

$    goto clean_up

$ endif

$!

$ if ((f$search( "''arch_name_exe'_exe.dir;1") .eqs. "") .or. -

   (f$search( "''arch_name'_lib.dir;1") .eqs. ""))

$ then

$    write sys$output -

      "   Can't find expected architecture-specific OpenSSL directories in:"

$    write sys$output "   ''ossl_dev_dir'"

$    status = rms_e_fnf

$    goto clean_up

$ endif

$!

$! All seems well (enough).  Define the OpenSSL logical names.

$!

$ ossl_root = ossl_dev_dir- "]"+ ".]"

$ define /translation_attributes = concealed /nolog'p1 SSLROOT 'ossl_root'

$ define /nolog 'p1' SSLCERTS     sslroot:[certs]

$ define /nolog 'p1' SSLINCLUDE   sslroot:[include]

$ define /nolog 'p1' SSLPRIVATE   sslroot:[private]

$ define /nolog 'p1' SSLEXE       sslroot:['arch_name_exe'_exe]

$ define /nolog 'p1' SSLLIB       sslroot:['arch_name'_lib]

$!

$! Defining OPENSSL lets a C program use "#include <openssl/{foo}.h>":

$ define /nolog 'p1' OPENSSL      SSLINCLUDE:

$!

$! Run a site-specific procedure, if it exists.

$!

$ if f$search( "sslroot:[vms]openssl_systartup.com") .nes."" then -

   @ sslroot:[vms]openssl_systartup.com

$!

$! Restore the original default dev:[dir] (if known).

$!

$ clean_up:

$!

$ if (f$type( orig_dev_dir) .nes. "")

$ then

$    set default 'orig_dev_dir'

$ endif

$!

$ EXIT 'status'

$!