ItsCam_TestCases.ttcn 182 KB
Newer Older
filatov's avatar
filatov committed
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000
/**
 *    @author   ETSI / STF405 / STF449
 *    @version  $URL$
 *              $Id$
 *    @desc     CAM Testcases (TP version: 0.0.1)
 *
 */

module ItsCam_TestCases {
    
    // LibCommon
    import from LibCommon_Sync all;
    import from LibCommon_VerdictControl all;
    import from LibCommon_Time all;
    
    // LibIts
    import from LibItsCommon_Functions all;
    import from LibItsCommon_TypesAndValues {
        type UtChangePosition
    };
    import from LibItsCam_TestSystem all;
    import from LibItsCam_Functions all;
    import from LibItsCam_Templates all;
    import from LibItsCam_TypesAndValues all;
    import from LibItsCam_Pics {modulepar all};
    
    import from ITS_Container language "ASN.1:1997" all;
    import from CAM_PDU_Descriptions language "ASN.1:1997" all;
    import from DENM_PDU_Descriptions language "ASN.1:1997" all;

    // 5.2.1
    group camMessageDissemination { 
        
        group camMessageFormat {
            
            /**
             * @desc Check that protocolVersion is set to 1 and messageID is 
             *       set to 2.
             * <pre>
             * Pics Selection: PICS_CAMHEADER
             * Initial conditions: 
             *     with {
             *         the IUT being in the "initial state"
             *     }
             * Expected behaviour:
             *     ensure that {
             *         when {
             *             a CAM is generated 
             *         }
             *         then {
             *             the IUT sends a valid CAM
             *                 containing ITS PDU header
             *                     containing protocolVersion
             *                         indicating value 1
             *                     and containing messageID
             *                         indicating value 2
             *         }
             *     }
             * </pre>
             * 
             * @version   0.0.2
             * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/FMT/BV-01
             * @reference ETSI EN 302 637-2 , Annex B.1
             */
            testcase TC_CAM_MSD_FMT_BV_01() runs on ItsCam system ItsCamSystem {
                
                // Local variables
                
                // Test control
                
                // Test component configuration
                f_cfUp();
                
                // Test adapter configuration
                
                // Preamble
                f_prInitialState();
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                
                // Test Body
                tc_ac.start;
                alt {
                    [] camPort.receive(mw_camInd ( mw_camMsg_any )){ 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Expected CAM message received ***");
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);  
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: CAM message not received ***");
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // end TC_CAM_MSD_FMT_BV_01
            
            /**
             * @desc Check that LF container is included in 1st CAM since CA 
             *       basic service activation.
             * <pre>
             * Pics Selection: PICS_LOWFREQUENCYCONTAINER
             * Initial conditions: 
             *     with {
             *         the IUT being in the "initial state"
             *         and the IUT has not sent any CAM yet
             *     }
             * Expected behaviour:
             *     ensure that {
             *         when {
             *             a CAM is generated 
             *         }
             *         then {
             *             the IUT sends a valid CAM
             *                 containing cam
             *                     containing camParameters
             *                         containing lowFrequencyContainer
             *         }
             *     }
             * </pre>
             * 
             * @version   0.0.2
             * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/FMT/BV-02
             * @reference ETSI EN 302 637-2 , clause 6.1.3
             */
            testcase TC_CAM_MSD_FMT_BV_02() runs on ItsCam system ItsCamSystem {
                
                // Local variables
                
                // Test control
                
                // Test component configuration
                f_cfUp();
                
                // Test adapter configuration
                
                // Preamble
                f_prInitialState();
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                
                // Test Body
                tc_ac.start;
                alt {
                    [] camPort.receive(mw_camInd ( mw_camMsg_LF_any )){ 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Expected CAM message received ***");
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);  
                    }
                    [] camPort.receive(mw_camInd ( mw_camMsg_any )){ 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": FAIL: Expected CAM message not received ***");
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_error);  
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: CAM message not received ***");
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // end TC_CAM_MSD_FMT_BV_02
            
            /**
             * @desc Check that LF container is included if time elapsed since 
             *       the generation of the last CAM with the low frequency 
             *       container generation is equal or larger than 500 ms.
             * <pre>
             * Pics Selection: PICS_LOWFREQUENCYCONTAINER
             * Initial conditions: 
             *     with {
             *         the IUT being in the "initial state"
             *         and the IUT has sent a CAM
             *             containing cam
             *                 containing camParameters
             *                     containing lowFrequencyContainer at time TIME_1
             *         and the IUT has not sent CAM
             *             containing cam
             *                 containing camParameters
             *                     containing lowFrequencyContainer after TIME_1
             *     }
             * Expected behaviour:
             *     ensure that {
             *         when {
             *             a CAM is generated at time TIME_2 >= (TIME_1 + 500ms)
             *         }
             *         then {
             *             the IUT sends a valid CAM
             *                 containing cam
             *                     containing camParameters
             *                         containing lowFrequencyContainer
             *         }
             *     }
             * </pre>
             * 
             * @version   0.0.2
             * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/FMT/BV-03
             * @reference ETSI EN 302 637-2 , clause 6.1.3
             */
            testcase TC_CAM_MSD_FMT_BV_03() runs on ItsCam system ItsCamSystem {
                
                // Local variables
                timer t_minTransInterval := c_lowFrequencyGenerationTime * 1.05;
                var SpeedValue v_speedValues[5] := { 1000, 2000, 3000, 4000, 5000 } //cm/s
                var integer v_cntSpeed, v_cntTime;
                var CamInd v_camInd;
                var boolean v_nextCamWithLF := false;
                const integer c_cntTimeLimit := 10;
                
                // Test control
                
                // Test component configuration
                f_cfUp();
                
                // Test adapter configuration
                
                // Preamble
                f_prInitialState();
                camPort.clear;
                tc_ac.start;
                alt {
                     [] camPort.receive(mw_camInd ( mw_camMsg_LF_any )){ 
                        tc_ac.stop;
                        t_minTransInterval.start;
                        log("*** " & testcasename() & ": INFO: Initial conditions: First CAM message received ***");
                        f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Initial conditions: CAM message not received ***");
                        f_selfOrClientSyncAndVerdictPreamble("error", e_timeout);
                    }
                }
                
                // Test Body
                for (v_cntSpeed:=0; v_cntSpeed<lengthof(v_speedValues); v_cntSpeed:=v_cntSpeed + 1) {
                    f_utTriggerEvent(m_changeSpeed(v_speedValues[v_cntSpeed]));
                    v_cntTime := 0;
                    tc_ac.start;
                    alt {
                    	[] camPort.receive(mw_camInd ( mw_camMsg_LF_any )) {
                    		tc_ac.stop; 
                    		v_cntTime := v_cntTime + 1;
                            if (v_cntTime == c_cntTimeLimit) { // Exit message loop
                                log("*** " & testcasename() & ": INFO: The subset of CAM messages including lowFrequencyContainer was received ***");
                                t_minTransInterval.start;
                                v_nextCamWithLF := false;                                
                            }
                            else {
                                log("*** " & testcasename() & ": INFO: CAM retransmission with LowFrequency container ***"); 
                                tc_ac.start;
                                t_minTransInterval.start;
                                v_nextCamWithLF := false;
                                repeat;
                            }
                    	}
                        [] camPort.receive(mw_camInd ( mw_camMsg_any )) -> value v_camInd {
                            tc_ac.stop;
                        	if(v_nextCamWithLF == true) {
                        		log("*** " & testcasename() & ": FAIL: No LowFrequency container in received CAM ***");
                                f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_error);
                        	}
                        	else {
                                log("*** " & testcasename() & ": INFO: CAM retransmission w/o LowFrequency container ***"); 
                                tc_ac.start;
                                repeat;
                        	}
                        }
                        [] t_minTransInterval.timeout {
                        	v_nextCamWithLF := true;
                            log("*** " & testcasename() & ": INFO: Next CAM shall contain LowFrequency container ***");
                            repeat;  
                        }
                        [] tc_ac.timeout {
                            log("*** " & testcasename() & ": INCONC: CAM message not received ***");
                            f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                        }
                    } 
                } 
                log("*** " & testcasename() & ": PASS: Generation of CAM messages including lowFrequencyContainer was successful ***");
                f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);  
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // end TC_CAM_MSD_FMT_BV_03
            
            
            /**
             * @desc Check that specialVehicle container is included in 1st CAM 
             *       since CA basic service activation.
             * <pre>
             * Pics Selection: PICS_SPECIALVEHICLECONTAINER
             * Initial conditions: 
             *     with {
             *         the IUT being in the "initial state"
             *         and the IUT is configured to advertise itself as a special vehicle
             *         and the IUT has not sent any CAM yet
             *     }
             * Expected behaviour:
             *     ensure that {
             *         when {
             *             a CAM is generated
             *         }
             *         then {
             *             the IUT sends a valid CAM
             *                 containing cam
             *                     containing camParameters
             *                         containing specialVehicleContainer
             *         }
             *     }
             * </pre>
             * 
             * @version   0.0.2
             * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/FMT/BV-04
             * @reference ETSI EN 302 637-2 , clause 6.1.3
             */
            testcase TC_CAM_MSD_FMT_BV_04() runs on ItsCam system ItsCamSystem {
                
                // Local variables
                var VehicleRole v_vehicleRole := c_vehicleRole_roadWork;
                
                // Test control
                if (not PICS_SPECIALVEHICLECONTAINER) {
                    testcase.stop(testcasename() & ": PICS_SPECIALVEHICLECONTAINER needs to be set to true");
                }
                
                // Test component configuration
                f_cfUp();
                
                // Test adapter configuration
                
                // Preamble
                f_prInitialState();
                f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                
                // Set vehicle role
                f_utTriggerEvent(m_setVehicleRole(v_vehicleRole));
                
                // Test Body
                tc_ac.start;
                alt {
                    [] camPort.receive(mw_camInd ( mw_camMsg_SVC_any )){ 
                        tc_ac.stop;
                        log("*** " & testcasename() & ": PASS: Expected CAM message received ***");
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);  
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: CAM message not received ***");
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                    }
                }
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // end TC_CAM_MSD_FMT_BV_04
            
            /**
             * @desc Check that specialVehicle container is included if time 
             *       elapsed since the generation of the last CAM with the 
             *       special vehicle container generation is equal or larger 
             *       than 500 ms.
             * <pre>
             * Pics Selection: PICS_SPECIALVEHICLECONTAINER
             * Initial conditions: 
             *     with {
             *         the IUT being in the "initial state"
             *         and the IUT has sent a CAM
             *             containing cam
             *                 containing camParameters
             *                     containing specialVehicleContainer at time TIME_1
             *         and the IUT has not sent CAM
             *             containing cam
             *                 containing camParameters
             *                     containing specialVehicleContainer after TIME_1
             *     }
             * Expected behaviour:
             *     ensure that {
             *         when {
             *             a CAM is generated at time TIME_2 >= (TIME_1 + 500ms)
             *         }
             *         then {
             *             the IUT sends a valid CAM
             *                 containing cam
             *                     containing camParameters
             *                         containing specialVehicleContainer
             *         }
             *     }
             * </pre>
             * 
             * @version   0.0.2
             * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/FMT/BV-05
             * @reference ETSI EN 302 637-2 , clause 6.1.3
             */
            testcase TC_CAM_MSD_FMT_BV_05() runs on ItsCam system ItsCamSystem {
                
                // Local variables
                timer t_minTransInterval := c_specialVehicleGenerationTime * 1.05;
                var VehicleRole v_vehicleRole := roadWork;
                var SpeedValue v_speedValues[5] := { 1000, 2000, 3000, 4000, 5000 } //cm/s
                var integer v_cntSpeed, v_cntTime;
                var CamInd v_camInd;
                var boolean v_nextCamWithSVC := false;
                const integer c_cntTimeLimit := 10;
                
                // Test control
                if (not PICS_SPECIALVEHICLECONTAINER) {
                    testcase.stop(testcasename() & ": PICS_SPECIALVEHICLECONTAINER needs to be set to true");
                }
                
                // Test component configuration
                f_cfUp();
                
                // Test adapter configuration
                
                // Preamble
                f_prInitialState();
                // Set vehicle role
                f_utTriggerEvent(m_setVehicleRole(v_vehicleRole));
                camPort.clear;
                tc_ac.start;
                alt {
                     [] camPort.receive(mw_camInd ( mw_camMsg_SVC_any )){ 
                        tc_ac.stop;
                        t_minTransInterval.start;
                        log("*** " & testcasename() & ": INFO: Initial conditions: First CAM message received ***");
                        f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    }
                    [] tc_ac.timeout {
                        log("*** " & testcasename() & ": INCONC: Initial conditions: CAM message not received ***");
                        f_selfOrClientSyncAndVerdictPreamble("error", e_timeout);
                    }
                }
                
                // Test Body
                for (v_cntSpeed:=0; v_cntSpeed<lengthof(v_speedValues); v_cntSpeed:=v_cntSpeed + 1) {
                    f_utTriggerEvent(m_changeSpeed(v_speedValues[v_cntSpeed]));
                    v_cntTime := 0;
                    tc_ac.start;
                    alt {
                        [] camPort.receive(mw_camInd ( mw_camMsg_SVC_any )) {
                            tc_ac.stop; 
                            v_cntTime := v_cntTime + 1;
                            if (v_cntTime == c_cntTimeLimit) { // Exit message loop
                                log("*** " & testcasename() & ": INFO: The subset of CAM messages including specialVehicleContainer was received ***");
                                t_minTransInterval.start;
                                v_nextCamWithSVC := false;                                
                            }
                            else {
                                log("*** " & testcasename() & ": INFO: CAM retransmission with SpecialVehicle container ***"); 
                                tc_ac.start;
                                t_minTransInterval.start;
                                v_nextCamWithSVC := false;
                                repeat;
                            }
                        }
                        [] camPort.receive(mw_camInd ( mw_camMsg_any )) -> value v_camInd {
                            tc_ac.stop;
                            if(v_nextCamWithSVC == true) {
                                log("*** " & testcasename() & ": FAIL: No SpecialVehicle container in received CAM ***");
                                f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_error);
                            }
                            else {
                                log("*** " & testcasename() & ": INFO: CAM retransmission w/o SpecialVehicle container ***"); 
                                tc_ac.start;
                                repeat;
                            }
                        }
                        [] t_minTransInterval.timeout {
                            v_nextCamWithSVC := true;
                            log("*** " & testcasename() & ": INFO: Next CAM shall contain SpecialVehicle container ***");
                            repeat;  
                        }
                        [] tc_ac.timeout {
                            log("*** " & testcasename() & ": INCONC: CAM message not received ***");
                            f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                        }
                    } 
                } 
                log("*** " & testcasename() & ": PASS: Generation of CAM messages including SpecialVehicleContainer was successful ***");
                f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);  
                
                // Postamble
                f_poDefault();
                f_cfDown();
                
            } // end TC_CAM_MSD_FMT_BV_05
            
        } // end group camMessageFormat
        
