LibItsCalm_Interface.ttcn 19.4 KB
Newer Older
reinaortega's avatar
reinaortega committed
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588
/**
 *    @author     ETSI / STF405
 *    @version    $URL: svn+ssh://vcs.etsi.org/TTCN3/LIB/LibIts/branches/splitCalm/CALM/LibIts_Interface.ttcn $
 *                $Id: LibIts_Interface.ttcn 419 2012-03-12 13:17:27Z reinaortega $
 *    @desc       Module containing PTCs and interface ports definitions for ITS
 *
 */
module LibItsCalm_Interface {
    
    // LibCommon
    import from LibCommon_Time {modulepar all;}
    import from LibCommon_Sync all;
    
    // LibIts - IP Protocols
    import from LibItsExternal_TypesAndValues all;
    //  LibIts - Non IP Protocols
    import from CALMiitsscu language "ASN.1:1997" all;
    import from CALMmanagement language "ASN.1:1997" all;
    import from CALMllsap language "ASN.1:1997" {
        type 
            INsapPrimitivesUp, INsapPrimitivesDown
    };
    import from CALMmsap language "ASN.1:1997" all;
    import from CALMfntp language "ASN.1:1997" all;
    import from LibItsMgt_TypesAndValues all;
    import from LibItsFntp_TypesAndValues all;
    import from LibItsFsap_TypesAndValues all;
	import from LibItsIicp_TypesAndValues all;
    // LibIts
    import from LibItsCommon_TypesAndValues all;
	import from LibItsCommon_TestSystem all;
    
    group adapterInterface {
            
        group portDefinitions {
        
            /**
             * @desc Adapter control port
             */
            type port AdapterControlPort message {
                out 
                    AcFntpPrimitive, AcFsapPrimitive; // Non IP Protocols
            } // end AdapterControlPort
    
            /**
             * @desc Upper Tester port
             */
            type port UpperTesterPort message {
                out 
                    UtInitialize, UtTrigger, UtCheck, UtCommandRequest;
                in 
                    UtResult, UtCommandConfirm, UtCommandIndication
            } // end UpperTesterPort
            
        } // end portDefinitions    

    } // adapterInterface     
    
    group interfaceComponents {
        
        

        /**
         * @desc Test component for ITS Management layer 
         */
        type component ItsMgt extends ItsBaseComponent {
        	
			port UpperTesterPort utPort;
		    port AdapterControlPort acPort;
            
            // MGT1 ports - Used to send remote command to/from 
            port IicpPort iicpPort;
            // MGT2 ports - Used to send command to/from through SAP interfaces
            port MgtMFSapPort mgtMFSapPort; 
            port MgtMNSapPort mgtMNSapPort;
            
            // timers
            
            // variables
            var CommandRef vc_commandRef := 0; // Cyclic counter identifying a NF-FNTP-COM.request
            var PduCounter vc_pduCounter := 0; // Cyclic counter identifying a PDU counter
            var integer vc_noFNTPfwtEntry := 0;
            
        } // End of component ItsCalm

        /**
         * @desc Test component for ITS Network and Transport layer 
         */
        type component ItsCalm extends ItsMgt {
            
            
            // NT3 ports
            port FntpPort fntpPort;
            // FIXM To be removed at the end port FastPort fastPort;
            
            // timers
            
            //variables for Gn
            var charstring vc_componentName := "";
            
            // Variables for Fntp
            var PortNumber vc_portNumber := { portLong := 0 };
            var ITS_scuId vc_scuId := 0; // TODO Check if it is used or not
            var UtCommandConfirm vc_utCommandConf; // FIXME To be removed
            
        } // End of component ItsNt
        
    } // End of group interfaceComponents
    
