/**
 *  @author     ETSI / STF405
 *  @version    $URL: svn+ssh://vcs.etsi.org/TTCN3/LIB/LibIts/trunk/ttcn/GeoNetworking/LibItsGeoNetworking_Functions.ttcn $
 *              $Id: LibItsGeoNetworking_Functions.ttcn 168 2010-09-22 15:18:22Z berge $
 *  @desc       Module containing functions for Ipv6OverGeoNetworking
 *
 */
module LibItsIpv6OverGeoNetworking_Functions {
    
    // Libcommon
    import from LibCommon_BasicTypesAndValues all;
    import from LibCommon_DataStrings all;
    import from LibCommon_VerdictControl all;
    
    // LibIts
    import from LibIts_TestSystem all;
    import from LibIts_Interface all; 
    import from LibItsGeoNetworking_TypesAndValues all;
    import from LibItsGeoNetworking_Functions all;
    import from LibItsGeoNetworking_Templates all;
    import from LibItsIpv6OverGeoNetworking_TypesAndValues all;
    import from LibItsIpv6OverGeoNetworking_Templates all;
    
    group ipv6OverGeoConfigurationFunctions {
        
        /**
         * @desc This configuration features:
         *       - one ITS node (IUT)
         *       - two ITS nodes (nodeA, nodeB)
         *       - Area1 which only includes NodeB and IUT
         *       - Area2 which only includes NodeB 
         *         NodeB being close to the area center    
         */
        function f_ipv6_cf01Up() runs on ItsNt {

            // Variables
 
            // Map
            map(self:ipv6OverGeoNetworkingPort, system:ipv6OverGeoNetworkingPort);
            
            f_cf01Up();
            
            f_addAddresses(vc_addressTable, c_compIut);
            f_addAddresses(vc_addressTable, c_compNodeA);
            f_addAddresses(vc_addressTable, c_compNodeB);
            
        } // end f_cf01Up

        /**
         * @desc Deletes configuration cf01
         */
        function f_ipv6_cf01Down() runs on ItsNt {

            // Map
            unmap(self:ipv6OverGeoNetworkingPort, system:ipv6OverGeoNetworkingPort);
            
            f_cf01Down();
            
        } // end f_cf01Down
        
    } // end group ipv6OverGeoConfigurationFunctions
    
    group testAdapter {
        
        function f_taUpdateInterfaces() {
            
            //TODO
            
        }
        
    } // end group testAdapter
    
    group sendFunctions {
        
        function f_sendGeoBroadcastWithRtAdv(
            in template (value) GvlTableEntry p_gvl,
            in charstring p_compName
        ) runs on ItsNt {
            
            var AddressTableEntry v_nodeAddresses := f_getAddresses(p_compName);
            var LongPosVector v_nodeLongPosVector := f_getPosition(p_compName);
            
            f_sendGeoNetMessage(
                m_geoNwReq(
                    m_geoNwPduWithPayload(
                        m_geoBroadcastHeader(
                            v_nodeLongPosVector,
                            v_nodeLongPosVector,
                            vc_localSeqNumber,
                            f_getGeoBroadcastArea(valueof(p_gvl.area))
                        ),
                        m_ipv6Payload(
                            m_ipv6Packet(
                                v_nodeAddresses.lla,
                                c_allNodesMca,
                                c_icmpHdr,
                                m_rtAdvWithOptions(
                                    m_rtAdvOpt_prefixOpt(
                                        p_gvl.prefixLength,
                                        c_lFlag1,
                                        c_aFlag1,
                                        c_validLifetime30s,
                                        c_preferredLifetime30s,
                                        p_gvl.prefix
                                    )
                                )
                            )
                        )
                    )
                )
            );
        }
        
    } //end group sendFunctions
    
