# A.1 Modified TTCN‑3 syntax BNF productions

This clause includes all BNF productions that are modifications of BNF rules defined in the TTCN-3 core language document [1]. When using this package the BNF rules below replace the corresponding BNF rules in the TTCN-3 core language document. The rule numbers define the correspondence of BNF rules.

Additions to clause A.1.6 of ETSI ES 201 873-1 are identified by underlined font, deletions are identified by strikethrough font. In case of contradiction between the above clause of part 1 and this clause (i.e. parts of the productions not marked by ~~strikethrough~~ font is changed in part 1), part 1 takes precedence, i.e. tools supporting the present document shall apply the insertions and deletions of this clause to the actual part 1 production or static semantics rule automtically.

94. BaseTemplateBody ::= (SimpleSpec |

 FieldSpecList |

 ArrayValueOrAttrib

 ) [ExtraMatchingAttributes] [ValueRedirect]

107. ArrayElementSpec ::= Minus |

 PermutationMatch |

 TemplateBody |

 DisjunctionMatch |

 RepetitionMatch

108. MatchingSymbol ::= Complement |

 (AnyValue [WildcardLengthMatch]) |

 (AnyOrOmit [WildcardLengthMatch]) |

 ListOfTemplates |

 Range |

 BitStringMatch |

 HexStringMatch |

 OctetStringMatch |

 CharStringMatch |

 SubsetMatch |

 SupersetMatch |

 DecodedContentMatch |

 DynamicMatch |

 ConjunctionMatch |

 ImplicationMatch |

 ExclusionMatch

113. BinOrMatch ::= Bin [StringRepetition] |

 AnyValue [StringRepetition] |

 AnyOrOmit

115. HexOrMatch ::= Hex [StringRepetition] |

 AnyValue [StringRepetition] |

 AnyOrOmit

117. OctOrMatch ::= Oct [StringRepetition] |

 AnyValue [StringRepetition] |

 AnyOrOmit

257.VarInstance ::= VarKeyword (

 ([LazyModifier | FuzzyModifier] [DeterministicModifier]] Type VarList) |

 ( TemplateModifier [(LazyModifier | FuzzyModifier) ) [DeterministicModifier] ]

 [MatchModifier]

 Type TempVarList)

 )

423. Value ::= PredefinedValue | ReferencedValue | SpecialValue

467.FormalTemplatePar ::= [(InParKeyword | OutParKeyword | InOutParKeyword )]

 TemplateModifier

 [(LazyModifier | FuzzyModifier) [DeterministicModifier]]

 [MatchModifier]

 Type Identifier [ArrayDef] [":=" (TemplateInstance | Minus)]

# A.2 Deleted TTCN‑3 syntax BNF productions

The rule for the nonterminal AddressValue shall be deleted.

# A.3 Additional TTCN‑3 syntax BNF productions

This clause includes all additional BNF productions that needed to define the syntax introduced by this package. All rules start with the digits "0222".

022001. DynamicMatch ::= DynamicModifier (StatementBlock | FunctionRef)

022002. DynamicModifier::= "@dynamic"

022003. RepetitionMatch ::= TemplateBody RepetitionCountSpec

022004. RepetitionCountSpec ::= "#" "(" [SingleExpression] ["," [SingleExpression]] ")"

/\*\* STATIC SEMANTICS The ValueKeyword has only meaning as a value in the StatementBlock of a 022001. DynamicMatch. The IndexModifier has only meaning as a value in the TemplateBody of a RepetitionMatch. \*\*/

022005. SpecialValue ::= ValueKeyword | NullValue | IndexModifier | OmitKeyword

022006. NullValue ::= "null"

022007. ConjunctionMatch ::= ConjunctKeyword ListOfTemplates

022008. ConjunctKeyword ::= "conjunct"

022009. ImplicationMatch ::= TemplateInstance ImpliesKeyword InfixTemplateOperand

022010. ImpliesKeyword ::= "implies"

022011. InfixTemplateOperand ::= ( TemplateInstanceNoAttr | ( "(" TemplateInstance ")" ))

022012. TemplateInstanceNoAttr ::= [(Type | Signature) Colon] [DerivedRefWithParList AssignmentChar]

 TemplateBodyNoAttr

022013. TemplateBodyNoAttr ::= SimpleSpec |

 FieldSpecList |

 ArrayValueOrAttrib

022014. ExclusionMatch ::= TemplateInstance ExceptKeyword InfixTemplateOperand

022015. DisjunctionMatch ::= DisjunctKeyword ListOfTemplates

022016. DisjunctKeyword ::= "disjunct"

022017. ValueRedirect ::= "->" SingleVarInstance

022018. StringRepetition ::= "#" (Num | ( "(" [Number] [","] [Number] ")" ))

022019. MatchModifier ::= "@match"