    group interfacePorts {
        
                
        group managementPorts {
            
            group mgt1Ports {
                
                /**
                 * @desc MGT1 IISC Port (IISC/LAN) 
                 */
                type port IicpPort message {
                    inout
                        IicpReq,
                        IicpResp;
                } // End of port IicpPort
                
            } // End of group mgt1Ports
            
            group mgt2Ports {
                
                /**
                 * @desc MGT2 Management Port - MF-SAP service primitives
                 */
                type port MgtMFSapPort message {
                    inout 
                        MgtMFSapRequestReq; 
                    in 
                        MgtMFSapCommandReq, MgtMFSapCommandConfirm, 
                        MgtMFSapRequestConfirm; 
                } // End of port MgtMFSapPort
                
                /**
                 * @desc MGT2 Management Port - MN-SAP service primitives
                 */
                type port MgtMNSapPort message { 
                    inout 
                        MgtMNSapCommandReq, 
                        MgtMNSapRequestReq;
                    in 
                        MgtMNSapCommandConfirm, 
                        MgtMNSapRequestConfirm;
                } // End of port MgtMNSapPort
                
            } // End of group mgt2Ports
            
        } // End of group managementPorts

        group networkAndTransportPorts {
            
                    
            group nt3Ports {
                
                /**
                 * @desc NT3 Fntp Port
                 */
                type port FntpPort message {
                    inout 
                        INsapPrimitivesUp,
                        INsapPrimitivesDown
                } // End of port FntpPort
                
                // FIXME To be remove at the end
//                /**
//                 * @desc NT3 Fast Port (Fast/M5-IR) 
//                 */
//                type port FastPort message {
//                    in FastInd;
//                    out FastReq;
//                } // end FastPort
                
            } // End of group nt3Ports
            
        } // End of group networkAndTransportPorts
    
    } // End of group interfacePorts

    group interfacePrimitives { 
        
                
        group managementPrimitives {
            
            group mgt1Primitives {
                
                /**
                 * @desc MGT1 IISC Indication Primitive 
                 */
                type record IicpResp {
                    IIC_Response msgInOut
                }
                
                /**
                 * @desc MGT1 IISC Request Primitive 
                 */
                type record IicpReq {
                    IIC_Request msgInOut
                }
                
            } // End of group mgt1Primitives
            
            /**
             * @desc    MGT2 Management Service Primitives
             * @see     ISO/CD 24102-3
             */
            group mgt2Primitives {
                
                /**
                 * @desc    MF-SAP service primitives
                 * @see     ISO/CD 24102-3 Clause 8.1
                 */
                group MF_SAP {
                    
//                    /**
//                     * @desc    Management service primitive MF-COMMAND.request
//                     * @see     ISO/CD 24102-3 Clause 8.2.2
//                     */
//                    type record MgtMFSapCommandInd {
//                        MF_Command_request msgIn
//                    }
//                    
                    /**
                     * @desc    Management service primitive MF-REQUEST.confirm
                     * @see     ISO/CD 24102-3 Clause 8.3.3
                     */
                    type record MgtMFSapRequestConfirm {
                        MF_Request_confirm msgIn
                    }
                    
//                    /**
//                     * @desc MGT2 Management Request Primitive 
//                     */
//                    type record MgtMFSapRequestInd { // FIXME To be removed
//                        MF_Request_request msgIn
//                    }
                    
                    /**
                     * @desc    Management service primitive MF-COMMAND.request
                     * @see     ISO/CD 24102-3 Clause 8.2.3
                     */
                    type record MgtMFSapCommandReq {
                        MF_Command_request msgIn
                    }
                    
					/**
                     * @desc    Management service primitive MF-COMMAND.confirm
                     * @see     ISO/CD 24102-3 Clause 8.2.3
                     */
                    type record MgtMFSapCommandConfirm {
                        MF_Command_confirm msgIn
                    }

                    /**
                     * @desc    Management service primitive MF-REQUEST.request
                     * @see     ISO/CD 24102-3 Clause 8.3.2
                     */
                    type record MgtMFSapRequestReq {
                        MF_Request_request msgInOut
                    }
                    
                } // End of group MF_SAP
                
                /**
                 * @desc    MF-SAP service primitives
                 * @see     ISO/CD 24102-3 Clause 7.1
                 */
                group MN_SAP {
                    
                    /**
                     * @desc    Management service primitive MN-COMMAND.request
                     * @see     ISO/CD 24102-3 Clause 7.2.2
                     */
                    type record MgtMNSapCommandReq {
                        MN_Command_request msgInOut
                    }
                    
                    /**
                     * @desc    Management service primitive MN-REQUEST.request
                     * @see     ISO/CD 24102-3 Clause 7.3.2
                     */
                    type record MgtMNSapRequestReq {
                        MN_Request_request msgInOut
                    }
                    
                    /**
                     * @desc    Management service primitive MN-COMMAND.confirm
                     * @see     ISO/CD 24102-3 Clause 7.2.3
                     */
                    type record MgtMNSapCommandConfirm {
                        MN_Command_confirm msgIn
                    }
                    
                    /**
                     * @desc    Management service primitive MN-REQUEST.confirm
                     * @see     ISO/CD 24102-3 Clause 7.3.3
                     */
                    type record MgtMNSapRequestConfirm {
                        MN_Request_confirm msgIn
                    }
                    
                } // End of group MN_SAP
                
            } // End of group mgt2Primitives
            
        } // End of group managementPrimitives 
        
        group networkAndTransportPrimitives { 
            
                    
            
            group nt3Primitives {
                
//                /**
//                 * @desc NT3 Fast Indication Primitive 
//                 */
//                type record FastInd {
//                }
//            
//                /**
//                 * @desc NT3 Fast Request Primitive 
//                 */
//                type record FastReq {
//                }
//            
            } // end nt3Primitives
            
        } // End of group networkAndTransportPrimitives
        
    }
    
