AtsSecurity_Functions.ttcn3 13.1 KB
Newer Older
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
/**
 *  @author     ETSI / STF481
 *  @version    $URL$
 *              $Id$
 *  @desc       Module containing functions for the secured GN ATS
 *
 */
module AtsSecurity_Functions {
    
    // LibIts
    import from DENM_PDU_Descriptions language "ASN.1:1997" all;
    import from ITS_Container language "ASN.1:1997" all;

    // LibCommon
    import from LibCommon_BasicTypesAndValues all;
    import from LibCommon_Time all;
    
    // LibItsCommon
    import from LibItsCommon_TypesAndValues all;
    import from LibItsCommon_TestSystem all;
    import from LibItsCommon_Functions all;
    
    // LibItsDenm
    import from LibItsDenm_TypesAndValues all;
    import from LibItsDenm_Templates all;
    import from LibItsDenm_Functions all;
    import from LibItsDenm_TestSystem all;
    
    // LibItsCam
//    import from LibItsCam_TypesAndValues all;
    import from LibItsCam_Templates all;
    import from LibItsCam_Functions all;
    import from LibItsCam_TestSystem all;
    
    // LibItsGeoNetworking
    import from LibItsGeoNetworking_TestSystem all;
    import from LibItsGeoNetworking_Functions all;
    import from LibItsGeoNetworking_Templates all;
    import from LibItsGeoNetworking_TypesAndValues all;
    
    // LibItsSecurity
    import from LibItsSecurity_TypesAndValues all;
    import from LibItsSecurity_Templates all;
    import from LibItsSecurity_Functions all;
    import from LibItsSecurity_Pixits all;
    
    group secCam {
        
        /**
        * @desc   Prepare a secured CAM
        * @param  p_configId            The configuration identifier to be used
        * @param  p_headerFields        HeaderFields to be inserted in the message
        * @param  p_signerInfoType      Add digest or AT certificate or certificate chain
        * @param  p_addMissingHeaders   Whether to add mandatory headers not present in p_headerFields
        * @return Secured GeoNetworking packet containing a CAM
        */
        function f_prepareSecuredCam(
                                     in charstring p_configId,
                                     in template (omit) HeaderFields p_headerFields := omit,
                                     in SignerInfoType p_signerInfoType := e_certificate_digest_with_sha256,
                                     in boolean p_addMissingHeaders := true
        ) runs on ItsGeoNetworking return GeoNetworkingPdu {
            // Local variables
            var GnNonSecuredPacket v_gnNonSecuredPacket;
            var octetstring v_gnPayload;
            var template (value) SecuredMessage v_securedMessage;
            
            // Build signed SecuredMessage
            v_gnNonSecuredPacket := valueof(m_geoNwShbPacket(
                f_getPosition(c_compNodeC)
            ));
            
            // Add CAM payload
            v_gnNonSecuredPacket.payload := valueof(
                f_adaptPayload_m(
                    bit2oct(
                        encvalue(
                            m_camReq(
                                m_camMsg_vehicle_HF_BV(
                                    f_getTsStationId(),
                                    f_getCurrentTime() mod 65536, // See ETSI EN 302 637-2 V1.3.0 - Clause B.3 generationDelatTime
                                    LibItsCam_Templates.m_tsPosition
            ))))));
            
            // Encode it
            v_gnPayload := bit2oct(
                encvalue(
                    v_gnNonSecuredPacket
                )
            );
            f_buildGnSecuredCam(
                v_securedMessage,
                m_payload_signed(v_gnPayload),
                p_signerInfoType,
                p_headerFields,
                p_configId,
                p_addMissingHeaders
            );
            
            // Return secured Gn packet
            return valueof(m_geoNwSecPdu(v_gnNonSecuredPacket, v_securedMessage));
        } // End of function f_prepareSecuredCam
        
        /**
        * @desc   Sends a secured CAM
        * @param  p_configId        The configuration identifier to be used
        * @param  p_headerFields    Additional HeaderFields
        * @param  p_signerInfoType  Add digest or AT certificate or certificate chain
        * @return GeoNetworking payload
        */
        function f_sendSecuredCam(
                                  in charstring p_configId,
                                  in template (omit) HeaderFields p_headerFields := omit,
                                  in SignerInfoType p_signerInfoType := e_certificate_digest_with_sha256
        ) runs on ItsGeoNetworking return GeoNetworkingPdu {
            // Local variables
            var GeoNetworkingPdu v_securedGnPdu := f_prepareSecuredCam(p_configId, p_headerFields, p_signerInfoType);
                   
            f_sendGeoNetMessage(m_geoNwReq_linkLayerBroadcast(v_securedGnPdu));
                        
            return v_securedGnPdu;
            
        } // End of function f_sendSecuredCam
        
    } // End of group secCam
    