        group camInformationAdaptation {
            
            group camInVehicleData {
                
                type record of UtCamTrigger UtCamTriggers;
                type record of CAM CamPdus;
                
                function f_CAM_MSD_INA_BV_01(in charstring p_INFO, in template (value) UtCamTriggers p_utTriggers, in template (present) CamPdus p_camPdus) runs on ItsCam {
                    
                    // Local variables
                    var integer v_cnt;
                    
                    log("*** " & testcasename() & ": Checking INFO==" & p_INFO & " ***");
                    
                    if (lengthof(p_utTriggers) != lengthof(p_camPdus)) {
                        log("*** " & testcasename() & ": INCONC: Invalid testcase configuration: Number of event triggers and expected CAM messages differs ***");
                        f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                    }
                    
                    for (v_cnt:=0; v_cnt<lengthof(p_utTriggers); v_cnt:=v_cnt+1) {
                        f_utTriggerEvent(p_utTriggers[v_cnt]);
                        
                        tc_ac.start;
                        alt {
                            [] camPort.receive( mw_camInd ( p_camPdus[v_cnt] )){ 
                                tc_ac.stop;
                                if (v_cnt==lengthof(p_utTriggers)-1) {
                                    log("*** " & testcasename() & ": PASS: Expected CAM message received ***");
                                    f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);  
                                }
                                else {
                                    log("*** " & testcasename() & ": PRECONDITION: Expected CAM message received ***");
                                }
                            }
                            [] tc_ac.timeout {
                                log("*** " & testcasename() & ": INCONC: CAM message not received ***");
                                f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                            }
                        }
                    }
                }
                
                /**
                 * @desc Check that latest value of in-vehicle data is included 
                 *       in CAM.
                 * <pre>
                 * Pics Selection: PICS_HIGHFREQUENCYCONTAINER
                 * Initial conditions: 
                 *     with {
                 *         the IUT being in the "initial state
                 *     }
                 *     INFO:  Curvature value
                 *     FIELD: highFrequencyContainer
                 *                .basicVehicleContainerHighFrequency
                 *                .curvature
                 *     VALUE: measured value
                 * 
                 * Expected behaviour:
                 *     ensure that {
                 *         when {
                 *             the IUT is alerted about INFO
                 *         }
                 *         then {
                 *             the IUT sends a valid CAM
                 *                 containing cam
                 *                     containing camParameters
                 *                         containing FIELD set to VALUE
                 *         }
                 *     }
                 * </pre>
                 * 
                 * @version   0.0.2
                 * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/INA/BV-01
                 * @reference ETSI EN 302 637-2 , clause 5.2
                 */
                testcase TC_CAM_MSD_INA_BV_01_01() runs on ItsCam system ItsCamSystem {
                    
                    // Local variables
                    var CamInd v_camInd;
                    var template (present) CurvatureValue v_curVal := ?;
                    var boolean v_initialReceived := false;
                    const CurvatureValue c_curValOffset := 1;
                    
                    // Test control
                    
                    // Test component configuration
                    f_cfUp();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    f_prInitialState();
                    f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                    // Test Body
                    log("*** " & testcasename() & ": Checking INFO==Curvature value ***");
                    
                    // change the curvature value to retrieve the current value
                    f_utTriggerEvent(m_changeCurvature(c_curValOffset));
                    
                    tc_ac.start;
                    alt {
                        [] camPort.receive( mw_camInd ( mw_camMsg_HF_BV(mw_HF_BV_curvature(v_curVal)) )) -> value v_camInd {
                            tc_ac.stop;
                            if (v_initialReceived) {
                                log("*** " & testcasename() & ": PASS: Expected CAM message received ***");
                                f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_success);  
                            }
                            else {
                                log("*** " & testcasename() & ": PRECONDITION: Expected CAM message received ***");
                                v_initialReceived := true;
                                //change again the curvature value and set the expectation to the measured value
                                v_curVal := v_camInd.msgIn.cam.camParameters.highFrequencyContainer.basicVehicleContainerHighFrequency.curvature.curvatureValue+c_curValOffset;
                                f_utTriggerEvent(m_changeCurvature(c_curValOffset));
                                tc_ac.start;
                                repeat;
                            }
                        }
                        [] tc_ac.timeout {
                            log("*** " & testcasename() & ": INCONC: CAM message not received ***");
                            f_selfOrClientSyncAndVerdictTestBody(c_tbDone, e_timeout);
                        }
                    }
                    
                    // Postamble
                    f_poDefault();
                    f_cfDown();
                    
                } // end TC_CAM_MSD_INA_BV_01_01
                