	group upperTester {
		
		/**
		 * @desc Upper Tester message to initialize IUT 
		 */
		type union UtInitialize {
			// Non IP Protocols
			UtFntpInitialize utFntpInitialize,
			UtFsapInitialize utFsapInitialize,
			UtIicpInitialize utIicpInitialize
		}

		/**
		 * @desc Upper Tester message to trigger an action on IUT 
		 */
		type record UtTrigger {
			UtEvent utEvent
		}

		/**
		 * @desc Upper Tester message to check event/status on IUT 
		 */    
		type record UtCheck {
			UtEvent utEvent
		}

		/**
		 * @desc Upper Tester message describing an action/event 
		 */
		type union UtEvent {
			// Non IP Protocols
			UtFntpEvent utFntpEvent,
			UtFsapEvent utFsapEvent
		}

		/**
		 * @desc Upper Tester message describing an action/event 
		 */
		type union UtCommandRequest {
			UtFntpCommandRequest utFntpCommandRequest,
			UtFsapCommandRequest utFsapCommandRequest
		}

		/**
		 * @desc Upper Tester message describing an action/event 
		 */
		type union UtCommandConfirm {
			UtFntpCommandConfirm utFntpCommandConfirm
//		   FIXME To be removed       UtFsapCommandConfirm utFsapCommandConfirm
		}

		/**
		 * @desc Upper Tester message describing an action/event 
		 */
		type union UtCommandIndication {
			UtFntpCommandIndication utFntpCommandIndication
			//UtFsapCommandIndication utFsapCommandIndication
		}

		/**
		 * @desc Upper Tester response message  
		 */    
		type boolean UtResult;
        
			/**
			 * @desc Upper tester functions
			 */
			group utFuntions { 
            
				/**
				 * @desc    Requests to bring the IUT in an initial state
				 * @param   p_init The initialisation to trigger.
				 */
				function f_utInitializeIut(template (value) UtInitialize p_init) runs on ItsCalm {
                
					utPort.send(p_init);
					tc_wait.start;
					alt {
						[] utPort.receive(UtResult:true) {
							tc_wait.stop;
							log("*** f_utInitializeIut: INFO: IUT initialized ***");
						}
						[] utPort.receive {
							tc_wait.stop;
							log("*** f_utInitializeIut: INFO: IUT could not be initialized ***");
							f_selfOrClientSyncAndVerdict("error", e_error);
						}
						[] tc_wait.timeout {
							log("*** f_utInitializeIut: INFO: IUT could not be initialized in time ***");
							f_selfOrClientSyncAndVerdict("error", e_timeout);
						}
						[else] { // Shortcut defaults
							repeat; 
						}
					}
                
				}
            
				/**
				 * @desc    Triggers event from the application layer
				 * @param   p_event The event to trigger.
				 */
				function f_utTriggerEvent(template (value) UtEvent p_event) runs on ItsCalm {
					var template (value) UtTrigger v_utMsg := { p_event };
                
					utPort.send(v_utMsg);
					alt {
						[] utPort.receive(UtResult:true) {
							tc_wait.stop;
						}
						[] utPort.receive {
							tc_wait.stop;
						}
						[] tc_wait.timeout {
						}
						[else] { // Shortcut defaults
							repeat; 
						}
					}
				}
            
				/**
				 * @desc Checks that the event was indicated at the application layer
				 * @param p_event The event to check.
				 * @param   p_discard The event should not appear. Default value: FALSE.
				 */
				function f_utCheckEvent(template (value) UtEvent p_event, boolean p_discard) runs on ItsCalm {
					var template (value) UtCheck v_utMsg := { p_event };
                
					utPort.send(v_utMsg);
					tc_wait.start;
					alt {
						[] utPort.receive(UtResult:true) {
							tc_wait.stop;
							if (p_discard == false) {
								log("*** f_utCheckEvent: INFO: Event correctly indicated at application layer ***");
							}
							else {
								log("*** f_utCheckEvent: ERROR: Event indicated at application layer where it should be discarded ***");
								f_selfOrClientSyncAndVerdict("error", e_error);
							}
						}
						[] utPort.receive(UtResult:false) {
							tc_wait.stop;
							if (p_discard == false) {
								log("*** f_utCheckEvent: ERROR: Event not correctly indicated at application layer ***");
								f_selfOrClientSyncAndVerdict("error", e_error);
							}
							else {
								log("*** f_utCheckEvent: INFO: Event not indicated at application layer***");
							}
						}
						[] tc_wait.timeout {
							log("*** f_utCheckEvent: ERROR: Timeout while waiting for event check result ***");
							f_selfOrClientSyncAndVerdict("error", e_timeout);                    
						}
						[else] { // Shortcut defaults
							repeat; 
						}
					}
				}
            
				/**
				 * @desc    Send a command request primitive and wait for the command confirm response
				 * @param   p_commandReq    The command request
				 * @param   p_commandConf   The command confirm response
				 * @param   p_discard       Set to true if command confirm responses shall be discard, otherwise the function failed 
				 * @param   p_result        The command/request confirm response
				 * @verdict Unchanged on success, fail otherwise
				 */
				function f_utCommandRequestConfirm(
					in template (value) UtCommandRequest p_commandReq, 
					in template (present) UtCommandConfirm p_commandConf, 
					in boolean p_discard, 
					out UtCommandConfirm p_result) 
				runs on ItsCalm {
                
					utPort.send(p_commandReq);
					tc_wait.start;
					alt {
						[] utPort.receive(p_commandConf) -> value p_result{
							tc_wait.stop;
						}
						[] utPort.receive {
							tc_wait.stop;
							if (p_discard == false) {
								log("*** f_utCommandRequestConfirm: ERROR: Event not correctly indicated at application layer ***");
								f_selfOrClientSyncAndVerdict("error", e_error);
							}
							else {
								log("*** f_utCommandRequestConfirm: INFO: Another event indicated at application layer, repeating check ***");
								repeat;
							}
						}
						[] tc_wait.timeout {
							if (p_discard == false) {
								log("*** f_utCommandRequestConfirm: ERROR: Timeout while waiting for event check result ***");
								f_selfOrClientSyncAndVerdict("error", e_timeout);
							}
							else {
								log("*** f_utCommandRequestConfirm: INFO: Event not indicated at application layer ***");
							}
						}
					} // end of 'alt' statement
                
				} // End of function f_utCommandRequestConfirm
            
					/**
					 * @desc    Send a command request primitive and do not wait for the command confirm response
					 * @param   p_commandReq    The command request
					 * @verdict Unchanged on success, fail otherwise
					 */
					function f_utCommandRequestWithoutConfirm(
						in template (value) UtCommandRequest p_commandReq 
					) runs on ItsCalm {
						utPort.send(p_commandReq);
					} // End of function f_utCommandRequestWithoutConfirm
                
				/**
				 * @desc Capture the next event sent to the Upper Tester
				 * @param   p_event     Receive template of the expected event
				 * @param   p_result    Return the value of the received event if template matchs
				 */
				function f_utCommandIndication( 
					in template UtCommandIndication p_event,
					out UtCommandIndication p_result
				) runs on ItsCalm {
                
					tc_wait.start;
					alt {
						[] utPort.receive(p_event) -> value p_result {
							tc_wait.stop;
						}
						[] utPort.receive {
							tc_wait.stop;
							log("*** f_utCommandIndication: INFO: Another event indicated at application layer, repeating check ***");
						}
						[] tc_wait.timeout {
							log("*** f_utCommandIndication: ERROR: Timeout while waiting for event check result ***");
						}
					} // end of 'alt' statement
                
				} // End of function f_utCommandIndication
            
			} // End of group utFunctions
	} // End of group upper tester		
    with {
        encode "LibIts_Interface"
    } // end interfacePrimitives    
    
} // End of module LibItsCalm_Interface