Added initial version of TC_464XLAT_PLATLSN_BF_BV_001, TC_464XLAT_PLATLSN_BF_BV_002. (04298348) · Commits · CABLE - Integrated broadband cable telecommunication networks / CableIPv6

ttcn/Ats464XLat/Ats464XLat_TestCases.ttcn3

+293 −0

Original line number	Diff line number	Diff line
		@@ -209,6 +209,299 @@ module Ats464XLat_TestCases {

		group validBehaviour {

		/**
		* @desc Check that the IUT supports the functionality of PLAT 1:n NAT mapping with port translation
		* @verdict pass on success, inconc on timeout, fail otherwise
		* <pre>
		* PICS Selection: none
		* Initial conditions:
		* with {
		* the IUT is properly provisioned
		* the interfaces are connected & functional
		* }
		* Expected behaviour:
		* ensure that {
		* when {
		* the IUT receives multiple IPv6 packets
		* containing IPv6 transport header
		* containing source address
		* indicating client IPv6 address
		* containing destination address
		* indicating IUT GW IPv6 prefix first 64 bits
		* indicating IUT IPv4 embedded into the IPv6 address in last 32 bits
		* from multiple client devices
		* }
		* then {
		* the IUT does a 1:n NAT mapping for multiple public IPv6 CLAT addresses sourced
		* and the IUT forwards packets to the destination with same public IPv4 source address
		* }
		* }
		* </pre>
		*
		* @version 0.0.1
		* @reference ETSI TS 101 569-1 Clause 6.6 464XLAT Technology Summary
		* @see ETSI TS xxx xxx-x V0.0.1.5a-draft (2013-07) TP/464XLAT/PLAT-LSN/BF/VB/01
		*/
		testcase TC_464XLAT_PLATLSN_BF_BV_001() runs on FourSixFourXLatComponent system TestAdapter {

		// Local variables
		var UInt v_hostNum := lengthof(PX_464XLAT_MAPPING_TABLE_1_TO_N.portInfos); /** Expected number of IPv6 packets to be forwarded */
		var Ipv4Packet v_ipv4Packet; /** IPv4 packets */
		var Ipv6Packet v_ipv6Packet; /** IPv6 packets address to IPv4 */
		var integer v_host; /** 'for' statement counter */

		// Test control

		// Test component configuration
		vc_lsnComponents[0] := LSNComponent.create(c_COMP_LSN);
		for (v_host := 0; v_host < v_hostNum; v_host := v_host + 1) {
		vc_hostComponents[v_host] := HostComponent.create(c_COMP_HOST & int2str(v_host));
		} // End of 'for' statement
		f_cf01Up_PLAT();

		// Test adapter configuration

		// Test Body
		// Start all components

		vc_lsnComponents[0].start(f_TC_464XLAT_PLATLSN_BF_BV_001_lsn(v_hostNum));
		for (v_host := 0; v_host < v_hostNum; v_host := v_host + 1) {
		v_ipv4Packet := m_ipv4Packet_dummy(
		PX_464XLAT_MAPPING_TABLE_1_TO_N.ip4Address,
		PX_IPV4_DESTINATION_INFORMATION.iutAddress,
		m_tcp_packet(
		PX_464XLAT_MAPPING_TABLE_1_TO_N.portInfos[v_host].srcPort,
		PX_464XLAT_MAPPING_TABLE_1_TO_N.dstPort,
		PX_IPV4_DESTINATION_INFORMATION.payload,
		m_tcp_flags_syn
		)
		);
		v_ipv6Packet := m_generalIpv6_ipv4Payload(
		c_ipv4Hdr,
		PX_464XLAT_MAPPING_TABLE_1_TO_N.portInfos[v_host].ip6Address,
		PX_464XLAT_PREFIX & c_4ZeroBytes & PX_464XLAT_MAPPING_TABLE_1_TO_N.ip4Address,
		v_ipv4Packet
		);

		vc_hostComponents[v_host].start(f_TC_464XLAT_PLATLSN_BF_BV_001_host(v_ipv6Packet));
		} // End of 'for' statement

		f_serverSyncNClientsAndStop(v_hostNum + 1, { c_prDone, c_tbDone, c_poDone });

		// Postamble
		f_down();

		} // End of testcase TC_464XLAT_PLATLSN_BF_BV_001

		group f_TC_464XLAT_PLATLSN_BF_BV_001 {

		/**
		* @desc Simulates LSN side
		* @verdict 'pass' on success, 'inconc' on 'timeout', fail otherwise
		*/
		function f_TC_464XLAT_PLATLSN_BF_BV_001_lsn(integer p_hostNum) runs on LSNComponent {

		// Local variables
		var FncRetCode v_result := e_success;
		var Ipv4Address v_localAddress := PX_IPV4_DESTINATION_INFORMATION.iutAddress;

		// Preamble
		// Clause 'Initial conditions'
		f_preamble_lsn(v_localAddress);
		f_selfOrClientSyncAndVerdict(c_prDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Preamble done. *");

		// Test Body
		// Clause 'when': the IUT does a 1:n NAT mapping for multiple public IPv6 B4 addresses sourced and,
		// the IUT forwards packets to the destination with same public IPv4 source address
		v_result := f_lsn_check_1_to_n_NAT_mapping(v_localAddress, p_hostNum);
		f_selfOrClientSyncAndVerdict(c_tbDone, v_result);

		// Postamble
		f_postamble_lsn();
		f_selfOrClientSyncAndVerdict(c_poDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Postamble done. *");

		} // End of function f_TC_464XLAT_PLATLSN_BF_BV_001_lsn

		/**
		* @desc Simulates client side
		* @verdict 'pass' on success, 'inconc' on 'timeout', fail otherwise
		*/
		function f_TC_464XLAT_PLATLSN_BF_BV_001_host(Ipv6Packet p_ipv6Packet) runs on HostComponent {

		// Local variables

		// Preamble
		// Clause 'Initial conditions'
		f_preamble_host();
		f_selfOrClientSyncAndVerdict(c_prDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Preamble done. *");

		// Test Body
		f_sendIpv6Packet(p_ipv6Packet);

		// Postamble
		f_postamble_host();
		f_selfOrClientSyncAndVerdict(c_poDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Postamble done. *");

		} // End of function f_TC_464XLAT_PLATLSN_BF_BV_001_host

		} // End of group f_TC_464XLAT_PLATLSN_BF_BV_001

		/**
		* @desc Check that the IUT supports the functionality of PLAT 1:1 NAT mapping with port translation
		* @verdict pass on success, inconc on timeout, fail otherwise
		* <pre>
		* PICS Selection: none
		* Initial conditions:
		* with {
		* the IUT is properly provisioned
		* the interfaces are connected & functional
		* }
		* Expected behaviour:
		* ensure that {
		* when {
		* the IUT receives multiple IPv6 packets
		* containing IPv6 transport header
		* containing source address
		* indicating client IPv6 address
		* containing destination address
		* indicating IUT GW IPv6 prefix first 64 bits
		* indicating IUT IPv4 embedded into the IPv6 address in last 32 bits
		* from multiple client devices
		* }
		* then {
		* the IUT does a 1:1 NAT mapping for multiple public IPv6 CLAT addresses sourced
		* and the IUT forwards packets to the destination with different public IPv4 source addresses
		* }
		* }
		* </pre>
		*
		* @version 0.0.1
		* @reference ETSI TS 101 569-1 Clause 6.6 464XLAT Technology Summary
		* @see ETSI TS xxx xxx-x V0.0.1.5a-draft (2013-07) TP/464XLAT/PLAT-LSN/BF/VB/02
		*/
		testcase TC_464XLAT_PLATLSN_BF_BV_002() runs on FourSixFourXLatComponent system TestAdapter {

		// Local variables
		var integer v_hostNum := lengthof(PX_464XLAT_MAPPING_TABLE_1_TO_1.mapInfos); /** Expected number of IPv6 packets to be forwarded */
		var Ipv4Packet v_ipv4Packet; /** IPv4 packets */
		var Ipv6Packet v_ipv6Packet; /** IPv6 packets address to IPv4 */
		var integer v_host; /** 'for' statement counter */

		// Test control

		// Test component configuration
		for (v_host := 0; v_host < v_hostNum; v_host := v_host + 1) {
		vc_lsnComponents[v_host] := LSNComponent.create(c_COMP_LSN & int2str(v_host));
		vc_hostComponents[v_host] := HostComponent.create(c_COMP_HOST & int2str(v_host));
		} // End of 'for' statement
		f_cf01Up_PLAT();

		// Test adapter configuration

		// Test Body
		// Start all components
		for (v_host := 0; v_host < v_hostNum; v_host := v_host + 1) {
		f_finalyzeIpv4Packet(
		m_ipv4Packet_dummy(
		PX_464XLAT_MAPPING_TABLE_1_TO_1.mapInfos[v_host].ip4Address,
		PX_IPV4_DESTINATION_INFORMATION.iutAddress,
		m_tcp_packet(
		PX_464XLAT_MAPPING_TABLE_1_TO_1.etsPort,
		PX_IPV4_DESTINATION_INFORMATION.iutPort,
		PX_IPV4_DESTINATION_INFORMATION.payload,
		m_tcp_flags_syn
		)
		),
		v_ipv4Packet
		);
		v_ipv6Packet := m_generalIpv6_ipv4Payload(
		c_ipv4Hdr,
		PX_464XLAT_MAPPING_TABLE_1_TO_1.mapInfos[v_host].ip6Address,
		PX_464XLAT_PREFIX & c_4ZeroBytes & PX_IPV4_DESTINATION_INFORMATION.iutAddress,
		v_ipv4Packet
		);

		vc_lsnComponents[v_host].start(f_TC_464XLAT_PLATLSN_BF_BV_002_lsn(v_ipv4Packet));
		vc_hostComponents[v_host].start(f_TC_464XLAT_PLATLSN_BF_BV_002_host(v_ipv6Packet));
		} // End of 'for' statement

		f_serverSyncNClientsAndStop(v_hostNum * 2, { c_prDone, c_tbDone, c_poDone });

		// Postamble
		f_down();

		} // End of testcase TC_464XLAT_PLATLSN_BF_BV_002

		group f_TC_464XLAT_PLATLSN_BF_BV_002 {

		/**
		* @desc Simulates LSN side
		* @verdict 'pass' on success, 'inconc' on 'timeout', fail otherwise
		*/
		function f_TC_464XLAT_PLATLSN_BF_BV_002_lsn(Ipv4Packet p_ipv4Packet) runs on LSNComponent {

		// Local variables

		// Preamble
		// Clause 'Initial conditions'
		f_preamble_lsn(p_ipv4Packet.ipv4Hdr.destinationAddress);
		f_selfOrClientSyncAndVerdict(c_prDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Preamble done. *");

		// Test Body
		// Clause 'when': the IUT does a 1:1 NAT mapping for multiple public IPv6 CLAT addresses sourced
		// and the IUT forwards packets to the destination with different public IPv4 source addresses
		tc_ac.start;
		alt {
		[] ipv4Port.receive(p_ipv4Packet) {
		tc_ac.stop;
		log("* " & __SCOPE__ & ": PASS: IPv4 packet was forwarded. *");
		f_selfOrClientSyncAndVerdict(c_tbDone, e_success);
		}
		[] tc_ac.timeout {
		f_selfOrClientSyncAndVerdict(c_tbDone, e_timeout);
		log("* " & __SCOPE__ & ": INCONC: Message was not received in time. *");
		}
		} // End of 'altstep' statement

		// Postamble
		f_postamble_lsn();
		f_selfOrClientSyncAndVerdict(c_poDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Postamble done. *");

		} // End of function f_TC_464XLAT_PLATLSN_BF_BV_002_lsn

		/**
		* @desc Simulates client side
		* @verdict 'pass' on success, 'inconc' on 'timeout', fail otherwise
		*/
		function f_TC_464XLAT_PLATLSN_BF_BV_002_host(Ipv6Packet p_ipv6Packet) runs on HostComponent {

		// Local variables

		// Preamble
		// Clause 'Initial conditions'
		f_preamble_host();
		f_selfOrClientSyncAndVerdict(c_prDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Preamble done. *");

		// Test Body
		f_sendIpv6Packet(p_ipv6Packet);
		f_selfOrClientSyncAndVerdict(c_tbDone, e_success);

		// Postamble
		f_postamble_host();
		f_selfOrClientSyncAndVerdict(c_poDone, e_success);
		log("* " & __SCOPE__ & ": INFO: Postamble done. *");

		} // End of function f_TC_464XLAT_PLATLSN_BF_BV_002_host

		} // End of group f_TC_464XLAT_PLATLSN_BF_BV_002

		} // End of group validBehaviour

		} // End of group basicFunction