Commit 6ab28867 authored by kzangeli's avatar kzangeli
Browse files

Merge remote-tracking branch 'origin/develop' into fix/csr-discovery-037

# Conflicts:
#	libraries/assertionUtils.py
parents 98c894e7 4f54dc83
Loading
Loading
Loading
Loading
+7 −0
Changes for .claude/CLAUDE.md: 7 added lines, 0 removed lines.
Original line number Diff line number Diff line
@@ -183,6 +183,13 @@ Scopes (optional): API group or subsystem, e.g. `subscription`, `temporal`, `rob

---

## Reviewing a Merge Request

Write MR reviews in the format of `.claude/review-template.md`. Diff against the MR's target branch, not `develop`:
stacked MRs target another MR's branch.

---

## What Agents Must Never Do

- Hardcode broker URLs or port numbers — always use variables from `resources/variables.py`.
+44 −3
Changes for .claude/commands/review-tc.md: 44 added lines, 3 removed lines.
Original line number Diff line number Diff line
@@ -37,9 +37,10 @@ robocop format --check <file>

PASS if exit code 0 (no changes needed). FAIL otherwise — list lines that would change.

### 3. Test case identifier pattern
### 3. Test case identifier pattern and file layout

Every test case name inside the file must match `XXX_YY_NN <Description>` where `XXX`, `YY`, `NN` are numeric.
Every test case name inside the file must match `XXX_YY_NN <Description>` where `XXX`, `YY`, `NN` are numeric, and
the file must sit at `TP/NGSI-LD/<Group>/<Subgroup>/<Operation>/<TC_ID>.robot`.

### 4. Required tags on every permutation

@@ -103,6 +104,39 @@ PYTHONPATH=./doc python -m unittest discover -s doc/tests

PASS if the output ends with `OK`. FAIL with the failing tests otherwise.

### 11. Spec clause tags and asserted behaviour

For every `section_reference` tag, read the clause in the spec (TS 104 175 for `core_`, TS 104 176 for `http_`,
TS 104 243 for `mqtt_`):

- The clause must describe the operation or behaviour the permutation tests (clause numbers don't change across spec
  versions, so a mismatch is a typo in the tag).
- What the TC asserts (status codes, response body, notification content) must match what the clause requires.

FAIL with the clause and a quote of the spec text otherwise.

### 12. Release tag

Every permutation in the file uses the same `since_vX.Y.Z` or `since_ts104_vX.Y.Z` tag (an untagged permutation
counts as v1.3.1), and it matches the spec version that introduced the feature.

FAIL if the file mixes versions or the tag is wrong.

### 13. Robot dry run

```bash
python3 -m robot --dryrun --outputdir ./results <file>
```

PASS if all TCs pass. FAIL with the errors otherwise.

### 14. Run against a broker (optional)

Run the TC with `/run-suite`. Report the broker and its version, then for each failure the expected result, the result
you got, its cause, and whether it is a known gap of that broker.

N/A if not run.

---

## Summary
@@ -113,7 +147,7 @@ After all checks, output a summary table:
|---|---|---|
| 1 | Commit message format | PASS / FAIL / N/A |
| 2 | Robocop formatting | PASS / FAIL |
| 3 | TC identifier pattern | PASS / FAIL |
| 3 | TC identifier pattern and file layout | PASS / FAIL |
| 4 | Required tags | PASS / FAIL |
| 5 | Keywords registered in doc/analysis/ | PASS / FAIL / WARN |
| 6 | Setup/Teardown symmetry | PASS / WARN / N/A |
@@ -121,6 +155,13 @@ After all checks, output a summary table:
| 8 | No hardcoded URLs | PASS / WARN |
| 9 | Documentation still generates | PASS / FAIL |
| 10 | Documentation unit tests | PASS / FAIL |
| 11 | Spec clause tags and asserted behaviour | PASS / FAIL |
| 12 | Release tag | PASS / FAIL |
| 13 | Robot dry run | PASS / FAIL |
| 14 | Run against a broker | PASS / WARN / N/A |

If all items are PASS or WARN, state: "Ready to open a merge request."
If any item is FAIL, list the remediation steps required before the MR can be opened.

When reviewing someone else's MR rather than your own change, write the review in the format of
`.claude/review-template.md`.
+36 −0
Changes for .claude/review-template.md: 36 added lines, 0 removed lines.
Original line number Diff line number Diff line
# Review — MR !<N>: <MR title>

<MR URL> — reviewed at `<short sha>` against `<target branch>` (stacked on !<M>, if the target is another MR's branch).

**Verdict:** <Approve | Approve after fixes (items #…) | Changes requested (items #…)>

<One or two sentences: what the MR adds, and the main thing the submitter must do, if anything.>

## Checks

The summary table of `/review-tc` (`.claude/commands/review-tc.md`), run on the MR's files and commits, with a short
note per result (e.g. the clauses verified, `n/n OK`, the broker and its version).

## Blocking

Must be fixed before merge. Omit the section if empty.

### 1. <Short title> (`path/to/file:line`)

- **Problem:** <what is wrong, with spec quote or evidence>
- **Fix:** <concrete change>

## Should fix

Same format. Omit if empty.

## Optional / nits

Same format, one or two lines each. Omit if empty.

## Broker run

Omit if not run.

| TC | Expected | Got | Cause | Expected failure? |
|---|---|---|---|---|
+272 −0
Changes for TP/NGSI-LD/CommonBehaviours/CommonResponses/VerifyHEAD/061_01.robot: 272 added lines, 0 removed lines.
Original line number Diff line number Diff line
*** Settings ***
Documentation       Verify that a HEAD request on a resource that has GET/HEAD functions in the same manner as a GET request, omits the body in the response and that the response code 204 No Content is used on success

Resource            ${EXECDIR}/resources/ApiUtils/Common.resource
Resource            ${EXECDIR}/resources/ApiUtils/ContextInformationProvision.resource
Resource            ${EXECDIR}/resources/ApiUtils/ContextInformationSubscription.resource
Resource            ${EXECDIR}/resources/ApiUtils/ContextSourceRegistration.resource
Resource            ${EXECDIR}/resources/ApiUtils/ContextSourceRegistrationSubscription.resource
Resource            ${EXECDIR}/resources/ApiUtils/TemporalContextInformationProvision.resource
Resource            ${EXECDIR}/resources/ApiUtils/jsonldContext.resource
Resource            ${EXECDIR}/resources/AssertionUtils.resource
Resource            ${EXECDIR}/resources/HttpUtils.resource
Resource            ${EXECDIR}/resources/JsonUtils.resource


*** Variables ***
${building_filename}=               building-simple-attributes.jsonld
${subscription_filename}=           subscriptions/subscription.jsonld
${registration_filename}=           csourceRegistrations/context-source-registration-with-expiration.jsonld
${csr_subscription_filename}=       csourceSubscriptions/subscription.jsonld
${tea_filename}=                    vehicle-temporal-representation.jsonld
${context_filename}=                @context-minimal-valid.json


*** Test Cases ***
061_01_01 Endpoint /entities/
    [Documentation]    Verify that a HEAD request on /entities/ is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    e-query    cb-head    http_5    http_7_2_3_1
    [Setup]    Create The Resource Under Test    entity
    ${response}=    Request With HEAD
    ...    path=entities/
    ...    type=Building
    ...    context=${ngsild_test_suite_context}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_02 Endpoint /entities/{entityId}
    [Documentation]    Verify that a HEAD request on /entities/{entityId} is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    e-retrieve    cb-head    http_5    http_7_3_3_1
    [Setup]    Create The Resource Under Test    entity
    ${response}=    Request With HEAD
    ...    path=entities/${id}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_03 Endpoint /subscriptions/
    [Documentation]    Verify that a HEAD request on /subscriptions/ is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    sub-query    cb-head    http_5    http_7_13_3_1
    [Setup]    Create The Resource Under Test    subscription
    ${response}=    Request With HEAD
    ...    path=subscriptions/
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_04 Endpoint /subscriptions/{subscriptionId}
    [Documentation]    Verify that a HEAD request on /subscriptions/{subscriptionId} is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    sub-retrieve    cb-head    http_5    http_7_14_3_1
    [Setup]    Create The Resource Under Test    subscription
    ${response}=    Request With HEAD
    ...    path=subscriptions/${id}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_05 Endpoint /types/
    [Documentation]    Verify that a HEAD request on /types/ is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    ed-types    cb-head    http_5    http_7_15_3_1
    [Setup]    Create The Resource Under Test    entity
    ${response}=    Request With HEAD
    ...    path=types/
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_06 Endpoint /types/{type}
    [Documentation]    Verify that a HEAD request on /types/{type} is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    ed-type    cb-head    http_5    http_7_16_3_1
    [Setup]    Create The Resource Under Test    entity
    ${response}=    Request With HEAD
    ...    path=types/Building
    ...    context=${ngsild_test_suite_context}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_07 Endpoint /attributes/
    [Documentation]    Verify that a HEAD request on /attributes/ is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    ed-attrs    cb-head    http_5    http_7_17_3_1
    [Setup]    Create The Resource Under Test    entity
    ${response}=    Request With HEAD
    ...    path=attributes/
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_08 Endpoint /attributes/{attrId}
    [Documentation]    Verify that a HEAD request on /attributes/{attrId} is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    ed-attr    cb-head    http_5    http_7_18_3_1
    [Setup]    Create The Resource Under Test    entity
    ${response}=    Request With HEAD
    ...    path=attributes/name
    ...    context=${ngsild_test_suite_context}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_09 Endpoint /temporal/entities/
    [Documentation]    Verify that a HEAD request on /temporal/entities/ is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    te-query    cb-head    http_5    http_8_2_3_1
    [Setup]    Create The Resource Under Test    temporal
    ${response}=    Request With HEAD
    ...    path=temporal/entities/
    ...    type=Vehicle
    ...    timerel=after
    ...    timeAt=2020-08-01T12:05:00Z
    ...    context=${ngsild_test_suite_context}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_10 Endpoint /temporal/entities/{entityId}
    [Documentation]    Verify that a HEAD request on /temporal/entities/{entityId} is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    te-retrieve    cb-head    http_5    http_8_3_3_1
    [Setup]    Create The Resource Under Test    temporal
    ${response}=    Request With HEAD
    ...    path=temporal/entities/${id}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_11 Endpoint /csourceRegistrations/
    [Documentation]    Verify that a HEAD request on /csourceRegistrations/ is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    csr-query    cb-head    http_5    http_9_2_3_1
    [Setup]    Create The Resource Under Test    registration
    ${response}=    Request With HEAD
    ...    path=csourceRegistrations/
    ...    type=Vehicle
    ...    context=${ngsild_test_suite_context}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_12 Endpoint /csourceRegistrations/{registrationId}
    [Documentation]    Verify that a HEAD request on /csourceRegistrations/{registrationId} is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    csr-retrieve    cb-head    http_5    http_9_3_3_1
    [Setup]    Create The Resource Under Test    registration
    ${response}=    Request With HEAD
    ...    path=csourceRegistrations/${id}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_13 Endpoint /csourceSubscriptions/
    [Documentation]    Verify that a HEAD request on /csourceSubscriptions/ is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    csrsub-query    cb-head    http_5    http_9_4_3_1
    [Setup]    Create The Resource Under Test    registration subscription
    ${response}=    Request With HEAD
    ...    path=csourceSubscriptions/
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_14 Endpoint /csourceSubscriptions/{subscriptionId}
    [Documentation]    Verify that a HEAD request on /csourceSubscriptions/{subscriptionId} is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    csrsub-retrieve    cb-head    http_5    http_9_5_3_1
    [Setup]    Create The Resource Under Test    registration subscription
    ${response}=    Request With HEAD
    ...    path=csourceSubscriptions/${id}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_15 Endpoint /jsonldContexts/
    [Documentation]    Verify that a HEAD request on /jsonldContexts/ is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    ctx-list    cb-head    http_5    http_10_2_3_1
    [Setup]    Create The Resource Under Test    context
    ${response}=    Request With HEAD
    ...    path=jsonldContexts/
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test

061_01_16 Endpoint /jsonldContexts/{contextId}
    [Documentation]    Verify that a HEAD request on /jsonldContexts/{contextId} is answered with 204 No Content, without Content-Length
    [Tags]    since_ts104_v1.1.1    ctx-serve    cb-head    http_5    http_10_3_3_1
    [Setup]    Create The Resource Under Test    context
    ${context_id}=    Replace String    ${id}    ${NGSI_LD_API_PATH}/${JSONLDCONTEXTS_ENDPOINT_PATH}/    ${EMPTY}
    ${context_id}=    Evaluate    urllib.parse.quote($context_id, safe='')    modules=urllib
    ${response}=    Request With HEAD
    ...    path=jsonldContexts/${context_id}
    Check Response Status Code    204    ${response.status_code}
    Check Response Body Is Empty    ${response}
    Check Response Headers Not Containing Content-Length    ${response.headers}
    [Teardown]    Delete The Resource Under Test


*** Keywords ***
Create The Resource Under Test
    [Documentation]    Create the resource the HEAD request is made on. ${id} is set only once the creation is
    ...    answered with 201, so that the teardown deletes only what was created
    [Arguments]    ${kind}
    VAR    ${id}=    ${EMPTY}    scope=TEST
    VAR    ${resource_kind}=    ${kind}    scope=TEST
    IF    $kind == 'entity'
        ${new_id}=    Generate Random Building Entity Id
        ${response}=    Create Entity Selecting Content Type
        ...    ${building_filename}
        ...    ${new_id}
        ...    ${CONTENT_TYPE_LD_JSON}
    ELSE IF    $kind == 'subscription'
        ${new_id}=    Generate Random Subscription Id
        ${response}=    Create Subscription    ${new_id}    ${subscription_filename}    ${CONTENT_TYPE_LD_JSON}
    ELSE IF    $kind == 'temporal'
        ${new_id}=    Generate Random Vehicle Entity Id
        ${response}=    Create Or Update Temporal Representation Of Entity Selecting Content Type
        ...    temporal_entity_representation_id=${new_id}
        ...    filename=${tea_filename}
        ...    content_type=${CONTENT_TYPE_LD_JSON}
    ELSE IF    $kind == 'registration'
        ${new_id}=    Generate Random CSR Id
        ${payload}=    Load JSON From File    ${EXECDIR}/data/${registration_filename}
        ${payload}=    Update Value To JSON    ${payload}    $..id    ${new_id}
        ${response}=    Create Context Source Registration With Return    ${payload}
    ELSE IF    $kind == 'registration subscription'
        ${new_id}=    Generate Random Subscription Id
        ${payload}=    Load Test Sample    ${csr_subscription_filename}    ${new_id}
        ${response}=    Create Context Source Registration Subscription    ${payload}
    ELSE IF    $kind == 'context'
        ${response}=    Add a new @context    ${context_filename}
    ELSE
        Fail    Unknown kind of resource: ${kind}
    END
    Check Response Status Code    201    ${response.status_code}
    IF    $kind == 'context'
        ${new_id}=    Fetch Id From Response Location Header    ${response.headers}
    END
    VAR    ${id}=    ${new_id}    scope=TEST

Delete The Resource Under Test
    [Documentation]    Delete the resource created by Create The Resource Under Test, if it was created
    IF    $id == ''    RETURN
    IF    $resource_kind == 'entity'
        Delete Entity    ${id}
    ELSE IF    $resource_kind == 'subscription'
        Delete Subscription    ${id}
    ELSE IF    $resource_kind == 'temporal'
        Delete Temporal Representation Of Entity    ${id}
    ELSE IF    $resource_kind == 'registration'
        Delete Context Source Registration    ${id}
    ELSE IF    $resource_kind == 'registration subscription'
        Delete Context Source Registration Subscription    ${id}
    ELSE IF    $resource_kind == 'context'
        Delete a @context    ${id}
    END
+70 −0
Changes for TP/NGSI-LD/CommonBehaviours/CommonResponses/VerifyHEAD/061_02.robot: 70 added lines, 0 removed lines.
Original line number Diff line number Diff line
*** Settings ***
Documentation       Verify that a HEAD request that the corresponding GET request would answer with an error is answered with the same error status code and no body

Resource            ${EXECDIR}/resources/ApiUtils/Common.resource
Resource            ${EXECDIR}/resources/AssertionUtils.resource

Test Template       Request With HEAD Answered With An Error


*** Test Cases ***    PATH    CONTEXT    EXPECTED_STATUS_CODE
061_02_01 Endpoint /entities/ Without Any Query Parameter
    [Tags]    since_ts104_v1.1.1    e-query    cb-head    http_5    http_7_2_3_1
    entities/    ${EMPTY}    400
061_02_02 Endpoint /entities/{entityId} If The Entity Id Is Not A Valid URI
    [Tags]    since_ts104_v1.1.1    e-retrieve    cb-head    http_5    http_7_3_3_1
    entities/thisisaninvaliduri    ${EMPTY}    400
061_02_03 Endpoint /entities/{entityId} If The Entity Is Not Known
    [Tags]    since_ts104_v1.1.1    e-retrieve    cb-head    http_5    http_7_3_3_1
    entities/urn:ngsi-ld:Building:unknown061    ${EMPTY}    404
061_02_04 Endpoint /subscriptions/{subscriptionId} If The Subscription Id Is Not A Valid URI
    [Tags]    since_ts104_v1.1.1    sub-retrieve    cb-head    http_5    http_7_14_3_1
    subscriptions/thisisaninvaliduri    ${EMPTY}    400
061_02_05 Endpoint /subscriptions/{subscriptionId} If The Subscription Is Not Known
    [Tags]    since_ts104_v1.1.1    sub-retrieve    cb-head    http_5    http_7_14_3_1
    subscriptions/urn:ngsi-ld:Subscription:unknown061    ${EMPTY}    404
061_02_06 Endpoint /types/{type} If The Type Is Not Known
    [Tags]    since_ts104_v1.1.1    ed-type    cb-head    http_5    http_7_16_3_1
    types/UnknownType061    ${ngsild_test_suite_context}    404
061_02_07 Endpoint /attributes/{attrId} If The Attribute Is Not Known
    [Tags]    since_ts104_v1.1.1    ed-attr    cb-head    http_5    http_7_18_3_1
    attributes/unknownAttribute061    ${ngsild_test_suite_context}    404
061_02_08 Endpoint /temporal/entities/ Without Any Query Parameter
    [Tags]    since_ts104_v1.1.1    te-query    cb-head    http_5    http_8_2_3_1
    temporal/entities/    ${EMPTY}    400
061_02_09 Endpoint /temporal/entities/{entityId} If The Entity Id Is Not A Valid URI
    [Tags]    since_ts104_v1.1.1    te-retrieve    cb-head    http_5    http_8_3_3_1
    temporal/entities/thisisaninvaliduri    ${EMPTY}    400
061_02_10 Endpoint /temporal/entities/{entityId} If The Entity Is Not Known
    [Tags]    since_ts104_v1.1.1    te-retrieve    cb-head    http_5    http_8_3_3_1
    temporal/entities/urn:ngsi-ld:Vehicle:unknown061    ${EMPTY}    404
061_02_11 Endpoint /csourceRegistrations/ Without Entity Types And Attribute Names
    [Tags]    since_ts104_v1.1.1    csr-query    cb-head    http_5    http_9_2_3_1
    csourceRegistrations/    ${ngsild_test_suite_context}    400
061_02_12 Endpoint /csourceRegistrations/{registrationId} If The Registration Id Is Not A Valid URI
    [Tags]    since_ts104_v1.1.1    csr-retrieve    cb-head    http_5    http_9_3_3_1
    csourceRegistrations/thisisaninvaliduri    ${EMPTY}    400
061_02_13 Endpoint /csourceRegistrations/{registrationId} If The Registration Is Not Known
    [Tags]    since_ts104_v1.1.1    csr-retrieve    cb-head    http_5    http_9_3_3_1
    csourceRegistrations/urn:ngsi-ld:ContextSourceRegistration:unknown061    ${EMPTY}    404
061_02_14 Endpoint /csourceSubscriptions/{subscriptionId} If The Subscription Id Is Not A Valid URI
    [Tags]    since_ts104_v1.1.1    csrsub-retrieve    cb-head    http_5    http_9_5_3_1
    csourceSubscriptions/thisisaninvaliduri    ${EMPTY}    400
061_02_15 Endpoint /csourceSubscriptions/{subscriptionId} If The Subscription Is Not Known
    [Tags]    since_ts104_v1.1.1    csrsub-retrieve    cb-head    http_5    http_9_5_3_1
    csourceSubscriptions/urn:ngsi-ld:Subscription:unknown061    ${EMPTY}    404
061_02_16 Endpoint /jsonldContexts/{contextId} If The @context Is Not Known
    [Tags]    since_ts104_v1.1.1    ctx-serve    cb-head    http_5    http_10_3_3_1
    jsonldContexts/unknownContext061    ${EMPTY}    404


*** Keywords ***
Request With HEAD Answered With An Error
    [Documentation]    Verify that a HEAD request that the GET request would answer with an error gets the same status code and no body
    [Arguments]    ${path}    ${context}    ${expected_status_code}

    ${response}=    Request With HEAD
    ...    path=${path}
    ...    context=${context}
    Check Response Status Code    ${expected_status_code}    ${response.status_code}
    Check Response Body Is Empty    ${response}
Loading