Added initial version of TC_464XLAT_PLATLSN_SPR_BV_001. (c4a2d792) · Commits · CABLE - Integrated broadband cable telecommunication networks / CableIPv6

ttcn/Ats464XLat/Ats464XLat_Pixits.ttcn3

+14 −0

Original line number	Diff line number	Diff line
		@@ -28,6 +28,20 @@ module Ats464XLat_Pixits {
		}
		}

		modulepar NatMappingTable_1_to_1 PX_464XLAT_MAPPING_TABLE_1_TO_1 := {
		etsPort := 6001,
		mapInfos := {
		{
		ip6Address := '20010db8000000000000000000000001'O,
		ip4Address := '91fea0ed'O
		},
		{
		ip6Address := '20010db8000000000000000000000002'O,
		ip4Address := '91fea0ee'O
		}
		}
		}

		modulepar NatMappingTable_1_to_n PX_464XLAT_MAPPING_TABLE_1_TO_N := {
		ip4Address := '91fea0ed'O,
		dstPort := 80,

ttcn/Ats464XLat/Ats464XLat_TestCases.ttcn3

+149 −0

Original line number	Diff line number	Diff line
		@@ -236,6 +236,153 @@ module Ats464XLat_TestCases {

		group validBehaviour {

		/**
		* @desc Check that the IUT functions with static port reservation per prefix downstream
		* @verdict pass on success, inconc on timeout, fail otherwise
		* <pre>
		* PICS Selection: none
		* Initial conditions:
		* with {
		* the IUT is properly provisioned
		* the interfaces are connected & functional
		* the static entries of well known ports for a singular prefix is configured on the IUT
		* }
		* Expected behaviour:
		* ensure that {
		* when {
		* the IUT receives multiple IPv4 packets downstream
		* containing IPv4 transport header
		* containing source address
		* indicating client IPv4 public address
		* containing destination address
		* indicating client IPv4 public static address
		* }
		* then {
		* Traffic using static port forward is forwarded to an internal client by the IUT
		* }
		* }
		* </pre>
		*
		* @version 0.0.1
		* @reference ETSI TS 101 569-1 Clause 6.6.6.19 Static Port Forwards
		* @see ETSI TS xxx xxx-x V0.0.1.5a-draft (2013-07) TP/464XLAT/PLAT-LSN/SPR/VB/01
		*/
		testcase TC_464XLAT_PLATLSN_SPR_BV_001() runs on FourSixFourXLatComponent system TestAdapter {

		// Local variables
		var integer v_hostNum := lengthof(PX_464XLAT_MAPPING_TABLE_1_TO_1.mapInfos); /** Expected number of IPv6 packets to be forwarded */
		var Ipv4Packet v_ipv4Packet; /** IPv4 packets */
		var Ipv6Packet v_ipv6Packet; /** IPv6 packets address to IPv4 */
		var integer v_host; /** 'for' statement counter */

		// Test control

		// Test component configuration
		for (v_host := 0; v_host < v_hostNum; v_host := v_host + 1) {
		vc_lsnComponents[v_host] := LSNComponent.create(c_COMP_LSN & int2str(v_host));
		vc_hostComponents[v_host] := HostComponent.create(c_COMP_HOST & int2str(v_host));
		} // End of 'for' statement
		f_cf01Up_PLAT();

		// Test adapter configuration

		// Test Body
		// Start all components
		for (v_host := 0; v_host < v_hostNum; v_host := v_host + 1) {
		f_finalyzeIpv4Packet(
		m_ipv4Packet_dummy(
		PX_IPV4_DESTINATION_INFORMATION.iutAddress,
		PX_464XLAT_MAPPING_TABLE_1_TO_1.mapInfos[v_host].ip4Address,
		m_tcp_packet(
		PX_IPV4_DESTINATION_INFORMATION.iutPort,
		PX_464XLAT_MAPPING_TABLE_1_TO_1.etsPort,
		PX_IPV4_DESTINATION_INFORMATION.payload,
		m_tcp_flags_syn
		)
		),
		v_ipv4Packet
		);
		v_ipv6Packet := m_generalIpv6_ipv4Payload(
		c_ipv4Hdr,
		PX_464XLAT_PREFIX & c_4ZeroBytes & PX_IPV4_DESTINATION_INFORMATION.iutAddress,
		PX_464XLAT_MAPPING_TABLE_1_TO_1.mapInfos[v_host].ip6Address,
		v_ipv4Packet
		);

		vc_lsnComponents[v_host].start(f_TC_464XLAT_PLATLSN_SPR_BV_001_lsn(v_ipv4Packet));
		vc_hostComponents[v_host].start(f_TC_464XLAT_PLATLSN_SPR_BV_001_host(v_ipv6Packet));
		} // End of 'for' statement

		f_serverSyncNClientsAndStop(v_hostNum * 2, { c_prDone, c_tbDone, c_poDone });

		// Postamble
		f_down();

		} // End of testcase TC_464XLAT_PLATLSN_SPR_BV_001

		group f_TC_464XLAT_PLATLSN_SPR_BV_001 {

		/**
		* @desc Simulates LSN side
		* @verdict 'pass' on success, 'inconc' on 'timeout', fail otherwise
		*/
		function f_TC_464XLAT_PLATLSN_SPR_BV_001_lsn(Ipv4Packet p_ipv4Packet) runs on LSNComponent {

		// Local variables

		// Preamble
		// Clause 'Initial conditions'
		f_preamble_lsn(p_ipv4Packet.ipv4Hdr.destinationAddress);
		f_selfOrClientSyncAndVerdict(c_prDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Preamble done. *");

		// Test Body
		ipv4Port.send(p_ipv4Packet);

		// Postamble
		f_postamble_lsn();
		f_selfOrClientSyncAndVerdict(c_poDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Postamble done. *");

		} // End of function f_TC_464XLAT_PLATLSN_SPR_BV_001_lsn

		/**
		* @desc Simulates client side
		* @verdict 'pass' on success, 'inconc' on 'timeout', fail otherwise
		*/
		function f_TC_464XLAT_PLATLSN_SPR_BV_001_host(Ipv6Packet p_ipv6Packet) runs on HostComponent {

		// Local variables

		// Preamble
		// Clause 'Initial conditions'
		f_preamble_host();
		f_selfOrClientSyncAndVerdict(c_prDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Preamble done. *");

		// Test Body
		tc_ac.start;
		alt {
		[] ipPort.receive(p_ipv6Packet) {
		tc_ac.stop;
		log("* " & __SCOPE__ & ": PASS: IPv4 packet was forwarded. *");
		f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
		}
		[] tc_ac.timeout {
		f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
		log("* " & __SCOPE__ & ": INCONC: Message was not received in time. *");
		}
		} // End of 'altstep' statement

		// Postamble
		f_postamble_host();
		f_selfOrClientSyncAndVerdict(c_poDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Postamble done. *");

		} // End of function f_TC_464XLAT_PLATLSN_SPR_BV_001_host

		} // End of group f_TC_464XLAT_PLATLSN_SPR_BV_001

		} // End of group validBehaviour

		} // End of group staticPortAndIpReservation
		@@ -431,6 +578,8 @@ module Ats464XLat_TestCases {

		} // End of group f_TC_464XLAT_PLATLSN_PF_BV_001

		//TODO add TC_464XLAT_PLATLSN_PF_BV_002

		} // End of group validBehaviour

		} // End of group packetFragmentation