    group secDenm {
        
        /**
        * @desc   Prepare a secured CENM
        * @param  p_configId            The configuration identifier to be used
        * @param  p_headerFields        HeaderFields to be inserted in the message
        * @param  p_signerInfoType      Add digest or AT certificate or certificate chain
        * @param  p_addMissingHeaders   Whether to add mandatory headers not present in p_headerFields
        * @return Secured GeoNetworking packet containing a CAM
        */
        function f_prepareSecuredDenm(
                                      in charstring p_configId,
                                      in template (omit) HeaderFields p_headerFields := omit,
                                      in SignerInfoType p_signerInfoType := e_certificate_digest_with_sha256,
                                      in boolean p_addMissingHeaders := true
        ) runs on ItsGeoNetworking return GeoNetworkingPdu {
            // Local variables
            var GnNonSecuredPacket v_gnNonSecuredPacket;
            var octetstring v_gnPayload;
            var LongPosVector v_longPosVectorNodeC := f_getPosition(c_compNodeC);
            var template (value) SecuredMessage v_securedMessage;
            var template (value) SituationContainer v_situation := m_situation(c_causeVehicleBreakdown, c_subCauseCode_Unavailable);
            
            // Build signed SecuredMessage
            v_gnNonSecuredPacket := valueof(
                m_geoNwBroadcastPacket(
                    v_longPosVectorNodeC,
                    vc_localSeqNumber,
                    f_getGeoBroadcastArea(
                        c_area2
            )));
            
            // Add the DENM payload
            v_gnNonSecuredPacket.payload := valueof(
                f_adaptPayload_m(
                    bit2oct(
                        encvalue(
                            m_denmReq(
                                m_denmPdu(
                                    m_denm(
                                        m_denmMgmtCon(
                                            m_tsActionId
                                        ),
                                        v_situation,
                                        m_denmLocation_zeroDelta
            )))))));
            
            // Encode it
            v_gnPayload := bit2oct(
                encvalue(
                    v_gnNonSecuredPacket
                )
            );
            f_buildGnSecuredDenm(
                v_securedMessage,
                m_payload_signed(v_gnPayload),
                p_signerInfoType,
                valueof(m_threeDLocation(
                    v_longPosVectorNodeC.latitude,
                    v_longPosVectorNodeC.longitude,
                    '0000'O
                )),
                p_headerFields,
                p_configId,
                p_addMissingHeaders
            );
            
            // Return secured Gn packet
            return valueof(m_geoNwSecPdu(v_gnNonSecuredPacket, v_securedMessage));
        } // End of function f_prepareSecuredDenm
        
        /**
        * @desc   Sends a secured DENM
        * @param  p_configId        The configuration identifier to be used
        * @param  p_headerFields    Additional HeaderFields
        * @param  p_signerInfoType  Add digest or AT certificate or certificate chain
        * @return GeoNetworking payload
        */
        function f_sendSecuredDenm(
                                  in charstring p_configId,
                                  in template (omit) HeaderFields p_headerFields := omit,
                                  in SignerInfoType p_signerInfoType := e_certificate_digest_with_sha256
        ) runs on ItsGeoNetworking return GeoNetworkingPdu {
            // Local variables
            var GeoNetworkingPdu v_securedGnPdu := f_prepareSecuredDenm(p_configId, p_headerFields, p_signerInfoType);
                   
            f_sendGeoNetMessage(m_geoNwReq_linkLayerBroadcast(v_securedGnPdu));
                        
            return v_securedGnPdu;
            
        } // End of function f_sendSecuredDenm
        
    } // End of group secDenm 
    