    group miscellaneous {
        
        /**
         * @desc Gets the Geographical Virtual link entry associated to an area
         * @param p_areaIndex The index of the area
         */
        function f_getGVL(in integer p_areaIndex) runs on ItsNt return GvlTableEntry {
            return valueof(vc_gvlTable[p_areaIndex]);
        } // end f_getGVL
        
        function f_getGvlInterface(in integer p_areaIndex) runs on ItsNt return charstring {
            return f_getGVL(p_areaIndex).interface   
        } // end f_getGvlInterface
        
        function f_getTVL() runs on ItsNt return GvlTableEntry {
            return valueof(vc_gvlTable[0]); // FIXME !!!
        } // end f_getTVL
        
        /**
         * @desc    Retrieves the MAC address from the GN address.
         * @param   p_gnAddr The GN address
         * @return  The MAC address
         */    
        function f_gnAddr2MacAddr(in GN_Address p_gnAddr) return MacAddress {
            return p_gnAddr.mid;
        } // end f_gnAddr2MacAddr
        
        /**
         * @desc    Retrieves the GN address from the MAC address.
         * @param   p_macAddr The MAC address
         * @return  The GN address
         */    
        function f_macAddr2GnAddr(in MacAddress p_macAddr) return GN_Address {
            var GN_Address v_gnAddr := valueof(m_dummyGnAddr);
            v_gnAddr.mid := p_macAddr;
            return v_gnAddr;
        } // end f_macAddr2GnAddr
        
        /**
         * @desc  Compute an Unique Interface ID based on a MAC Address
         * @param p_macAddr MAC Address
         * @return  Unique interface ID
         */
        function f_createUniqueInterfaceId (  
           in  Oct6 p_macAddr
        )
        return Oct8 {
            var UInt8 i;
            var Oct3 v_leftPartMac := int2oct(0,3);
            var Oct3 v_rightPartMac := int2oct(0,3);
            var Bit24 v_leftPartBits := int2bit(0,24);
            var Bit24 v_leftPartBitMask := oct2bit('020000'O);
            
            //get leftPart
            for (i:=0; i<lengthof(p_macAddr)-3; i:=i+1) {
                v_leftPartMac[i] := p_macAddr[i];
            }
            //get rightPart
            for (i:=3; i<lengthof(p_macAddr); i:=i+1) {
                v_rightPartMac[i-3] := p_macAddr[i];
            }
            //flipBit universalBit of leftPart
            v_leftPartBits :=  oct2bit(v_leftPartMac);
            v_leftPartBits := v_leftPartBits xor4b v_leftPartBitMask;
            v_leftPartMac := bit2oct(v_leftPartBits);
            //build InterfaceId
            return v_leftPartMac & 'FFFE'O & v_rightPartMac;
        } // end f_createUniqueInterfaceId

        /**
         * @desc    Compute link-local, solicited-node multicast IPv6 addresses
         *          and MAC-Solicited-node Address, based on prefix and MAC address
         * @param   p_addressTable Address Table
         * @param   p_componentName entity for which addresses are computed and added
         * @return  Address table entry that will contain all the results
         */
        function f_addAddresses(
            inout AddressTable p_addressTable,
            in charstring p_componentName
        ) runs on ItsNt {            
            const UInt8 c_uniIdLen := 64;
            var AddressTableEntry v_addressTableEntry;
            var MacAddress v_macAddr;
            var Oct8 v_interfaceIdReady := int2oct(0,8);
            var Oct3 v_rightPartMac := int2oct(0,3);
            var UInt8 i;

            v_addressTableEntry.key := p_componentName;
            v_macAddr := f_gnAddr2MacAddr(f_getPosition(p_componentName).gnAddr);

            v_addressTableEntry.macAddress := v_macAddr;

            // compute interface ID
            v_interfaceIdReady := f_createUniqueInterfaceId(v_macAddr);
            
            // LLA
            v_addressTableEntry.lla := 'FE80000000000000'O & v_interfaceIdReady;
            
            // get rightPart
            for (i:=3; i<lengthof(v_macAddr); i:=i+1) {
                v_rightPartMac[i-3] := v_macAddr[i];
            }
            
            // SOL_NODE_MCA
            v_addressTableEntry.solNodeMca := 'FF0200000000000000000001FF'O & v_rightPartMac;
            
            // MAC_MCA
            v_addressTableEntry.macSolNodeMca := '3333FF'O & v_rightPartMac;
            
            p_addressTable[lengthof(p_addressTable)] := v_addressTableEntry;

        } // end f_computeAddresses

        function f_getAddresses(
            in charstring p_positionKey
        ) runs on ItsNt 
        return AddressTableEntry {
            
            var AddressTableEntry v_return;
            var integer i := 0;
            
            for (i:=0; i<lengthof(vc_addressTable); i:=i+1) {
                if (vc_addressTable[i].key == p_positionKey) {
                    v_return := vc_addressTable[i];
                }
            }
            
            return v_return;
        } // end  f_getAddresses

        /**
         * @desc    Compute global address based on prefix and MAC address
         * @param   p_compName Component name
         * @param   p_prefix Prefix
         * @param   p_prefixLen Prefix Length
         * @return  Global IPv6 address
         */
        function f_computeGlobalAddress(
            in charstring p_compName,
            in Oct16 p_prefix, 
            in UInt8 p_prefixLen
        ) runs on ItsNt
        return Ipv6Address {

            var Oct8 v_prefixReady := int2oct(0,8);            
            var Oct8 v_interfaceIdReady := int2oct(0,8);
            var Bit128 v_prefixBits := oct2bit(p_prefix);
            var Bit64 v_prefixReadyBits := int2bit(0, 64);
            var UInt8 i;
            
            if (p_prefixLen > 64) {
                log("**** f_computeGlobalAddress: Wrong prefixLen ****");
                return '00000000000000000000000000000000'O;
            }
            else {
                //Fill v_prefixReady with existing Prefix
                for (i:=0; i<p_prefixLen; i:=i+1) {
                    v_prefixReadyBits[i] := v_prefixBits[i];
                }
                v_prefixReady := bit2oct(v_prefixReadyBits);
            }
            
            // compute interface ID
            v_interfaceIdReady := f_createUniqueInterfaceId(f_getAddresses(p_compName).macAddress);

            return v_prefixReady & v_interfaceIdReady;
                        
        } // end f_computeGlobalAddress

        /**
         * @desc    Derives the traffic class from the IPv6 TrafficClass field
         * @param   p_trafficClass The traffic class value in the IPv6 packet
         * @return  The traffic class based on the definition in ETSI TS 102 636-6-1 Table 1
         */    
        function f_getTrafficClassFromIpv6Packet(in UInt8 p_trafficClass) return TrafficClass {
            var TrafficClass v_trafficClass;
            
            v_trafficClass.reserved := 0;
            v_trafficClass.relevance := 0;
            
            if (p_trafficClass<64) {
                v_trafficClass.reliability := e_low;
                v_trafficClass.latency := e_high
            }
            else if (p_trafficClass>63 and p_trafficClass<128) {
                v_trafficClass.reliability := e_low;
                v_trafficClass.latency := e_medium
            }
            else if (p_trafficClass>127 and p_trafficClass<193) {
                v_trafficClass.reliability := e_low;
                v_trafficClass.latency := e_low
            }
            else {
                v_trafficClass.reliability := e_low;
                v_trafficClass.latency := e_veryLow
            }
            
            return v_trafficClass;
        } // end f_getTrafficClassFromPriority
    
    } // end group miscellaneous

} // end LibItsIpv6OverGeoNetworking_Functions