                /**
                 * @desc Check that latest value of in-vehicle data is included 
                 *       in CAM.
                 * <pre>
                 * Pics Selection: PICS_HIGHFREQUENCYCONTAINER
                 * Initial conditions: 
                 *     with {
                 *         the IUT being in the "initial state
                 *     }
                 *     INFO:  Brake pedal being activated
                 *     FIELD: highFrequencyContainer
                 *                .basicVehicleContainerHighFrequency
                 *                .accelerationControl
                 *                .brakePedalActive
                 *     VALUE: 1
                 * 
                 * Expected behaviour:
                 *     ensure that {
                 *         when {
                 *             the IUT is alerted about INFO
                 *         }
                 *         then {
                 *             the IUT sends a valid CAM
                 *                 containing cam
                 *                     containing camParameters
                 *                         containing FIELD set to VALUE
                 *         }
                 *     }
                 * </pre>
                 * 
                 * @version   0.0.2
                 * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/INA/BV-01-02
                 * @reference ETSI EN 302 637-2 , clause 5.2
                 */
                testcase TC_CAM_MSD_INA_BV_01_02() runs on ItsCam system ItsCamSystem {
                    
                    // Local variables
                    
                    // Test control
                    
                    // Test component configuration
                    f_cfUp();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    f_prInitialState();
                    f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                    // Test Body
                    f_CAM_MSD_INA_BV_01(
                        "Brake pedal being activated", 
                        { m_setAccelerationControlStatus(c_brakePedalEngaged) }, 
                        { mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_brakePedalActive_On)) }
                    );
                    
                    // Postamble
                    f_poDefault();
                    f_cfDown();
                    
                } // end TC_CAM_MSD_INA_BV_01_02
                
                /**
                 * @desc Check that latest value of in-vehicle data is included 
                 *       in CAM.
                 * <pre>
                 * Pics Selection: PICS_HIGHFREQUENCYCONTAINER
                 * Initial conditions: 
                 *     with {
                 *         the IUT being in the "initial state
                 *     }
                 *     INFO:  Brake pedal being deactivated
                 *     FIELD: highFrequencyContainer
                 *                .basicVehicleContainerHighFrequency
                 *                .accelerationControl
                 *                .brakePedalActive
                 *     VALUE: 0
                 * 
                 * Expected behaviour:
                 *     ensure that {
                 *         when {
                 *             the IUT is alerted about INFO
                 *         }
                 *         then {
                 *             the IUT sends a valid CAM
                 *                 containing cam
                 *                     containing camParameters
                 *                         containing FIELD set to VALUE
                 *         }
                 *     }
                 * </pre>
                 * 
                 * @version   0.0.2
                 * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/INA/BV-01-03
                 * @reference ETSI EN 302 637-2 , clause 5.2
                 */
                testcase TC_CAM_MSD_INA_BV_01_03() runs on ItsCam system ItsCamSystem {
                    
                    // Local variables
                    
                    // Test control
                    
                    // Test component configuration
                    f_cfUp();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    f_prInitialState();
                    f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                    // Test Body
                    f_CAM_MSD_INA_BV_01(
                        "Brake pedal being deactivated", 
                        { m_setAccelerationControlStatus(c_brakePedalEngaged), m_setAccelerationControlStatus(c_accCtrlIdle) },
                        { mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_brakePedalActive_On)), mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_brakePedalActive_Off)) }
                    );
                    
                    // Postamble
                    f_poDefault();
                    f_cfDown();
                    
                } // end TC_CAM_MSD_INA_BV_01_03
                
                /**
                 * @desc Check that latest value of in-vehicle data is included 
                 *       in CAM.
                 * <pre>
                 * Pics Selection: PICS_HIGHFREQUENCYCONTAINER
                 * Initial conditions: 
                 *     with {
                 *         the IUT being in the "initial state
                 *     }
                 *     INFO: Gas pedal being activated
                 *     FIELD: highFrequencyContainer
                 *                .basicVehicleContainerHighFrequency
                 *                .accelerationControl
                 *                .gasPedalActive
                 *     VALUE: 1
                 * 
                 * Expected behaviour:
                 *     ensure that {
                 *         when {
                 *             the IUT is alerted about INFO
                 *         }
                 *         then {
                 *             the IUT sends a valid CAM
                 *                 containing cam
                 *                     containing camParameters
                 *                         containing FIELD set to VALUE
                 *         }
                 *     }
                 * </pre>
                 * 
                 * @version   0.0.2
                 * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/INA/BV-01-04
                 * @reference ETSI EN 302 637-2 , clause 5.2
                 */
                testcase TC_CAM_MSD_INA_BV_01_04() runs on ItsCam system ItsCamSystem {
                    
                    // Local variables
                    
                    // Test control
                    
                    // Test component configuration
                    f_cfUp();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    f_prInitialState();
                    f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                    // Test Body
                    f_CAM_MSD_INA_BV_01(
                        "Gas pedal being activated", 
                        { m_setAccelerationControlStatus(c_gasPedalEngaged) },
                        { mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_gasPedalActive_On)) }
                    );
                    
                    // Postamble
                    f_poDefault();
                    f_cfDown();
                    
                } // end TC_CAM_MSD_INA_BV_01_04
                
                /**
                 * @desc Check that latest value of in-vehicle data is included 
                 *       in CAM.
                 * <pre>
                 * Pics Selection: PICS_HIGHFREQUENCYCONTAINER
                 * Initial conditions: 
                 *     with {
                 *         the IUT being in the "initial state
                 *     }
                 *     INFO: Gas pedal being deactivated
                 *     FIELD: highFrequencyContainer
                 *                .basicVehicleContainerHighFrequency
                 *                .accelerationControl
                 *                .gasPedalActive
                 *     VALUE: 0
                 * 
                 * Expected behaviour:
                 *     ensure that {
                 *         when {
                 *             the IUT is alerted about INFO
                 *         }
                 *         then {
                 *             the IUT sends a valid CAM
                 *                 containing cam
                 *                     containing camParameters
                 *                         containing FIELD set to VALUE
                 *         }
                 *     }
                 * </pre>
                 * 
                 * @version   0.0.2
                 * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/INA/BV-01-05
                 * @reference ETSI EN 302 637-2 , clause 5.2
                 */
                testcase TC_CAM_MSD_INA_BV_01_05() runs on ItsCam system ItsCamSystem {
                    
                    // Local variables
                    
                    // Test control
                    
                    // Test component configuration
                    f_cfUp();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    f_prInitialState();
                    f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                    // Test Body
                    f_CAM_MSD_INA_BV_01(
                        "Gas pedal being deactivated", 
                        { m_setAccelerationControlStatus(c_gasPedalEngaged), m_setAccelerationControlStatus(c_accCtrlIdle) },
                        { mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_gasPedalActive_On)), mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_gasPedalActive_Off)) }
                    );
                    
                    // Postamble
                    f_poDefault();
                    f_cfDown();
                    
                } // end TC_CAM_MSD_INA_BV_01_05
                
                /**
                 * @desc Check that latest value of in-vehicle data is included 
                 *       in CAM.
                 * <pre>
                 * Pics Selection: PICS_HIGHFREQUENCYCONTAINER
                 * Initial conditions: 
                 *     with {
                 *         the IUT being in the "initial state
                 *     }
                 *     INFO: Emergency brake being activated
                 *     FIELD: highFrequencyContainer
                 *                .basicVehicleContainerHighFrequency
                 *                .accelerationControl
                 *                .emergencyBrakeActive
                 *     VALUE: 1
                 * 
                 * Expected behaviour:
                 *     ensure that {
                 *         when {
                 *             the IUT is alerted about INFO
                 *         }
                 *         then {
                 *             the IUT sends a valid CAM
                 *                 containing cam
                 *                     containing camParameters
                 *                         containing FIELD set to VALUE
                 *         }
                 *     }
                 * </pre>
                 * 
                 * @version   0.0.2
                 * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/INA/BV-01-06
                 * @reference ETSI EN 302 637-2 , clause 5.2
                 */
                testcase TC_CAM_MSD_INA_BV_01_06() runs on ItsCam system ItsCamSystem {
                    
                    // Local variables
                    
                    // Test control
                    
                    // Test component configuration
                    f_cfUp();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    f_prInitialState();
                    f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                    // Test Body
                    f_CAM_MSD_INA_BV_01( 
                        "Emergency brake being activated", 
                        { m_setAccelerationControlStatus(c_emergencyBrakeEngaged) },
                        { mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_emergencyBrakeActive_On)) }
                    );
                    
                    // Postamble
                    f_poDefault();
                    f_cfDown();
                    
                } // end TC_CAM_MSD_INA_BV_01_06
                
                /**
                 * @desc Check that latest value of in-vehicle data is included 
                 *       in CAM.
                 * <pre>
                 * Pics Selection: PICS_HIGHFREQUENCYCONTAINER
                 * Initial conditions: 
                 *     with {
                 *         the IUT being in the "initial state
                 *     }
                 *     INFO: Emergency brake being deactivated
                 *     FIELD: highFrequencyContainer
                 *                .basicVehicleContainerHighFrequency
                 *                .accelerationControl
                 *                .emergencyBrakeActive
                 *     VALUE: 0
                 * 
                 * Expected behaviour:
                 *     ensure that {
                 *         when {
                 *             the IUT is alerted about INFO
                 *         }
                 *         then {
                 *             the IUT sends a valid CAM
                 *                 containing cam
                 *                     containing camParameters
                 *                         containing FIELD set to VALUE
                 *         }
                 *     }
                 * </pre>
                 * 
                 * @version   0.0.2
                 * @see       ETSI TS 102 868-2 v0.0.2 TP/CAM/MSD/INA/BV-01-07
                 * @reference ETSI EN 302 637-2 , clause 5.2
                 */
                testcase TC_CAM_MSD_INA_BV_01_07() runs on ItsCam system ItsCamSystem {
                    
                    // Local variables
                    
                    // Test control
                    
                    // Test component configuration
                    f_cfUp();
                    
                    // Test adapter configuration
                    
                    // Preamble
                    f_prInitialState();
                    f_selfOrClientSyncAndVerdictPreamble(c_prDone, e_success);
                    
                    // Test Body
                    f_CAM_MSD_INA_BV_01(
                        "Emergency brake being deactivated", 
                        { m_setAccelerationControlStatus(c_emergencyBrakeEngaged), m_setAccelerationControlStatus(c_accCtrlIdle) },
                        { mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_emergencyBrakeActive_On)), mw_camMsg_HF_BV(mw_HF_BV_accCtrl(mw_emergencyBrakeActive_Off)) }
                    );
                    
                    // Postamble
                    f_poDefault();
                    f_cfDown();
                    
                } // end TC_CAM_MSD_INA_BV_01_07
                
                /**
                 * @desc Check that latest value of in-vehicle data is included