    group camTrigger {
        
        /**
        * @desc    Triggers a CAM change speed event to get a CAM frequency greather than 1 Hz (i.e. more than one CAM per seconds)
        * @remark  This function spawns an ItsCam component in alive mode
        * @see     fb_changeCamFrequencyGreatherThan1Hz()
        * @return  Reference to the component used to send the trigger
        */
        function f_setCamFrequencyGreatherThan1Hz() runs on ItsBaseComponent return ItsCam {
            var ItsCam v_camComponent;
            
            v_camComponent := ItsCam.create("CAM Trigger");
            v_camComponent.start(fb_setCamFrequencyGreatherThan1Hz());
            v_camComponent.done;
            
            return v_camComponent;
        } // End of function f_setCamFrequencyGreatherThan1Hz
        
        /**
        * @desc Behaviour function for triggering a CAM change speed event on IUT
        */
        function fb_setCamFrequencyGreatherThan1Hz() runs on ItsCam {
            
            // Local variables
            var SpeedValue v_speedValue := 1667; // in cm/s, e.g. 60Km/h = 1667 cm/s
            
            map(self:utPort, system:camUtPort);
            
            LibItsCam_Functions.f_utTriggerEvent(valueof(m_changeSpeed(v_speedValue)));
            
            unmap(self:utPort, system:camUtPort);
        }  // End of function fb_setCamFrequencyGreatherThan1Hz
        
    } // End of group camTrigger 
    
    group denmTrigger {
        
        /**
        * @desc    Triggers a DENM event on IUT
        * @remark  This function spawns an ItsDenm component in alive mode
        * @see     fb_secTriggerDenmEvent()
        * @return  Reference to the component used to send the trigger
        */
        function f_triggerDenmEvent() runs on ItsBaseComponent return ItsDenm {
            var ItsDenm v_denmComponent;
            
            v_denmComponent := ItsDenm.create("DENM Trigger") alive;
            v_denmComponent.start(fb_secTriggerDenmEvent());
            v_denmComponent.done;
            
            return v_denmComponent;
        } // End of function f_triggerDenmEvent
        
        /**
        * @desc    Cancels all previously triggered DENM events on IUT
        * @param   p_denmComponent     Reference of the component previously used to trigger DENM events
        * @see     fb_secCancelDenmEvent()
        */
        function f_cancelDenmEvent(ItsDenm p_denmComponent) runs on ItsBaseComponent {
            p_denmComponent.start(fb_secCancelDenmEvent());
            p_denmComponent.done;
            p_denmComponent.kill;
        } // End of function f_cancelDenmEvent
        
        /**
        * @desc Behaviour function for triggering a DENM event on IUT
        */
        function fb_secTriggerDenmEvent() runs on ItsDenm {
            
            // Local variables
            var template (value) SituationContainer v_situation := m_situation(c_causeVehicleBreakdown, c_subCauseCode_Unavailable);
            
            map(self:utPort, system:denmUtPort);
            vc_default := activate(LibItsDenm_Functions.a_utDefault());
            
            vc_utActionIDs[0] := LibItsDenm_Functions.f_utTriggerEvent(m_utTriggerEvent(v_situation, m_denmLocation_zeroDelta));
            log("actionId=", vc_utActionIDs[0]);
            
        }  // End of function f_secTriggerDenmEvent
        
        /**
        * @desc Behaviour function for cancelling previously triggered DENM events on IUT
        */
        function fb_secCancelDenmEvent() runs on ItsDenm {
            
            // Local variables
            var integer v_counter;
            
            for (v_counter := 0; v_counter < lengthof(vc_utActionIDs); v_counter := v_counter + 1) {
                LibItsDenm_Functions.f_utTerminateEvent(m_utEventCancellation(vc_utActionIDs[v_counter]));
            } // End of 'for' statement
            
            unmap(self:utPort, system:denmUtPort);
            deactivate(vc_default);
            
        } // End of function f_secTriggerDenmEvent
        
    } // End of group denmTrigger
    
} // End of module AtsSecurity_Functions